Posizionamento delle icone del desktop a sinistra anziché a destra

Qualsiasi modo per creare automaticamente alias o icone da mostrare sul lato sinistro del desktop di Apple. Di default vanno a destra.

Non c'è modo di forzare le icone ad andare automaticamente a sinistra (e rimanere disposti secondo il criterio scelto).

Per ovviare al problema, puoi modificare le Opzioni di visualizzazione nel Finder per non disporre gli elementi in base a nessun criterio e posizionare manualmente le icone a sinistra.

• Fai clic su uno spazio vuoto sul desktop.
• Premi Cmd+ Jo usa il mouse per accedere al menu Visualizza del Finder > Mostra opzioni di visualizzazione .
• Nel menu a discesa Ordina per: nella finestra di dialogo, seleziona Nessuno o Aggancia alla griglia .
• Sarai in grado di rilasciare i file ovunque sul desktop e rimarranno lì.

Vedi Nozioni di base su Mac: modifica le finestre per ulteriori informazioni.

Consulta anche le pagine di base di Mac per ulteriori informazioni sull'uso di un Mac.

Questa non è la soluzione migliore ma può funzionare se non altro ...

1. Creare un'azione della cartella Automator associata al desktop.
2. Aggiungi l'elemento: "esegui applecript"

3. Incolla il seguente codice nella casella di testo di applecript:

   -- https://gist.github.com/mrienstra/8330528
   -- Based on http://www.tuaw.com/2012/12/24/applescript-desktop-icon-race/
   -- Inspired by http://namesakecomic.com/comic/happy-new-year-from-namesake/#comment-1182035013
   
   -- Rearranges Desktop icons to flow from left to right, top to bottom.
   
   -- To have this run automatically every time files are added or removed from the Desktop, set this script to run as a Desktop "Folder Action". (See https://developer.apple.com/library/mac/documentation/applescript/conceptual/applescriptlangguide/reference/ASLR_folder_actions.html )
   
   -- This is currently a rough proof-of-concept. It has only been tested with OS X 10.8.5 (Mountain Lion).
   
   -- Current known limitations: Does not work with "Label position" set to "Right" (specifically, icons will overlap).
   
   
   
   -- Adjust these for different spacing
   property theSpacingFactor : 1.0
   property theGutterXFactor : 0.57
   property theGutterYFactor : 0.57
   
   
   
   on rearrangeDesktopIcons()
       tell application "Finder"
           tell icon view options of window of desktop
               set theArrangement to arrangement
               set theArrangementString to theArrangement as string
               if {"not arranged", "«constant ****narr»", "snap to grid", "«constant ****grda»"} does not contain theArrangementString then
                   display alert "\"Rearrange Desktop Icons\" AppleScript says:" message "Cannot rearrange Desktop items, please change Desktop \"Sort by\" to \"None\" or \"Snap to Grid\"." giving up after 10
                   return
               end if
               set theIconSize to icon size
               set theLabelSize to text size
           end tell
   
           set theDesktopBounds to bounds of window of desktop
           set theDesktopWidth to item 3 of theDesktopBounds
           set theDesktopHeight to item 4 of theDesktopBounds
   
           -- Retrieve a list of items on the desktop
           set theDesktopItems to every item of desktop
           set theContestantOffset to theIconSize / 2
   
           set theSpacing to (theIconSize + theLabelSize + theContestantOffset) * theSpacingFactor
           set theGuttersX to theSpacing * theGutterXFactor
           set theGuttersY to theSpacing * theGutterYFactor
           set theMaxColumns to ((theDesktopWidth - theGuttersX * 2) / theSpacing) as integer
           set theMaxRows to ((theDesktopHeight - theGuttersY * 2) / theSpacing) as integer
           set theMaxLocations to theMaxRows * theMaxColumns
   
           set y to 1
           repeat with a from 1 to length of theDesktopItems
               set x to a mod theMaxColumns
               if x is 0 then
                   set x to theMaxColumns
               end if
   
               if a is greater than theMaxLocations then
                   set desktop position of item a of theDesktopItems to {theGuttersX, theGuttersY}
               else
                   set desktop position of item a of theDesktopItems to {theGuttersX + (x - 1) * theSpacing, theGuttersY + (y - 1) * theSpacing}
               end if
   
               if a mod theMaxColumns is 0 then
                   set y to y + 1
               end if
           end repeat
       end tell
   end rearrangeDesktopIcons
   
   
   
   on adding folder items to alias after receiving listOfAlias
       rearrangeDesktopIcons()
   end adding folder items to
   
   on removing folder items from alias after losing listOfAliasOrText
       rearrangeDesktopIcons()
   end removing folder items from
   
   rearrangeDesktopIcons()
   

Quindi, ogni volta che un file viene aggiunto al desktop, tutti i file verranno riorganizzati in ordine alfabetico ...

Organizza tutte le cartelle nell'ordine desiderato. Quindi sotto Visualizza premi "ripulisci". Questo allineerà tutto bene. Quindi puoi semplicemente evidenziare tutte le cartelle e posizionarle esattamente dove le desideri. I Mac non organizzano le cartelle a sinistra, ma solo a destra, ma con un paio di semplici passaggi puoi avere tutto organizzato in modo ordinato a sinistra.

Ho appena evidenziato tutte le cartelle dal lato destro, poi le ho afferrate tutte e incollate a sinistra.