Crea un nuovo file (.txt) nel Finder - Scorciatoia da tastiera

Volevo sapere se esiste un modo per impostare le scorciatoie da tastiera per creare nuovi file nel Finder. Ad esempio, per impostazione predefinita, è possibile creare una nuova cartella utilizzando CMD+ Shift+ N. Esiste una scorciatoia da tastiera per creare un nuovo file di testo? Sono un programmatore, quindi sarebbe estremamente utile

Sarei anche interessato a creare un altro tipo di file usando le scorciatoie da tastiera.

Ho tentato di utilizzare l'automazione ma lo trovo abbastanza confuso e non sono sicuro di come collegare una scorciatoia da tastiera ad esso.

Bene, eccoti qui con un AppleScript per questo.

Innanzitutto, crea AppleScript:

1. Apri Automator
2. Crea un'azione rapida
3. Impostare l'ingresso su nessun ingresso
4. Trascina e rilascia l' elemento Esegui flusso di lavoro AppleScript nello spazio grigio.
5. Incolla il codice dal basso in AppleScript
6. Salva il flusso di lavoro come Crea nuovo file
   Se iCloud Drive è attivato, assicurati di salvare il file Library/Services/nella cartella Home.

try
  tell application "Finder" to set the this_folder ¬
   to (folder of the front window) as alias
on error -- no open folder windows
  set the this_folder to path to desktop folder as alias
end try

set thefilename to text returned of (display dialog ¬
 "Create file named:" default answer "filename.txt")
set thefullpath to POSIX path of this_folder & thefilename
do shell script "touch \"" & thefullpath & "\""

Per aggiungerlo come scorciatoia:

• Vai a Preferenze di Sistema -> Tastiera -> Tasti di scelta rapida -> Servizi
• Scorri verso il basso fino a trovare il servizio Crea nuovo file
• Assegnare una scorciatoia facendo clic sul lato destro nessuno , che si trasforma in a Add Shortcut.
  Fare clic sul pulsante e digitare il collegamento che si desidera utilizzare.
  Io uso ⌘ Command+ ⌥ Option+N

Ho creato un AppleScript molto simile a quello di @ YoshiBotX, ma con alcuni miglioramenti.

L'idea è di creare un flusso di lavoro di Automator e assegnare un collegamento ad esso utilizzando i seguenti passaggi:

• Apri Automator e crea un servizio ;
• Impostare l'input su nessun input e l'applicazione su Finder.app ;
• Trascina e rilascia l' elemento Esegui flusso di lavoro AppleScript nello spazio grigio;
• Inserisci il contenuto di questo AppleScript nella casella di testo;
• Salva il flusso di lavoro con un nome ragionevole (come Nuovo file );
• Vai su Impostazioni -> Tastiera -> Tasti di scelta rapida -> Servizi e assegna un collegamento ad esso.

Ora, mostriamo AppleScript:

set file_name to "untitled"
set file_ext to ".txt"
set is_desktop to false

-- get folder path and if we are in desktop (no folder opened)
try
    tell application "Finder"
        set this_folder to (folder of the front Finder window) as alias
    end tell
on error
    -- no open folder windows
    set this_folder to path to desktop folder as alias
    set is_desktop to true
end try

-- get the new file name (do not override an already existing file)
tell application "System Events"
    set file_list to get the name of every disk item of this_folder
end tell
set new_file to file_name & file_ext
set x to 1
repeat
    if new_file is in file_list then
        set new_file to file_name & " " & x & file_ext
        set x to x + 1
    else
        exit repeat
    end if
end repeat

-- create and select the new file
tell application "Finder"

    activate
    set the_file to make new file at folder this_folder with properties {name:new_file}
    if is_desktop is false then
        reveal the_file
    else
        select window of desktop
        set selection to the_file
        delay 0.1
    end if
end tell

-- press enter (rename)
tell application "System Events"
    tell process "Finder"
        keystroke return
    end tell
end tell

Per comodità, sto inserendo questo AppleScript in questo GitHub Gist .

Puoi creare tu stesso un servizio di automazione - è piuttosto semplice da fare. Quindi è possibile assegnare una scorciatoia da tastiera in modo che non sia necessario attivare il servizio tramite il menu dei servizi (cosa che si può fare comunque).

Apri Automator e seleziona Servizio come tipo di nuovo documento.

Impostare il servizio per non ricevere input in Finder.app e aggiungere l'azione Nuovo documento TextEdit al flusso di lavoro.

Salvare il servizio, quindi aprire Preferenze di Sistema → Tastiera → Scorciatoie → Servizi dove troverai il servizio elencato in Generale con il nome che hai dato per il servizio quando lo hai salvato.

Aggiungi una scorciatoia da tastiera al servizio selezionando il servizio quindi facendo clic su "aggiungi scorciatoia".

Qui potresti avere dei problemi se il collegamento è già utilizzato. Quindi diventa creativo per crearne uno che funzioni per te.

Puoi anche assegnare un collegamento a uno script come questo:

tell application "Finder"
    set selection to make new file at (get insertion location)
end tell

La posizione di inserimento è la destinazione della finestra del Finder in primo piano o del desktop.

terminale aperto e digitare

touch filename

o

> filename

Questa è una ripubblicazione di un post che ho pubblicato l'anno scorso. Ho avuto una buona esperienza con quanto segue.

Esistono due utilità utili che è possibile scaricare e installare che ti permetteranno di creare un nuovo file di testo (o file RTF) in una cartella attualmente aperta che stai visualizzando utilizzando il Finder.

Le utility si chiamano NewTextFileHere e NewRTFHere e possono essere scaricate da

http://mac.softpedia.com/developer/Jonas-Wisser-37498.html

Le icone per una di queste app possono quindi essere incluse in tutte le finestre del Finder.

Proprio quello che stavo cercando, Richard Fuhr. Grazie per questo.

Una nota: il link dell'URL per NewTextFileHere sembra caricarsi su una pagina vuota. Ma ho fatto una ricerca e ho trovato l'app qui: http://mac.softpedia.com/progDownload/NewTextFileHere-Download-70374.html

Un'alternativa, se hai già BetterTouchTools (era un'app gratuita, ora ha un modello pay-what-you-want con un periodo di prova di 30 giorni), puoi trovare l'azione su "Utility Actions > Create New File in Current Folder"cui fa esattamente questo, con un pop-up per permetterti di scegliere il nome. Assegna il collegamento desiderato (ho scelto Opzione + Maiusc + N) e sei a posto.

Nel caso in cui si utilizzi MacVim , è disponibile un'opzione Finder -> Servicesper creare un nuovo buffer vim:

Ho mappato questo al collegamento ShiftcmdMin System Preferences -> Keyboard -> Shortcuts: