Il comando "delay" di AppleScript non funziona dal momento che passa a Yosemite

Nota: il problema con è delaystato risolto in OS X 10.11 El Capitan.

Da quando ho effettuato l'aggiornamento a Yosemite, gli script di Apple che utilizzano i ritardi hanno smesso di funzionare. Come posso risolvere questo problema?

Ecco l'applescript più semplice del mondo, per un semplice esempio:

set volume output volume 0
delay 5
set volume output volume 20
delay 5
set volume output volume 0
delay 5
set volume output volume 20
delay 5
set volume output volume 0
delay 5
set volume output volume 20
delay 5
set volume output volume 0

Il completamento dovrebbe richiedere 30 secondi. Se lo eseguo in Script Editor (precedentemente Applescript Editor) ci vogliono 30 secondi per completarlo. Ma se salvo questo script come app, quando avvio l'app, i ritardi vengono ignorati e l'app richiede una frazione di secondo per essere completata.

Come posso forzare Applescript a ritardare per un determinato periodo di tempo prima di passare al passaggio successivo? Questo è un problema tecnico di Yosemite? Esiste una soluzione affidabile?

Nota: il problema con è delaystato risolto in OS X 10.11 El Capitan.

@ 2oh1, hai la giusta idea di base nella tua risposta, ma ecco una risposta completa e corretta:

L'unico modo ragionevole per aggirare questo problema è invocare il "ritardo" all'interno di un ciclo che garantisca la durata desiderata prima di continuare. Il modo migliore per farlo è quello di sovrascrivere il "ritardo" con un gestore personalizzato:

on delay duration
  set endTime to (current date) + duration
  repeat while (current date) is less than endTime
    tell AppleScript to delay endTime - (current date)
  end repeat
end delay

Ciò ti consente di lasciare invariato il resto dello script e di utilizzare normalmente "delay", ad es.

delay 5
display alert "I like cake!"

[NOTA: normalmente, il gestore personalizzato userebbe "continua durata del ritardo" per invocare il "ritardo" incorporato, ma ho scoperto che, sebbene funzioni all'interno di Script Editor, restituisce un errore se utilizzato in un'applet ("Can" t continua il ritardo. (-1708) "). Ho risolto il problema dicendo direttamente ad AppleScript di gestire il comando delay invece di usare "continue" per arrivarci.]

Il problema è che delayelabora l'input dell'utente durante la pausa dello script, quindi puoi ancora fare clic su menu o finestre visualizzate da un'applet e c'è un bug (risolto in 10.11) in cui l'input dell'utente fa sì delayche non attenda la durata completa prima di riprendere l'esecuzione dello script . Se non interagisci con l'applet, delayfunziona correttamente.

Mentre combattevo lo stesso problema mi sono imbattuto in questa risposta a una domanda non così correlata e ho deciso di provarlo e sembra funzionare per me.

Sostituisci semplicemente delay 5con do shell script "/bin/sleep 5"e ottieni lo stesso risultato.

Non sto dicendo che questa è la soluzione migliore, ma sembra aver risolto il mio problema. Invece di utilizzare un semplice ritardo, che viene ignorato per motivi che non capisco, sono passato a ottenere l'ora e il looping fino a quando non viene raggiunto un nuovo orario (utilizza ancora un ritardo, ma non importa se ignora il ritardo poiché lo script non continua fino al raggiungimento del tempo).

# Pause for five minutes
set GetTheTime to current date
set NewTime to GetTheTime + (5 * minutes)
repeat while (current date) is less than NewTime
    delay 60
end repeat

Sto ancora morendo dalla voglia di sapere perché il ritardo viene ignorato (o accelerato drammaticamente?! ??), ma questo fa il lavoro, per quanto goffo.

Ho trovato una soluzione in un post sul forum tedesco . Aggiungi queste righe all'inizio dello script:

use framework "Foundation"
use scripting additions
current application's NSThread's sleepForTimeInterval:1

carzyj aveva quella che considero la migliore risposta, ma quando combinato con il metodo di Chris Page, ottieni:

on delay duration
  do shell script "/bin/sleep " & duration
end delay

È possibile commentare "on delay" fino a "end delay" per ripristinare il ritardo originale.

questa è una modifica alla soluzione @ chris-page

Sembra essere un equilibrio tra reattività e cattura accurata del ritardo.

on delay duration
    set endTime to (current date) + duration
    repeat while (current date) is less than endTime
        set delta to duration / 100
        if duration < 0.2 then
            set delta to 0.2
        end if
        tell AppleScript to delay delta
    end repeat
end delay

Ma invece di dire ad Applescript di ritardare per la durata complessiva, diciamo solo di ritardare per un periodo frazionario della durata. se il periodo è inferiore a quello consentito da Apple (1/60 di secondo), impostiamolo su quel delta. Che possiamo mantenere un po 'di reattività, ma allo stesso tempo essere precisi. il sospetto è che a volte il ritardo non funzioni, quindi la ripetizione mentre il ciclo manterrà bloccato il thread, ma in scenari di successo, vogliamo che il delta di ritardo sia breve in modo che il processo possa ancora essere interrotto

Quindi, per mettere tutto insieme, credo che Chris significhi questo:

on delay duration
   set endTime to (current date) + duration
   repeat while (current date) is less than endTime
      tell AppleScript to delay endTime - (current date)
   end repeat
end delay