Esiste un modo per non richiedere una password per l'accesso quando sono a casa ma ne ho ancora richiesta dappertutto

Sto cercando un modo per accedere automaticamente al mio computer quando mi sveglio da sleep / startup quando sono a casa / connesso al mio wifi di casa; ma quando, ad esempio, sono a scuola o non sono connesso al mio wifi di casa, ho bisogno di una password.

Sto eseguendo El Capitan 10.11 Beta (15A278b) su un MacBook Pro (Retina 15 pollici metà 2015)

wifi sleep-wake

— genero derozario
fonte

Ho configurato il mio sistema per fare qualcosa di simile a quello che stai cercando di fare. Mentre personalmente non disabilito mai la mia password di accesso (non consiglio mai di farlo per diversi motivi), modifico alcune delle mie impostazioni di sicurezza per la mia rete domestica locale rispetto a quando sono fuori casa.

Innanzitutto, vorrai ottenere e installare ControlPlane (che NON ho testato con El Capitan). Questo componente aggiuntivo ti consentirà di modificare un sacco di impostazioni sul tuo Mac in base alle informazioni sulla posizione che può trarre da " fonti di prova ". Ha anche un sacco di funzioni integrate, è AppleScriptable e open source .

Dopo aver installato ControlPlane, dovrai creare un AppleScript che ti consenta di disabilitare o abilitare l'accesso con password in base alle informazioni sulla posizione.

L'AppleScript che crei può variare a seconda del Mac OS in uso (nel tuo caso El Capitan). Ma sarà simile allo script che ho creato su OS X 10.9.5 per fare quello che vuoi.

NOTA 1: questo script attiva o disattiva solo le impostazioni presenti nella pagina Sicurezza e privacy, NON comprende le informazioni sulla posizione. Probabilmente vorrai creare una versione di questo AppleScript per ogni posizione identificata da ControlPlane e modificarla di conseguenza.

NOTA 2 : questo script richiede all'utente di inserire la password amministrativa due volte quando disabilita le impostazioni di accesso con password e salvaschermo. Non conosco un modo per aggirare questo a meno che tu non voglia scendere e fare script di shell da ControlPlane, o aggiungere la tua password in AppleScript e farlo scrivere per te.

NON GARANTISCO O GARANTISCO QUESTO SCRIPT! UTILIZZARE A VOSTRO RISCHIO PROPRIO COME NON HO TESTATO CON EL CAPITAN.

-- !!! USE THIS SCRIPT AT YOUR OWN RISK !!!
-- !!! NO IMPLIED OR EXPLICIT GUARANTEES OR WARRANTIES ARE MADE !!!
-- USE OF THIS SCRIPT IS NOT GUARANTEED TO WORK ON ALL OS VERSIONS!

-- An AppleScript to Disable and Enable automatic login and sleep/screen saver password request.
-- This script may require the user to enter their administrative password twice when disabling.
-- This script ONLY toggles the settings found on the Security & Privacy page.

tell application "System Preferences"
    activate
    set current pane to pane id "com.apple.preference.security"
    delay 1
    tell application "System Events"
        tell process "System Preferences"
            click menu item "Security & Privacy" of menu "View" of menu bar 1
            delay 0.5

            -- Check to see if the System Prefs are locked and editing is disabled.
            if title of checkbox 1 of window 1 is "Click the lock to make changes." then
                click checkbox 1 of window 1
                repeat until checkbox "Click the lock to prevent further changes." of window 1 exists
                    delay 0.1
                end repeat
            end if

            -- This should enable or disable "Disable automatic login"
            click checkbox "Disable automatic login" of tab group 1 of window 1
            repeat until not (exists sheet 1 of window 1)
                delay 0.1
            end repeat
            delay 0.5

            -- This should enable or disable "Require password after sleep or screen saver begins"
            click checkbox 1 of tab group 1 of window 1
            delay 0.25
            repeat until not (exists sheet 1 of window 1)
                click button "Turn Off Screen Lock" of sheet 1 of window 1
            end repeat
            delay 0.25
            -- BE CARFULE IF YOU CHANGE THIS AS IT COULD MODIFY YOUR KEYCHAIN!!!
            repeat until not (exists sheet 1 of window 1)
                click button "Keep Using Keychain" of sheet 1 of window 1
            end repeat

        end tell
    end tell
    tell application "System Preferences" to quit
end tell

Se usi questo script come app AppleScript ASSICURATI che le impostazioni di accessibilità siano abilitate, altrimenti non funzionerà.

— kenjikato
fonte