Come posso ridimensionare tutte le mie finestre quando cambio display?

Esiste un'app che mi permetterà di ridimensionare automaticamente tutte le mie finestre aperte quando passo dallo schermo del mio laptop al monitor esterno?

Trascorro il mio tempo lavorando su un monitor esterno collegato al mio mbp o solo al mio mbp. Quando passo dal monitor al laptop, tutte le mie app a schermo intero (la vecchia definizione) hanno finestre più grandi della risoluzione del mio laptop. Devo ridimensionarli tutti, ma poi quando mi ricollego al monitor esterno sono tutti più piccoli, allora li vorrei.

Ho provato Moon, ma sono stato in grado di ridimensionare le finestre su un singolo spazio alla volta, in genere ho più applicazioni in modalità a schermo intero (la vecchia definizione) aperte su più spazi.

Ci sono infiniti modi per farlo, quindi eccone alcuni:

• Prima di scollegare il monitor esterno, apri il pannello Preferenze display in Preferenze di Sistema e fai clic sul pulsante "Raccogli Windows".

  [o se hai già scollegato]

• Tieni Optionpremuto il tasto e scegli "Disponi davanti" dal menu Finestra.

  [o]

• Usa il Optiontasto e fai clic su (+) nella parte superiore di qualsiasi finestra del Finder e li ridimensionerà automaticamente.

Questo script di Applescript potrebbe anche funzionare:

tell application "Finder"
-- get desktop dimensions (dw = desktop width; dh = desktop height)
set db to bounds of window of desktop
set {dw, dh} to {item 3 of db, item 4 of db}
end tell

tell application "System Events"
repeat with proc in application processes
tell proc
repeat with win in windows
-- get window dimensions (w = width; h = height)
set {w, h} to size of win

-- get window postion (l = left of window; t = top of window)
set {l, t} to position of win

-- nh = new window height; nw = new window width
set {nh, nw} to {h, w}

-- window width is bigger than desktop size,
-- so set new window width to match the desktop
if (w > dw) then ¬
set nw to dw

-- window height is bigger than the desktop size (minus menu bar),
-- so set new window height to be desktop height - 22 pixels
if (h > dh - 22) then ¬
set nh to dh - 22

-- r = right coordinate of window; b = bottom coordinate of window
set {r, b} to {l + nw, t + nh}

-- nl = new left coordinate; nt = new top coordinate
set {nl, nt} to {l, t}

-- left coordinate is off screen, so set new left coordinate
-- to be 0 (at the left edge of the desktop)
if (l < 0) then ¬
set nl to 0

-- top coordinate is above bottom of menu bar (22 pixels tall),
-- so set new top coordinate to be 22
if (t < 22) then ¬
set nt to 22

-- right coordinate extends beyond desktop width,
-- so set new left coordinate to be desktop width - window width
if (r > dw) then ¬
set nl to dw - nw

-- bottom coordinate extends beyond desktop height,
-- so set new top coordinate to be desktop height - window height
if (b > dh) then ¬
set nt to dh - nh

-- if we have calculated a new top or left coordinate, reposition window
if (l ≠ nl or t ≠ nt) then ¬
set position of win to {nl, nt}

-- if we have calculated a new height or width, resize window
if (h ≠ nh or w ≠ nw) then ¬
set size of win to {nw, nh}
end repeat
end tell
end repeat
end tell

Naturalmente c'è anche l'alternativa a pagamento, che potrebbe includere Soggiorno , Divy , Disponi , ecc.

Puoi provare Stay . Ti consente di impostare dimensioni / disposizioni della finestra in base ai display collegati e ha il supporto Spaces. Non sono sicuro che abbia lo stesso comportamento che stai cercando con Spaces (le FAQ non sono chiare), ma probabilmente vale la pena controllare almeno la demo.