Ho una variabile di testo di classe textche mostra qualcosa del genere quando viene restituito:

"
This is sentence 1.
This is sentence 2.
This is sentence 3.
This is sentence 4."

Voglio essere in grado di eliminare righe specifiche dal testo, senza influire sul resto della variabile.

Ad esempio: delete {1, 3}per ottenere questo risultato:

"This is sentence 1.
This is sentence 3.
This is sentence 4."

Il metodo descritto in questa risposta ha un bug grave:

"Come eliminare una riga specifica di un paragrafo in AppleScript?"

Il metodo collegato per eliminare le righe in un paragrafo in realtà converte tutti gli avanzamenti di riga nella variabile di testo in ritorni. In altre parole, è impossibile eseguire questo codice più di una volta sulla stessa variabile.

Ad esempio, il seguente codice:

set varText to "
This is sentence 1.
This is sentence 2.
This is sentence 3.
This is sentence 4."
set varText to do shell script "sed -e '1d;3d' <<< " & quoted form of varText
-- Employing the same method on the same variable:
set varText to do shell script "sed -e '1d;3d' <<< " & quoted form of varText
return varText

ritorna

""

Poiché questo metodo funziona correttamente solo se le righe della variabile di testo sono il prodotto di una linefeed(come dovrebbe), il problema non è che questo metodo non riesce a percepire returnuna nuova riga (come avevo inizialmente sostenuto in questa domanda). Il problema è che questo codice introduce returninnanzitutto una variabile di testo.

Quindi, voglio una soluzione che mi permetta di eseguire la stessa variabile di testo attraverso la soluzione più di una volta nello stesso AppleScript.

In altre parole, sto cercando un metodo per rimuovere una riga specifica da un paragrafo che non ha questo bug e non inserisce un returnpunto nel testo.

Ok, ho eliminato l'originale e la prima modifica perché hai modificato la tua domanda originaria al punto che è più facile scrivere una nuova risposta del tutto.

Poiché la tua domanda iniziale mostrava la seguente riga di codice , come esempio di come può essere impostata la variabile, la includerò per dire quanto segue.

Se varTextè stato impostato, ad esempio:

set varText to (return & "This is sentence 1." & return & "This is sentence 2." & return & "This is sentence 3." & return & "This is sentence 4.")

• In quale returnè invece x0Dl'uso più appropriato di linefeed( x0A) invece, nel caso in cui la variabile sia data e non un messaggio usa e getta.

O:

set varText to "
This is sentence 1.
This is sentence 2.
This is sentence 3.
This is sentence 4."

• In cui ciascuna di queste righe termina in realtà con un linefeed( x0A) come dovrebbe essere su un Mac.

Il do shell script comando ha un bug in quanto converte x0Aa x0Ddopo quello che è tornato dalla riga di comando con le attese x0Afinali ripassato. L'ho confermato perché se utilizzo quanto segue:

set varText to "
This is sentence 1.
This is sentence 2.
This is sentence 3.
This is sentence 4."

set varText to do shell script "sed  -e '1d;3d' <<< " & quoted form of varText & " | tee $HOME/Desktop/outfile"

Quindi outfilecontiene linefeed( x0A) le terminazioni in modo che lo stesso venga restituito do shell scriptma converte erroneamente le x0Aterminazioni di linea in x0Dterminazioni che possono quindi essere gestite come segue:

Quindi, per sistemare il bug , assicurati sempre che il contenuto della variabile passata e restituita contenga x0Aterminazioni di riga usando il seguente codice dihandler esempio .

Di seguito si presume che varTextsia già stato impostato da uno dei metodi sopra descritti.

on ensureLinesEndWith0A(varText)
    set varText to paragraphs of varText
    set oldTID to AppleScript's text item delimiters
    set AppleScript's text item delimiters to linefeed
    set varText to varText as string
    set AppleScript's text item delimiters to oldTID
    return varText
end ensureLinesEndWith0A

set varText to ensureLinesEndWith0A(varText)
set varText to do shell script "sed  -e '1d;3d' <<< " & quoted form of varText
set varText to ensureLinesEndWith0A(varText)

È quindi possibile utilizzare nuovamente quanto segue per eliminare più righe da varText:

set varText to ensureLinesEndWith0A(varText)
set varText to do shell script "sed  -e '1d;3d' <<< " & quoted form of varText
set varText to ensureLinesEndWith0A(varText)

L'immagine seguente mostra un esempio di chiamata al do shell script " sed ..." comando due volte.

Esempio:

set varText to "
This is sentence 1.
This is sentence 2.
This is sentence 3.
This is sentence 4."

set varText to do shell script "sed -e '1d;3d' <<< " & quoted form of varText

Ritorna:

"This is sentence 1.
This is sentence 3.
This is sentence 4."

Aggiornamento: a seguito di una scoperta menzionata in Modifica: di Come eliminare una riga specifica di un paragrafo basato su "return" in AppleScript? , vorrei fare la seguente dichiarazione:

NOTA: Sfortunatamente ciò che viene restituito in questo caso ha caratteri di ritorno a capo (x0D) invece dei caratteri di nuova riga previsti (x0A) e secondo me è un bug!

È un bug perché: il do shell script "sed ..." comando eseguito in Terminal con quello varTextrestituisce con \n(x0A) non \r(x0D) come dovrebbe. Anche il do shell script "sed ..." comando compilato in Script Editor ha ancora \n(x0A) non \r(x0D), tuttavia il motivo per cui viene restituito con \r(x0D) l'intenzione del previsto \n(x0A) è un mistero per me al momento e lo considererò un AppleScript bug poiché non rispecchia il comportamento previsto dello stesso quando eseguito nel Terminale.

Quindi, per tenere conto del bug nei risultati del do shell script "sed ..." comando , ecco come lo gestirò. Dopo il do shell script "sed ..." comando utilizzare le seguenti righe di codice :

set newLine to "\n"
set varText to paragraphs of varText
set oldTID to AppleScript's text item delimiters
set AppleScript's text item delimiters to newLine
set varText to varText as string
set AppleScript's text item delimiters to oldTID

Ora, ciò che è restituito contiene una nuova serie (x0a) personaggi come avrebbe dovuto cominciare con se non ci fosse questo bug, non di ritorno a capo (x0d) caratteri .

Nota: una volta compilata, la set newLine to "\n"riga di codice verrà visualizzata come di seguito:

set newLine to "
"

Suddividiamo questo script in pezzi più piccoli e poi riuniamolo in un unico AppleScript.

Questo approccio è interamente scritto in AppleScript e non richiede strumenti esterni. L'uso di strumenti esterni, come perlo sed, probabilmente porterà a soluzioni molto più brevi ma hai menzionato in altre domande che vogliono imparare AppleScript.

1. Dividi con delimitatori

È possibile utilizzare il comportamento dei delimitatori di AppleScript per dividere una stringa . È possibile modificare il delimitatore come desiderato per return, linefeedo anche personaggi come =:

 -- http://macscripter.net/viewtopic.php?id=24473
 to split(someText, delimiter)
     set AppleScript's text item delimiters to delimiter
     set someText to someText's text items
     set AppleScript's text item delimiters to {""} --> restore delimiters to default value
     return someText
 end split

 set myText to (return & "This is sentence 1." & return & "This is sentence 2." & return & "This is sentence 3." & return & "This is sentence 4.")
 set myLines to split(myText, return)

2. Elenco filtri

Con l'elenco restituito, è possibile filtrare gli elementi indesiderati utilizzando un ciclo:

 -- http://macscripter.net/viewtopic.php?id=24525
 set indexesToDelete to {1, 4}
 set cleanList to {}

 repeat with i from 1 to count myLines
     if i is not in indexesToDelete then set cleanList's end to myLines's item i
 end repeat

3. Combina gli oggetti

L'elenco filtrato di frasi può essere ricombinato utilizzando un altro ciclo:

-- Combine the filtered list into a string
set myResult to ""
repeat with i from 1 to count cleanList
    if myResult is "" then
        set myResult to cleanList's item i
    else
        set myResult to myResult & return & cleanList's item i
    end if
end repeat

Interamente AppleScript

La combinazione di questi frammenti genera il seguente codice:

-- Get the text to work with
set myText to (return & "This is sentence 1." & return & "This is sentence 2." & return & "This is sentence 3." & return & "This is sentence 4.")

-- Split the text into lines based on 'return' delimiter
set myLines to split(myText, return)

-- Filter out indexes 1 and 4 using a loop
set indexesToDelete to {1, 4}
set cleanList to {}
repeat with i from 1 to count myLines
    if i is not in indexesToDelete then set cleanList's end to myLines's item i
end repeat

-- Combine the filtered list into a string
set myResult to ""
repeat with i from 1 to count cleanList
    if myResult is "" then
        set myResult to cleanList's item i
    else
        set myResult to myResult & return & cleanList's item i
    end if
end repeat

-- Final string
myResult

to split(someText, delimiter)
    set AppleScript's text item delimiters to delimiter
    set someText to someText's text items
    set AppleScript's text item delimiters to {""} --> restore delimiters to default value
    return someText
end split

Lo script sopra potrebbe essere ridotto combinando i cicli di filtro e ricombinazione. Li ho lasciati come compiti separati per dimostrare meglio i loro ruoli.