Come tornare alla visualizzazione elenco di brani in playlist su iTunes 12.6

Come faccio a visualizzare la vecchia lista di brani all'interno di playlist su iTunes 12.6? Alcune delle mie playlist (sia vecchie che nuove) sono ora visibili nella stupida lista che mostra la copertina dell'album e tutti i tipi di merda extra, e ho solo circa 8 canzoni per schermo che posso vedere contemporaneamente senza scorrere. Come faccio a tornare solo alla visualizzazione elenco di solo testo all'interno di singole playlist (non solo la libreria principale) in iTunes 12.6?

Visualizza menu & gt; Visualizza come.

Scegli il tuo preferito.
La playlist contiene "mini cover". I brani sono minimi, solo testo.

Sfortunatamente, non è un'impostazione globale, è per playlist.

Questo mi ha frustrato per anni; come hanno imitato tanti altri (ora standard) comportamenti come la cronologia di navigazione, ma non hanno reso le viste globali?

Essenzialmente la cosa più vicina che ho letto (e implementato) per risolvere questo è il caricamento di una nuova installazione di iTunes e la creazione del primo elenco, quindi l'impostazione di tutte le preferenze su di esso, quindi in futuro tutte le liste erediteranno effettivamente le impostazioni di l'elenco originale.

Non so come modificare la modalità di visualizzazione predefinita per le nuove playlist, ma puoi eseguire uno script come quello in basso in Script Editor per cambiare la modalità di visualizzazione di tutte le playlist esistenti.

tell application "iTunes"
    repeat with p in user playlists
        set view of browser window 1 to p
        try
            tell application "System Events" to tell process "iTunes" to click menu item "Songs" of menu 1 of menu item "View As" of menu 1 of menu bar item "View" of menu bar 1
        end try
    end repeat
end tell

Senza il try blocca lo script in alto con un errore quando raggiunge una playlist "speciale" come la vista "Songs" in cui la voce "Visualizza & gt; Visualizza come & gt; Canzoni" non esiste. Puoi rimuovere il try bloccare se si sostituisce user playlists con user playlists whose special kind is not none and smart is false. Nella mia versione di iTunes, tell application "iTunes" to name of user playlists whose special kind is not none tornato {"Music", "Movies", "TV Shows", "Podcasts", "iTunes U", "Audiobooks", "Purchased"}.

Io uso uno script come quello qui sotto per creare la maggior parte delle nuove playlist. Richiede GNU xargs e readlink che è possibile installare eseguendo brew install findutils coreutils.

osascript -e'on run {a}
    set l to {}
    repeat with f in (get paragraphs of a)
        set end of l to POSIX file f
    end repeat
    tell application "iTunes"
        if number of l is 1 then
            tell application "Finder" to set n to name of (item 1 of l as alias)
            set p to make new user playlist with properties {name:n}
        else
            set p to make new user playlist
        end if
        with timeout of 0 seconds -- don't exit with an error if the add command takes over 20 seconds
            add l to p
        end
        set view of browser window 1 to p
        tell application "System Events" to tell process "iTunes"
            click menu item "Songs" of menu 1 of menu item "View As" of menu 1 of menu bar item "View" of menu bar 1
        end tell
    end tell
end run' "$(printf %s\\n "${@-$(cat)}"|gxargs -rd\\n greadlink -f)"

Se l'applicazione Eventi di sistema non è presente nell'elenco delle applicazioni in "Preferenze di sistema & gt; Sicurezza e privacy & gt; Privacy & gt; Accessibilità", lo script sopra riportato genera un errore come questo: 636:751: execution error: System Events got an error: osascript is not allowed assistive access. (-1719).