Sto usando un MacBook Air con Sierra.
Mi piace usare diverse impostazioni del mouse con il mio touchpad e il mio mouse USB. Per facilitare questo, ogni volta che collego il mouse, devo andare a System Preferencese modificare le impostazioni del mouse (invertire la direzione di scorrimento e regolare la sensibilità). Esiste un modo per automatizzare questa modifica (magari utilizzando l'automatore) nelle impostazioni che si verificano automaticamente ogni volta che si collega il mouse USB?
Risposte:
In macOS Sierra , se hai solo un normale mouse USB , non uno fornito con il suo software ed è multifunzione con pulsanti aggiuntivi, ecc., Quindi in Preferenze di Sistema > Mouse , hai le seguenti impostazioni che possono essere modificate:
E due impostazioni aggiuntive sotto il mouse che non saranno indirizzate, per due motivi, al pulsante principale del mouse: i pulsanti di opzione , se diverso da quello predefinito di Sinistra , sono con ogni probabilità già impostati e non cambieranno necessariamente perché si vuole cambiare il direzione di scorrimento: naturale casella di controllo , e dal momento che l'OP ha dichiarato mouse USB , darò per scontato non utilizza Bluetooth e può ignorare l' installazione di Bluetooth mouse ... pulsante .
Questa risposta utilizzerà AppleScript per ottenere le impostazioni prima e dopo per il valore dei dispositivi di scorrimento elencati sopra da utilizzare nel codice AppleScript che segue dopo questo codice .
Apri Script Editor e crea un nuovo documento, quindi aggiungi il seguente codice :
tell application "System Preferences"
set current pane to pane id "com.apple.preference.mouse"
--delay 0.5 -- # If necessary, uncomment 'delay' command and set its value in seconds and or decimal fractions there of.
tell application "System Events"
log "Scrolling speed is set to: " & value in (get properties of slider 1 of front window of application process "System Preferences")
log "Double-Click speed is set to: " & value in (get properties of slider 2 of front window of application process "System Preferences")
log "Tracking speed is set to: " & value in (get properties of slider 3 of front window of application process "System Preferences")
end tell
end tell
Ci saranno due stati di differenza nella direzione di scorrimento: la casella di controllo naturale in Preferenze di Sistema > Mouse , selezionata e deselezionata e la modifica delle impostazioni del dispositivo di scorrimento tra i due stati .
Il codice sopra verrà eseguito una volta per ottenere le impostazioni del valore corrente dei cursori . Quindi apporta le modifiche di impostazione che desideri ai cursori per lo stato opposto di quello che era quando hai raccolto i valori delle prime impostazioni per il primo stato . Quindi eseguire nuovamente il codice per ottenere le impostazioni differenziali.
Inserirai quindi i valori , raccolti sopra, nel codice seguente. Puoi commentare o rimuovere qualsiasi dispositivo di scorrimento che non verrà modificato dal codice seguente.
I commenti nel codice qui sotto dovrebbero essere adeguati, tuttavia, non esitare a chiedere se hai bisogno di qualcosa di spiegato.
Ho salvato il seguente codice AppleScript in Script Editor come un'applicazione denominata Toggle Mouse Settings nella cartella Applicazioni .
Quando eseguito, commuta lo stato della direzione di scorrimento: casella di controllo naturale tra selezionata e non selezionata insieme alle impostazioni del dispositivo di scorrimento in ogni stato .
Codice AppleScript per l' app Toggle Mouse Settings :
on run
try
tell application "System Preferences"
set current pane to pane id "com.apple.preference.mouse"
-- delay 0.5 -- # If necessary, uncomment 'delay' command and set its value in seconds and or decimal fractions there of.
tell application "System Events"
set isChecked to get value of checkbox 1 of front window of application process "System Preferences" as boolean
if isChecked then
-- # The 'Scroll direction: Natural' checkbox is checked, uncheck it.
set cbValue to value of (click checkbox 1 of front window of application process "System Preferences") as boolean
-- # Scrolling Speed - Valid Values: 0.0 to 8.0
set value of slider 1 of front window of application process "System Preferences" to 6.0
-- # Double-Click Speed - Valid Values: 0.0 to 10.0
set value of slider 2 of front window of application process "System Preferences" to 8.0
-- # Tracking Speed - Valid Values: 0.0 to 9.0
set value of slider 3 of front window of application process "System Preferences" to 6.0
else
-- # The 'Scroll direction: Natural' checkbox is not checked, check it.
set cbValue to value of (click checkbox 1 of front window of application process "System Preferences") as boolean
-- # Scrolling Speed - Valid Values: 0.0 to 8.0
set value of slider 1 of front window of application process "System Preferences" to 4.5
-- # Double-Click Speed - Valid Values: 0.0 to 10.0
set value of slider 2 of front window of application process "System Preferences" to 8.0
-- # Tracking Speed - Valid Values: 0.0 to 9.0
set value of slider 3 of front window of application process "System Preferences" to 4.0
end if
end tell
tell me
if cbValue then
display notification "Natural scrolling is now active." with title (name of me)
else
display notification "Natural scrolling is no longer active." with title (name of me)
end if
end tell
quit
end tell
on error eStr number eNum
activate
display dialog eStr & " number " & eNum buttons {"OK"} default button 1 with title "Toggle Mouse Settings" with icon caution
tell application "System Preferences" to quit
return
end try
end run
Nota: prima di eseguire l' app Toggle Mouse Settings , è necessario aggiungerla a: Preferenze di Sistema > Sicurezza e Privacy > Privacy > Accessibilità
Esiste un'app chiamata EventScripts che può essere utilizzata per attivare l'attivazione e la rimozione di un dispositivo USB. Non l'ho mai usato prima, solo consapevole che esiste.
C'è anche un'app chiamata Scroll Reverser . Non l'ho mai usato prima, solo consapevole che esiste.