Come posso iniziare il tethering Bluetooth usando la riga di comando?

Vorrei un modo rapido per iniziare il tethering usando il mio iPhone, speriamo solo usando la tastiera. Usando il menu bluetooth, posso scegliere l'opzione Connetti alla rete nel sottomenu del mio dispositivo, ma è possibile automatizzarlo?

Alla fine voglio assegnare questo a un collegamento in (il fantastico) Alfred.app, ma tutto ciò che utilizza la riga di comando o AppleScript funzionerà.

È possibile? Grazie!!

Non sembra che ci sia un dizionario AppleScript diretto per lavorare con Bluetooth in questo modo.

Tuttavia, è possibile utilizzare gli script della GUI, che fondamentalmente utilizza la funzionalità di accessibilità di Mac OS per selezionare voci di menu, ecc.

Un ottimo commento su come iniziare con la GUI AppleScript è disponibile su MacOSAutomation.com .

L'automazione della GUI può essere difficile se hai un elenco di cose in continua evoluzione, ma se di solito hai un elenco di elementi bluetooth collegati che rimane lo stesso, dovresti essere a posto.

È quindi possibile chiamare questo AppleScript tramite Alfred.

http://macscripter.net/viewtopic.php?id=38559

Nel link sopra c'è un bellissimo script che ho appena aggiornato un po '. Nota che usa blueutil [ git repo ] [ sito web / binari ].

Abilita Bluetooth:

-- Enable Bluetooth and Connect to iPhone

property blueutilPath : "/opt/local/bin/blueutil"

-- Turn on bluetooth.
if execBlueutil("status") contains "Status: off" then
    execBlueutil("on")

    connectDevice()

    doGrowl()

end if

on execBlueutil(command)
    set res to do shell script blueutilPath & " " & command
    if res contains "Error" then
        display dialog res
        quit
    end if
    return res
end execBlueutil

-- Connect Device
on connectDevice()
    tell application "System Preferences"
        activate
        set AppleScript's text item delimiters to "."
        set current pane to pane "com.apple.preference.network"
        set winNetwork to "Network"
        set btooth to "Bluetooth"

        tell application "System Events" to tell process "System Preferences"
            set theRow to row 1 of table 1 of scroll area 1 of window winNetwork whose value of static text 1 contains btooth
            select theRow --clicks the bluetooth row
            --If Bluetooth is already connected, the button will say Disconnect, so we don't want to turn it off:
            try
                click (button 1 of group 1 of window winNetwork whose title is "Connect")
            end try
        end tell
        tell application "System Preferences"
            quit
        end tell
    end tell
end connectDevice

on doGrowl()
    tell application "System Events"
        set isRunning to (count of (every process whose bundle identifier is "com.Growl.GrowlHelperApp")) > 0
    end tell
    if isRunning then
        tell application id "com.Growl.GrowlHelperApp"
            set the allNotificationsList to ¬
                {"Bluetooth Setting"}
            set the enabledNotificationsList to ¬
                {"Bluetooth Setting"}
            register as application ¬
                "AppleScript - Bluetooth" all notifications allNotificationsList ¬
                default notifications enabledNotificationsList

            notify with name ¬
                "Bluetooth Setting" title ¬
                "Bluetooth is On & iPhone Connected" description ¬
                "Bluetooth has been enabled with iPhone tethered." application name "AppleScript - Bluetooth" icon of file (path to me)
        end tell
    end if
end doGrowl

Disabilita bluetooth:

property blueutilPath : "/opt/local/bin/blueutil"

-- Turn off Bluetooth.
if execBlueutil("status") contains "Status: on" then
    execBlueutil("off")

    doGrowl()
end if
on execBlueutil(command)
    set res to do shell script blueutilPath & " " & command
    if res contains "Error" then
        display dialog res
        quit
    end if
    return res
end execBlueutil

on doGrowl()
    tell application "System Events"
        set isRunning to (count of (every process whose bundle identifier is "com.Growl.GrowlHelperApp")) > 0
    end tell
    if isRunning then
        tell application id "com.Growl.GrowlHelperApp"
            set the allNotificationsList to ¬
                {"Bluetooth Setting"}
            set the enabledNotificationsList to ¬
                {"Bluetooth Setting"}
            register as application ¬
                "AppleScript - Bluetooth" all notifications allNotificationsList ¬
                default notifications enabledNotificationsList

            notify with name ¬
                "Bluetooth Setting" title ¬
                "Bluetooth Off" description ¬
                "Bluetooth has been disabled." application name "AppleScript - Bluetooth" icon of file (path to me)
        end tell
    end if
end doGrowl

Consiglierei di usare l'automatore per questo, puoi chiamarlo da Alfred per renderlo facile :)

Il mio attuale flusso di lavoro dell'automatore fa questo:

Click the "bluetooth" menu bar item.
Connect to Network

Usando questo metodo puoi automatizzare quasi tutto in un minuto