Quando apro un file DMG, come faccio ad aprirlo davanti alle finestre?

Ogni volta che scarico un .dmgfile e poi lo apro (di solito dalla barra di download in Chrome), si apre in background. C'è un modo per farlo aprire davanti alla mia finestra?

modificare

Per chiarire: voglio che la finestra DMG venga visualizzata come finestra attiva.

Ho creato uno script Azione cartella in Applescript, che potrebbe fare esattamente quello che vuoi. Copialo e incollalo in un nuovo Applescript e salvalo come Applicazione (senza una finestra di dialogo iniziale!) In "/ Libreria / Script / Script azione cartella /". Puoi quindi collegarlo a qualsiasi cartella (molto probabilmente la tua ~ / Download / cartella) facendo clic con il pulsante destro del mouse sulla cartella e selezionando "configura azioni cartella" dal menu a discesa dei servizi. Attiva Azioni cartella e lascia che lo script guardi la cartella.

Ciò che lo script fa sostanzialmente è reagire agli oggetti rilasciati nella cartella a cui è collegato e se l'elemento rilasciato è di tipo: "Immagine", collega l'immagine come volume tramite lo strumento da riga di comando "hdiutil".

Puoi configurarne il comportamento impostando le proprietà openWindow e makeFrontmost nello Script; questo può essere fatto anche facendo doppio clic sullo script dopo averlo salvato come applicazione: in due dialoghi verrà quindi chiesto quale dovrebbe essere il comportamento standard.

Spero che aiuti,

Asmus

 property openWindow : true
 property makeFrontmost : true

 on run

    display dialog "Do you want to bring the Finder to the front after new items are added?" buttons {"Don't Activate", "Activate"} default button 2
    if the button returned of the result is "Don't Activate" then
        set makeFrontmost to false
    else
        set makeFrontmost to true
    end if


    display dialog "Open Folder after adding new files?" buttons {"Don't Open", "Open"} default button 2
    if the button returned of the result is "Don't Open" then
        set openWindow to false
    else
        set openWindow to true
    end if


 end run

 on adding folder items to thisFolder after receiving addedItems

    repeat with i from 1 to number of items in addedItems
        set itemKind to the kind of (info for item i of addedItems) as string

        if itemKind is "Disk Image" then
            set itemPath to (quoted form of POSIX path of item i of addedItems)
            try
                showImage(itemPath)
            end try
        end if

    end repeat

 end adding folder items to


 on showImage(itemPath)

    set volumeMountpointInfo to do shell script "/usr/bin/hdiutil  attach " & itemPath & " | grep Volumes"


    if (openWindow is true) then
        if (makeFrontmost is true) then
            tell application "Finder" to activate
        end if

       set currentDelim to text item delimiters
       set text item delimiters to tab

       set volumeMountpoint to POSIX file (text item 3 of volumeMountpointInfo)

       set text item delimiters to currentDelim

       tell application "Finder" to open folder volumeMountpoint

    end if

 end showImage

====

secondo Applescript per determinare il tipo di file rilasciato in una cartella

On adding folder items to thisFolder after receiving addedItems
repeat with i from 1 to number of items in addedItems
    set itemKind to the kind of (info for item i of addedItems) as string
    display dialog itemKind
end repeat
end adding folder items to

La modifica deve essere "Immagine disco" anziché "Immagine"

Da quello che posso dire, OS X mostrerà automaticamente il contenuto di un'immagine del disco solo se è di sola lettura. Questo è indicato da una matita con una barra in basso a sinistra nella finestra del Finder durante la visualizzazione del contenuto dell'immagine.

Se si desidera modificare un'immagine del disco in modo da farlo, è possibile creare un'immagine del disco esistente in sola lettura utilizzando Utility Disco. Sfortunatamente, questo non cambierà il comportamento delle immagini prodotte in modo errato che è possibile scaricare da Internet.

1. Montare l'immagine del disco che si desidera aprire automaticamente.
2. Apri Utility Disco cercandola con Spotlight.
3. Seleziona l'icona "Nuova immagine" nella barra degli strumenti.
4. Assegna un nome al file e seleziona "sola lettura" in "Formato immagine".
5. Fai clic su "Salva". Quando monti questa nuova immagine, si aprirà automaticamente una finestra del Finder.

Anche questo probabilmente non risponde sufficientemente alla domanda, ma ...

Se si preme il comando e si fa clic sull'elemento nella barra di download, viene visualizzato l'elemento nel Finder. A quel punto, semplicemente premendo command-O (o facendo doppio clic sul file dmg) lo monterà e lo aprirà in una nuova finestra in primo piano.