2.4 "TFT LCD Shield non funziona su Arduino Mega

9

Anche sul sito web di eBay si dice che non posso usare il display LCD TFT da 2,4 "per collegarmi ad Arduino Mega. Il problema è che ho comprato questo scudo per errore. Voglio mettere questo scudo su Arduino Mega 2560. C'è un modo di combinare Mega e 2.4 "Display Shield?

nota: ho provato Arduino Uno del mio amico. Shield funziona molto bene.

nota: la foto sotto sta determinando la mia domanda. Il display non esegue il mio codice Arduino. Funziona solo con il suo LED.

inserisci qui la descrizione dell'immagine

    // UTFT_Demo_320x240 (C)2012 Henning Karlsen
// web: http://www.henningkarlsen.com/electronics
//
// This program is a demo of how to use most of the functions
// of the library with a supported display modules.
//
// This demo was made for modules with a screen resolution 
// of 320x240 pixels.
//
// This program requires the UTFT library.
//

#include <UTFT.h>
#define ILI9320_16 18
// Declare which fonts we will be using
extern uint8_t SmallFont[];

// Uncomment the next line for Arduino 2009/Uno
//UTFT myGLCD(UNO_24,A2,A1,A3,A4);   // Remember to change the model parameter to suit your display module!

// Uncomment the next line for Arduino Mega
UTFT myGLCD(ILI9320_16,38,39,40,41);   // Remember to change the model parameter to suit your display module!

void setup()
{
  randomSeed(analogRead(0));

// Setup the LCD
  pinMode(A0,OUTPUT);       // for the UNO_SHIELD_1IN1
  digitalWrite(A0,HIGH);    // the RD pin must be set high
  myGLCD.InitLCD();
  myGLCD.setFont(SmallFont);
}

void loop()
{
  int buf[318];
  int x, x2;
  int y, y2;
  int r;

// Clear the screen and draw the frame
  myGLCD.clrScr();

  myGLCD.setColor(255, 0, 0);
  myGLCD.fillRect(0, 0, 319, 13);
  myGLCD.setColor(64, 64, 64);
  myGLCD.fillRect(0, 226, 319, 239);
  myGLCD.setColor(255, 255, 255);
  myGLCD.setBackColor(255, 0, 0);
  myGLCD.print("* Universal Color TFT Display Library *", CENTER, 1);
  myGLCD.setBackColor(64, 64, 64);
  myGLCD.setColor(255,255,0);
  myGLCD.print("<http://electronics.henningkarlsen.com>", CENTER, 227);

  myGLCD.setColor(0, 0, 255);
  myGLCD.drawRect(0, 14, 319, 225);

// Draw crosshairs
  myGLCD.setColor(0, 0, 255);
  myGLCD.setBackColor(0, 0, 0);
  myGLCD.drawLine(159, 15, 159, 224);
  myGLCD.drawLine(1, 119, 318, 119);
  for (int i=9; i<310; i+=10)
    myGLCD.drawLine(i, 117, i, 121);
  for (int i=19; i<220; i+=10)
    myGLCD.drawLine(157, i, 161, i);

// Draw sin-, cos- and tan-lines  
  myGLCD.setColor(0,255,255);
  myGLCD.print("Sin", 5, 15);
  for (int i=1; i<318; i++)
  {
    myGLCD.drawPixel(i,119+(sin(((i*1.13)*3.14)/180)*95));
  }

  myGLCD.setColor(255,0,0);
  myGLCD.print("Cos", 5, 27);
  for (int i=1; i<318; i++)
  {
    myGLCD.drawPixel(i,119+(cos(((i*1.13)*3.14)/180)*95));
  }

  myGLCD.setColor(255,255,0);
  myGLCD.print("Tan", 5, 39);
  for (int i=1; i<318; i++)
  {
    myGLCD.drawPixel(i,119+(tan(((i*1.13)*3.14)/180)));
  }

  delay(2000);

  myGLCD.setColor(0,0,0);
  myGLCD.fillRect(1,15,318,224);
  myGLCD.setColor(0, 0, 255);
  myGLCD.setBackColor(0, 0, 0);
  myGLCD.drawLine(159, 15, 159, 224);
  myGLCD.drawLine(1, 119, 318, 119);

// Draw a moving sinewave
  x=1;
  for (int i=1; i<(318*20); i++) 
  {
    x++;
    if (x==319)
      x=1;
    if (i>319)
    {
      if ((x==159)||(buf[x-1]==119))
        myGLCD.setColor(0,0,255);
      else
        myGLCD.setColor(0,0,0);
      myGLCD.drawPixel(x,buf[x-1]);
    }
    myGLCD.setColor(0,255,255);
    y=119+(sin(((i*1.1)*3.14)/180)*(90-(i / 100)));
    myGLCD.drawPixel(x,y);
    buf[x-1]=y;
  }

  delay(2000);

  myGLCD.setColor(0,0,0);
  myGLCD.fillRect(1,15,318,224);

// Draw some filled rectangles
  for (int i=1; i<6; i++)
  {
    switch (i)
    {
      case 1:
        myGLCD.setColor(255,0,255);
        break;
      case 2:
        myGLCD.setColor(255,0,0);
        break;
      case 3:
        myGLCD.setColor(0,255,0);
        break;
      case 4:
        myGLCD.setColor(0,0,255);
        break;
      case 5:
        myGLCD.setColor(255,255,0);
        break;
    }
    myGLCD.fillRect(70+(i*20), 30+(i*20), 130+(i*20), 90+(i*20));
  }

  delay(2000);

  myGLCD.setColor(0,0,0);
  myGLCD.fillRect(1,15,318,224);

// Draw some filled, rounded rectangles
  for (int i=1; i<6; i++)
  {
    switch (i)
    {
      case 1:
        myGLCD.setColor(255,0,255);
        break;
      case 2:
        myGLCD.setColor(255,0,0);
        break;
      case 3:
        myGLCD.setColor(0,255,0);
        break;
      case 4:
        myGLCD.setColor(0,0,255);
        break;
      case 5:
        myGLCD.setColor(255,255,0);
        break;
    }
    myGLCD.fillRoundRect(190-(i*20), 30+(i*20), 250-(i*20), 90+(i*20));
  }

  delay(2000);

  myGLCD.setColor(0,0,0);
  myGLCD.fillRect(1,15,318,224);

// Draw some filled circles
  for (int i=1; i<6; i++)
  {
    switch (i)
    {
      case 1:
        myGLCD.setColor(255,0,255);
        break;
      case 2:
        myGLCD.setColor(255,0,0);
        break;
      case 3:
        myGLCD.setColor(0,255,0);
        break;
      case 4:
        myGLCD.setColor(0,0,255);
        break;
      case 5:
        myGLCD.setColor(255,255,0);
        break;
    }
    myGLCD.fillCircle(100+(i*20),60+(i*20), 30);
  }

  delay(2000);

  myGLCD.setColor(0,0,0);
  myGLCD.fillRect(1,15,318,224);

// Draw some lines in a pattern
  myGLCD.setColor (255,0,0);
  for (int i=15; i<224; i+=5)
  {
    myGLCD.drawLine(1, i, (i*1.44)-10, 224);
  }
  myGLCD.setColor (255,0,0);
  for (int i=224; i>15; i-=5)
  {
    myGLCD.drawLine(318, i, (i*1.44)-11, 15);
  }
  myGLCD.setColor (0,255,255);
  for (int i=224; i>15; i-=5)
  {
    myGLCD.drawLine(1, i, 331-(i*1.44), 15);
  }
  myGLCD.setColor (0,255,255);
  for (int i=15; i<224; i+=5)
  {
    myGLCD.drawLine(318, i, 330-(i*1.44), 224);
  }

  delay(2000);

  myGLCD.setColor(0,0,0);
  myGLCD.fillRect(1,15,318,224);

// Draw some random circles
  for (int i=0; i<100; i++)
  {
    myGLCD.setColor(random(255), random(255), random(255));
    x=32+random(256);
    y=45+random(146);
    r=random(30);
    myGLCD.drawCircle(x, y, r);
  }

  delay(2000);

  myGLCD.setColor(0,0,0);
  myGLCD.fillRect(1,15,318,224);

// Draw some random rectangles
  for (int i=0; i<100; i++)
  {
    myGLCD.setColor(random(255), random(255), random(255));
    x=2+random(316);
    y=16+random(207);
    x2=2+random(316);
    y2=16+random(207);
    myGLCD.drawRect(x, y, x2, y2);
  }

  delay(2000);

  myGLCD.setColor(0,0,0);
  myGLCD.fillRect(1,15,318,224);

// Draw some random rounded rectangles
  for (int i=0; i<100; i++)
  {
    myGLCD.setColor(random(255), random(255), random(255));
    x=2+random(316);
    y=16+random(207);
    x2=2+random(316);
    y2=16+random(207);
    myGLCD.drawRoundRect(x, y, x2, y2);
  }

  delay(2000);

  myGLCD.setColor(0,0,0);
  myGLCD.fillRect(1,15,318,224);

  for (int i=0; i<100; i++)
  {
    myGLCD.setColor(random(255), random(255), random(255));
    x=2+random(316);
    y=16+random(209);
    x2=2+random(316);
    y2=16+random(209);
    myGLCD.drawLine(x, y, x2, y2);
  }

  delay(2000);

  myGLCD.setColor(0,0,0);
  myGLCD.fillRect(1,15,318,224);

  for (int i=0; i<10000; i++)
  {
    myGLCD.setColor(random(255), random(255), random(255));
    myGLCD.drawPixel(2+random(316), 16+random(209));
  }

  delay(2000);

  myGLCD.fillScr(0, 0, 255);
  myGLCD.setColor(255, 0, 0);
  myGLCD.fillRoundRect(80, 70, 239, 169);

  myGLCD.setColor(255, 255, 255);
  myGLCD.setBackColor(255, 0, 0);
  myGLCD.print("That's it!", CENTER, 93);
  myGLCD.print("Restarting in a", CENTER, 119);
  myGLCD.print("few seconds...", CENTER, 132);

  myGLCD.setColor(0, 255, 0);
  myGLCD.setBackColor(0, 0, 255);
  myGLCD.print("Runtime: (msecs)", CENTER, 210);
  myGLCD.printNumI(millis(), CENTER, 225);

  delay (10000);
}
arduino-mega  shields  lcd 
— Baia
fonte
1
L'annuncio eBay ha questa affermazione senza senso: "Questo scudo NON funziona con i Mega Arduinos ma sarà metà della velocità delle schede di tipo Uno a causa del modo in cui Mega riorganizza tutti i pin (non c'è modo di aggirare questo!) "Come può non funzionare contemporaneamente ed essere a metà velocità?
— Gwideman,
Stai usando la versione a 8 bit o 16 bit?
— LoneWolf,
Si dice codice per usare i pin 38-41 mentre si guarda l'immagine che lo scudo non si collega nemmeno ai pin 38-41. Stai anche definendo un modello lcd diverso per Mega rispetto a UNO. Prova a usare lo stesso codice di uno; cosìUTFT myGLCD(UNO_24,A2,A1,A3,A4);
— Gerben
Guardando la formulazione, sembra che non funzioni, ma alla fine avranno una libreria più lenta per farlo funzionare.

Risposte:

7

Mi è capitato di acquistare gli stessi schermi LCD qualche giorno fa, cercando una libreria per usarlo con una scheda MEGA 2560 che ho trovato https://github.com/Smoke-And-Wires/TFT-Shield-Example-Code che supporta schede UNO e MEGA .

L'uso è molto, semplice se vogliamo usarlo per MEGA , dovremmo cambiare l'intestazione #include "uno_24_shield.h"in SWTFT.cpp in#include "mega_24_shield.h"

Descrizione (utile per aggiungere il supporto per lo scudo in altre librerie):

L'incompatibilità deriva da diverse mappature delle porte per il pin-out di Arduino tra Mega e UNO.

in UNO LCD shield sarà collegato tramite:

+---------------+-----+-----+-----+-----+-----+-----+-----+-----+
| LCD Data Bit  |  7  |  6  |  5  |  4  |  3  |  2  |  1  |  0  |
+---------------+-----+-----+-----+-----+-----+-----+-----+-----+
| Digital pin # |  7  |  6  |  5  |  4  |  3  |  2  |  9  |  8  |
+---------------+-----+-----+-----+-----+-----+-----+-----+-----+
| Uno port/pin  | PD7 | PD6 | PD5 | PD4 | PD3 | PD2 | PB1 | PB0 |
+---------------+-----+-----+-----+-----+-----+-----+-----+-----+

in MEGA sarà collegato tramite:

+---------------+-----+-----+-----+-----+-----+-----+-----+-----+
| LCD Data Bit  |  7  |  6  |  5  |  4  |  3  |  2  |  1  |  0  |
+---------------+-----+-----+-----+-----+-----+-----+-----+-----+
| Digital pin # |  7  |  6  |  5  |  4  |  3  |  2  |  9  |  8  |
+---------------+-----+-----+-----+-----+-----+-----+-----+-----+
| MEGA port/pin | PH4 | PH3 | PE3 | PG5 | PE5 | PE4 | PH6 | PH5 |
+---------------+-----+-----+-----+-----+-----+-----+-----+-----+
— user3473830
fonte
1
DIO MIO!! FUNZIONA: D Per prima cosa scarico Arduino Enhanced Release 1.0.5 da qui: forum.arduino.cc/index.php/topic,118440.0.html Quindi ho aperto il tuo codice GitHub e poi scaricato. Apro swtft.cpp tramite il programma DevC / C ++ che ho scaricato prima. Cambio una riga con queste: #include "mega_24_shield.h", quindi carico il codice in Mega e ha funzionato. Ho solo messo il display LCD TFT da 2,4 "su MEGA, non ho fatto più niente di connessione. Ho solo messo lo scudo su Mega: D Dio ti salva: D Grazie molto speciale. L'errore è rimasto fermo per 6 mesi. Grazie.
— Baia
4

Un modo per procedere è creare un foglio di calcolo che mostri le posizioni dei pin utilizzate da questa scheda e i segnali di scudo di Arduino a cui si collegano. Accanto a questi, sono necessarie colonne che mostrano i segnali effettivi su ATMega2560 (per Mega2560) e ATMega328 (per Uno) a cui si collegano questi pin di schermatura. È possibile ottenere queste informazioni dai disegni schematici Uno e Mega2560.

In una rapida occhiata, sembra che i nomi dei pin di schermatura di Arduino per Uno e Mega siano gli stessi: ad esempio, il pin di schermatura '0' (zero digitale) si trova nella stessa posizione su entrambe le schede, e allo stesso modo per altri pin.

Tuttavia, su Uno digital-0 si collega alla porta ATMega328 D bit 0, mentre su Mega2560 si collega alla porta ATMega2560 E bit 0. E le cose diventano più ottuse con il digitale 2..7.

Ora, quando twiddling i singoli bit usando digitalWrite (pin, value), la libreria Arduino si occupa senza dubbio della traduzione nella porta / bit appropriata che deve essere impostata per il chip ATMega e la scheda Arduino in uso. Tuttavia, le librerie che utilizzano funzioni di livello inferiore (soprattutto se devono scrivere interi byte sulle porte, come una libreria LCD veloce) dovranno compiere i propri passi per effettuare questa traduzione.

Quindi ... il primo passo è determinare se esiste una libreria di driver LCD separata per Mega2560.

Quindi, verifica se la libreria che hai ha un codice di inizializzazione che dovrebbe determinare su quale scheda è in esecuzione (ed è la tua scheda inclusa?) O richiede di impostare un flag per dirgli quale scheda è in uso.

In mancanza di questo, si potrebbe creare un pasticcio di ponticelli o qualche altro schema di cablaggio a ponticello i segnali di Mega di ATmega2560 modo che è cablato come un Uno sarebbe. Non è chiaro che ciò sia possibile, dal momento che alcuni dei Port D di ATMega2560 non sono nemmeno collegati a un header.

Oppure potresti guardare il codice sorgente della libreria e vedere cosa sta realmente facendo e cosa dovrebbe fare diversamente per far funzionare i pin ATMega 2560 a cui si collega lo scudo.

— gwideman
fonte
0

Devi confrontare le funzioni dei pin tra il tuo Mega e quello del tuo amico. Quindi è necessario effettuare quei collegamenti elettrici. Ne parlo un po 'nella sezione "posizioni dei pin" della mia risposta qui .

Ciò richiede "l'hacking". Qualcosa deve essere fatto per reindirizzare quelle connessioni fisiche. Normalmente utilizzo uno scudo intermedio per tradurre i pin secondo necessità. C'era uno scudo appositamente realizzato per questo scopo ma non sono riuscito a trovarlo. Forse questo avrebbe funzionato ?

— Chris K
fonte
SPI non è un problema, come lo scudo sta usando D0-D7 immagine . Quali altre cose potrebbero influenzare questo?
— Pinguino anonimo
Utilizzando il nostro sito, riconosci di aver letto e compreso le nostre Informativa sui cookie e Informativa sulla privacy.
Licensed under cc by-sa 3.0 with attribution required.