Come aggiornare una variabile in un ISR usando i timer

Sto cercando di controllare la frequenza di Timer3 utilizzando un contatore. Il valore del contatore, dichiarato come volatile, viene incrementato nell'ISR e ogni secondo la somma viene mostrata nel loop principale e il valore resettato a zero.

Il timer è stato impostato correttamente. (Se scelgo un timer da 3Hz posso vedere il led che lampeggia)

Il problema

Il contatore non è incrementato. Ecco l'output:

Setup Completed
tick: 1
tick: 0
tick: 0
tick: 0

CODICE

volatile int cont = 0;

void setup()
{
  Serial.begin(9600);

  pinMode(13, OUTPUT);

  // Initialize Timer
  cli();          // disable global interrupts
  TCCR3A = 0;     // set entire TCCR3A register to 0
  TCCR3B = 0;     // same for TCCR3B

  // set compare match register to desired timer count: 800 Hz
  OCR3B = 20; // 800Hz 5; // 3 Hz
  // turn on CTC mode:
  TCCR3B |= (1 << WGM12);
  // Set CS10 and CS12 bits for 1024 prescaler:
  TCCR3B |= (1 << CS30) | (1 << CS32);
  // enable timer compare interrupt:
  TIMSK3 |= (1 << OCIE3B);
  // enable global interrupts:
  sei();

  Serial.println("Setup completed");
}

void loop()
{
  if (millis() % 1000 == 0)
  {
    Serial.print(" tick: ");
    Serial.println(cont);
    cont = 0;
  }
}

ISR(TIMER3_COMPB_vect)
{
  //digitalWrite(13, digitalRead(13) ^ 1);
  cont++;
}

EDIT Questo timer viene utilizzato per leggere un valore anlog da un accelerometro e memorizzarlo in un array di float. Ma al momento sono bloccato su questo problema di aggiornamento.

SOLUZIONE 1 Grazie a Gerben

volatile int cont = 0;

void setup()
{
  Serial.begin(9600);
  pinMode(13, OUTPUT);

  // Initialize Timer
  cli();          // disable global interrupts
  TCCR3A = 0;     // set entire TCCR3A register to 0
  TCCR3B = 0;     // same for TCCR3B

  // set compare match register to desired timer count: 800 Hz
  OCR3A = 20; // 20; //800Hz 5; // 3 Hz
  // turn on CTC mode:
  TCCR3B |= (1 << WGM32);
  // Set CS10 and CS12 bits for 1024 prescaler:
  TCCR3B |= (1 << CS30) | (1 << CS32);
  // enable timer compare interrupt:
  TIMSK3 |= (1 << OCIE3B);
  // enable global interrupts:
  sei();
  Serial.println("Setup completed");
}

void loop()
{
  delay(1000);
  Serial.println(cont);
  cont = 0;
}

ISR(TIMER3_COMPB_vect)
{
  cont++;
}

SOLUZIONE 2 Grazie a BrettM

volatile int cont = 0;

void setup()
{
  Serial.begin(9600);
  pinMode(13, OUTPUT);

  // Initialize Timer
  cli();          // disable global interrupts
  TCCR3A = 0;     // set entire TCCR3A register to 0
  TCCR3B = 0;     // same for TCCR3B

  // set compare match register to desired timer count: 800 Hz
  OCR3B =  20; //800Hz 5; // 3 Hz
  // turn on CTC mode:
  //TCCR3B |= (1 << WGM32);
  // Set CS10 and CS12 bits for 1024 prescaler:
  TCCR3B |= (1 << CS30) | (1 << CS32);
  // enable timer compare interrupt:
  TIMSK3 |= (1 << OCIE3B);
  // enable global interrupts:
  sei();
  Serial.println("Setup completed");
}

void loop()
{
  Serial.println(cont); 
  cont = 0;
  delay(1000);

}

ISR(TIMER3_COMPB_vect)
{
  TCNT3 = 0;
  cont++;
}

In modalità CTC il massimo è OCR3Ano OCR3B!

Dopodiché TIMSK3 |= (1 << OCIE3B);dovrebbe essere modificato anche in TIMSK3 |= (1 << OCIE3A);e ISR(TIMER3_COMPB_vect)inISR(TIMER3_COMPA_vect)

Per 3Hz, OCR3Adovrebbe essere 5208, non 20.

Tecnicamente TCCR3B |= (1 << WGM12);dovrebbe essereTCCR3B |= (1 << WGM32);

Sembra che la mia risposta a questa domanda sia stata precedentemente incompleta, grazie per aver sottolineato che la modalità CTC funziona solo con OCR3A Gerben. Mi scuso per non aver testato una risposta prima di pubblicarla.

Date le informazioni solo in questa domanda, la risposta di Gerben è completa, ma poiché l'altra domanda implica che non è possibile utilizzare OCR3A a causa della libreria Servo, aggiungerò un po '. (Ho anche modificato quella risposta)

puoi emulare il comportamento della modalità CTC impostando TCNT3 su 0 nella tua routine di interrupt. Ricorda di rimuovere la riga che attiva la modalità CTC nel tuo codice.

Ho testato il tuo codice con questo ISR:

ISR(TIMER3_COMPB_vect)
{
  TCNT3 = 0;
  cont++;
}

e questa configurazione dei registri del timer

OCR3B = 5208; // 800Hz 5; // 3 Hz
// Set CS10 and CS12 bits for 1024 prescaler:
TCCR3B |= (1 << CS30) | (1 << CS32);
// enable timer compare interrupt:
TIMSK3 |= (1 << OCIE3B);

Questo potrebbe essere un po 'meno preciso alle alte frequenze rispetto al CTC, non ne sono sicuro, ma a 3Hz ha funzionato perfettamente. Si noti che 5208 era il valore OCR corretto, non 20 (di nuovo grazie a Gerben).