codice macchina x86-64, 44 byte
(Lo stesso codice macchina funziona anche in modalità 32 bit.)
La risposta di @Daniel Schepler è stata un punto di partenza per questo, ma questa ha almeno una nuova idea algoritmica (non solo il golf migliore della stessa idea): i codici ASCII per 'B'( 1000010) e 'X'( 1011000) danno 16 e 2 dopo il mascheramento con0b0010010 .
Quindi dopo aver escluso decimale (cifra iniziale diversa da zero) e ottale (il carattere dopo '0'è inferiore a 'B'), possiamo semplicemente impostare base = c & 0b0010010e saltare nel ciclo delle cifre.
Callable con x86-64 System V as unsigned __int128 parse_cxx14_int(int dummy, const char*rsi); Estrai il valore di ritorno EDX dalla metà superiore del unsigned __int128risultato con tmp>>64.
.globl parse_cxx14_int
## Input: pointer to 0-terminated string in RSI
## output: integer in EDX
## clobbers: RAX, RCX (base), RSI (points to terminator on return)
parse_cxx14_int:
xor %eax,%eax # initialize high bits of digit reader
cdq # also initialize result accumulator edx to 0
lea 10(%rax), %ecx # base 10 default
lodsb # fetch first character
cmp $'0', %al
jne .Lentry2
# leading zero. Legal 2nd characters are b/B (base 2), x/X (base 16)
# Or NUL terminator = 0 in base 10
# or any digit or ' separator (octal). These have ASCII codes below the alphabetic ranges
lodsb
mov $8, %cl # after '0' have either digit, apostrophe, or terminator,
cmp $'B', %al # or 'b'/'B' or 'x'/'X' (set a new base)
jb .Lentry2 # enter the parse loop with base=8 and an already-loaded character
# else hex or binary. The bit patterns for those letters are very convenient
and $0b0010010, %al # b/B -> 2, x/X -> 16
xchg %eax, %ecx
jmp .Lentry
.Lprocessdigit:
sub $'0' & (~32), %al
jb .Lentry # chars below '0' are treated as a separator, including '
cmp $10, %al
jb .Lnum
add $('0'&~32) - 'A' + 10, %al # digit value = c-'A' + 10. we have al = c - '0'&~32.
# c = al + '0'&~32. val = m+'0'&~32 - 'A' + 10
.Lnum:
imul %ecx, %edx
add %eax, %edx # accum = accum * base + newdigit
.Lentry:
lodsb # fetch next character
.Lentry2:
and $~32, %al # uppercase letters (and as side effect,
# digits are translated to N+16)
jnz .Lprocessdigit # space also counts as a terminator
.Lend:
ret
I blocchi modificati rispetto alla versione di Daniel sono (per lo più) rientrati meno di altre istruzioni. Anche il ciclo principale ha il suo ramo condizionale in fondo. Questo si è rivelato essere un cambiamento neutrale perché nessuno dei due percorsi potrebbe cadere in cima ad esso, e ildec ecx / loop .Lentry idea di entrare nel ciclo si è rivelata non essere una vittoria dopo aver gestito l'ottale in modo diverso. Ma ha meno istruzioni all'interno del ciclo con il ciclo in forma idiomatica {} mentre struttura, quindi l'ho tenuto.
Il cablaggio di test C ++ di Daniel funziona invariato in modalità 64 bit con questo codice, che utilizza la stessa convenzione di chiamata della sua risposta a 32 bit.
g++ -Og parse-cxx14.cpp parse-cxx14.s &&
./a.out < tests | diff -u -w - tests.good
Disassemblaggio, inclusi i byte del codice macchina che rappresentano la risposta effettiva
0000000000000000 <parse_cxx14_int>:
0: 31 c0 xor %eax,%eax
2: 99 cltd
3: 8d 48 0a lea 0xa(%rax),%ecx
6: ac lods %ds:(%rsi),%al
7: 3c 30 cmp $0x30,%al
9: 75 1c jne 27 <parse_cxx14_int+0x27>
b: ac lods %ds:(%rsi),%al
c: b1 08 mov $0x8,%cl
e: 3c 42 cmp $0x42,%al
10: 72 15 jb 27 <parse_cxx14_int+0x27>
12: 24 12 and $0x12,%al
14: 91 xchg %eax,%ecx
15: eb 0f jmp 26 <parse_cxx14_int+0x26>
17: 2c 10 sub $0x10,%al
19: 72 0b jb 26 <parse_cxx14_int+0x26>
1b: 3c 0a cmp $0xa,%al
1d: 72 02 jb 21 <parse_cxx14_int+0x21>
1f: 04 d9 add $0xd9,%al
21: 0f af d1 imul %ecx,%edx
24: 01 c2 add %eax,%edx
26: ac lods %ds:(%rsi),%al
27: 24 df and $0xdf,%al
29: 75 ec jne 17 <parse_cxx14_int+0x17>
2b: c3 retq
Altre modifiche rispetto alla versione di Daniel includono il salvataggio sub $16, %alall'interno del ciclo delle cifre, usando più subinvece che testcome parte del rilevamento di separatori e cifre rispetto a caratteri alfabetici.
A differenza di Daniel, ogni personaggio in basso '0'è trattato come un separatore, non solo '\''. (Tranne ' ': and $~32, %al/ jnzin entrambi i nostri loop considera lo spazio come un terminatore, che è probabilmente conveniente per il test con un numero intero all'inizio di una riga.)
Ogni operazione che si modifica %alall'interno del ciclo ha un flag che consuma un ramo impostato dal risultato e ogni ramo va (o cade) in una posizione diversa.
