SQL Server 2008 R2 Ripristina COPY_ONLY backup completo con registri delle transazioni

11

Dopo aver fatto qualche ricerca, non riesco a trovare una risposta a questa domanda.

Contesto Sto tentando di impostare un piano di backup che soddisfi i seguenti tre requisiti:

  1. Affidabilità dei backup, con backup completi notturni
  2. Backup del registro delle transazioni da cui è possibile ripristinare
  3. Bassa quantità di spazio su disco utilizzata
  4. I backup devono essere accessibili localmente per uno strumento di controllo

Quindi per soddisfare queste esigenze sto pensando a backup completi settimanali, differenziali giornalieri e transazioni orarie. Quindi ogni notte verrebbe eseguito un backup copy_only che può essere spedito fuori sede, questo backup viene eseguito in modo che la catena di registro non venga interrotta e abbiamo backup completi notturni affidabili fuori sede, senza dover consumare così tanto spazio su disco locale.

Domanda È possibile ripristinare dal backup copy_only e ripristinare successivamente i registri delle transazioni.

Lasciami fare un esempio in modo da sapere di cosa sto parlando.

Utilizzando l'elenco seguente mi chiedo se è possibile ripristinare FullbackupCOPY_ONLYC.bak seguito da TransactionbackupG.trn, TransactionbackupH.trn, infine TransactionbackupI.trn

> ---List of Backups---   
FullbackupA.bak 01/01/2013 00:00:00   
>  DifferntialbackupA.bak 02/01/2013 00:00:00 
FullbackupCOPY_ONLYA.bak 02/01/2013 00:00:00
>     TransactionbackupA.trn 02/01/2013 01:00:00
>     TransactionbackupB.trn 02/01/2013 02:00:00
>     TransactionbackupC.trn 02/01/2013 03:00:00
>  DifferntialbackupB.bak 03/01/2013 00:00:00 
FullbackupCOPY_ONLYB.bak 03/01/2013 00:00:00
>     TransactionbackupD.trn 03/01/2013 01:00:00
>     TransactionbackupE.trn 03/01/2013 02:00:00
>     TransactionbackupF.trn 03/01/2013 03:00:00
>  DifferntialbackupC.bak 04/01/2013 00:00:00 
FullbackupCOPY_ONLYC.bak 04/01/2013 00:00:00
>     TransactionbackupG.trn 04/01/2013 01:00:00
>     TransactionbackupH.trn 04/01/2013 02:00:00
>     TransactionbackupI.trn 04/01/2013 03:00:00

Forse questa intera installazione non è ragionevole Sono abbastanza nuovo per SQL Server e sto cercando di imparare mentre vado. Qualsiasi consiglio / aiuto sarebbe apprezzato.

sql-server-2008  backup  transaction-log 
— dv10t
fonte

Risposte:

14

Un backup completo in SQL Server 2008 non interrompe la catena di log. Reimposta solo il differenziale base-lsn.

È inoltre possibile ripristinare i backup del registro solo dopo il ripristino da una copia. Il seguente script dimostra che:

CREATE DATABASE BakTst13;
GO
ALTER DATABASE BakTst13 SET RECOVERY FULL;
GO
USE BakTst13;
GO
CREATE TABLE dbo.tst(id INT IDENTITY(1,1));
GO
INSERT INTO dbo.tst DEFAULT VALUES
GO 10
GO
BACKUP DATABASE BakTst13 
TO DISK = 'BakTst13_Full_1' WITH INIT,FORMAT;
GO
INSERT INTO dbo.tst DEFAULT VALUES
GO 10
GO
BACKUP LOG BakTst13 
TO DISK = 'BakTst13_Log_1' WITH INIT,FORMAT;
GO
INSERT INTO dbo.tst DEFAULT VALUES
GO 10
GO
BACKUP DATABASE BakTst13 
TO DISK = 'BakTst13_Full_2' WITH INIT,FORMAT;
GO
INSERT INTO dbo.tst DEFAULT VALUES
GO 10
GO
BACKUP DATABASE BakTst13 
TO DISK = 'BakTst13_Full_C' WITH COPY_ONLY,INIT,FORMAT;
GO
INSERT INTO dbo.tst DEFAULT VALUES
GO 10
GO
BACKUP LOG BakTst13 
TO DISK = 'BakTst13_Log_2' WITH INIT,FORMAT;
GO
USE tempdb;
GO
DROP DATABASE BakTst13;
GO
RESTORE DATABASE BakTst13 FROM DISK='BakTst13_Full_1' WITH NORECOVERY;
RESTORE LOG BakTst13 FROM DISK='BakTst13_Log_1' WITH NORECOVERY;
RESTORE LOG BakTst13 FROM DISK='BakTst13_Log_2' WITH RECOVERY;
GO
SELECT * FROM BakTst13.dbo.tst;
GO
DROP DATABASE BakTst13;
GO
RESTORE DATABASE BakTst13 FROM DISK='BakTst13_Full_C' WITH NORECOVERY;
RESTORE LOG BakTst13 FROM DISK='BakTst13_Log_2' WITH RECOVERY;
GO
SELECT * FROM BakTst13.dbo.tst;
GO
DROP DATABASE BakTst13;

Crea un database e una tabella e inserisce 50 righe in quella tabella. Tra questi inserti vengono eseguiti diversi backup in questo ordine:

  1. Pieno
  2. Login
  3. Pieno
  4. Copia completa_Solo
  5. Login

Successivamente il database viene rilasciato e ripristinato in questo modo:

  1. 1o pieno
  2. 1 ° registro
  3. 2 ° registro

Quanto segue SELECTdimostra che il ripristino ha avuto esito positivo.

Ciò dimostra che né un COP_ONLYbackup completo né un normale interrompono la catena di registro.

Quindi il database viene nuovamente rilasciato e ripristinato in questo modo:

  1. Copia_Solo pieno
  2. 2 ° registro

Successivamente il SELECTsuccesso dimostra ancora.

Ciò dimostra che è possibile utilizzare un COPY_ONLYbackup completo come base del Log Restore.

Test differenziali

Ho creato anche una DIFFERENTIALversione:

CREATE DATABASE BakTst13;
GO
ALTER DATABASE BakTst13 SET RECOVERY FULL;
GO
USE BakTst13;
GO
CREATE TABLE dbo.tst(id INT IDENTITY(1,1));
GO
INSERT INTO dbo.tst DEFAULT VALUES
GO 10
GO
BACKUP DATABASE BakTst13 
TO DISK = 'BakTst13_Full_1' WITH INIT,FORMAT;
GO
INSERT INTO dbo.tst DEFAULT VALUES
GO 10
GO
BACKUP DATABASE BakTst13 
TO DISK = 'BakTst13_Diff_1' WITH DIFFERENTIAL,INIT,FORMAT;
GO
INSERT INTO dbo.tst DEFAULT VALUES
GO 10
GO
BACKUP DATABASE BakTst13 
TO DISK = 'BakTst13_Full_2' WITH INIT,FORMAT;
GO
INSERT INTO dbo.tst DEFAULT VALUES
GO 10
GO
BACKUP DATABASE BakTst13 
TO DISK = 'BakTst13_Diff_2' WITH DIFFERENTIAL,INIT,FORMAT;
GO
INSERT INTO dbo.tst DEFAULT VALUES
GO 10
GO
BACKUP DATABASE BakTst13 
TO DISK = 'BakTst13_Full_C' WITH COPY_ONLY,INIT,FORMAT;
GO
INSERT INTO dbo.tst DEFAULT VALUES
GO 10
GO
BACKUP DATABASE BakTst13 
TO DISK = 'BakTst13_Diff_3' WITH DIFFERENTIAL,INIT,FORMAT;
GO
USE tempdb;
GO
DROP DATABASE BakTst13;
GO
RAISERROR('------> Starting restore F1, D1, D2',0,1)WITH NOWAIT;
RESTORE DATABASE BakTst13 FROM DISK='BakTst13_Full_1' WITH NORECOVERY; 
RESTORE DATABASE BakTst13 FROM DISK='BakTst13_Diff_1' WITH NORECOVERY;
RESTORE DATABASE BakTst13 FROM DISK='BakTst13_Diff_2' WITH NORECOVERY;--<--Fails!
GO
DROP DATABASE BakTst13;
GO
RAISERROR('------> Starting restore FC, D3',0,1)WITH NOWAIT;
RESTORE DATABASE BakTst13 FROM DISK='BakTst13_Full_C' WITH NORECOVERY;
RESTORE DATABASE BakTst13 FROM DISK='BakTst13_Diff_3' WITH NORECOVERY;--<--Fails!
GO
DROP DATABASE BakTst13;
GO
RAISERROR('------> Starting restore F2, D2, D3',0,1)WITH NOWAIT;
RESTORE DATABASE BakTst13 FROM DISK='BakTst13_Full_2' WITH NORECOVERY; 
RESTORE DATABASE BakTst13 FROM DISK='BakTst13_Diff_2' WITH NORECOVERY;
RESTORE DATABASE BakTst13 FROM DISK='BakTst13_Diff_3' WITH RECOVERY;
GO
SELECT * FROM BakTst13.dbo.tst;
GO
DROP DATABASE BakTst13;

Questo richiede i backup in questo ordine:

  1. 1o pieno
  2. 1 ° differenziale
  3. 2 ° pieno
  4. 2o differenziale
  5. Copy_Only Diff
  6. 3o differenziale

Prova quindi questa route di ripristino:

  1. 1o pieno
  2. 1 ° differenziale
  3. 2o differenziale

Il passaggio 3 ha esito negativo con questo errore:

Msg 3136, Level 16, State 1, Line 4
This differential backup cannot be restored because the database has not been restored to the correct earlier state.

Ciò dimostra che un normale backup completo interrompe la catena differenziale.

Successivamente il database viene eliminato e viene tentato questo flusso di ripristino:

  1. Copia_Solo pieno
  2. 3o differenziale

Il passaggio 2 ha esito negativo con lo stesso errore del passaggio 3 sopra. Ciò dimostra che un backup solo copia non può essere utilizzato come base per un ripristino differenziale.

Quindi il database viene nuovamente eliminato e viene eseguito il seguente ripristino:

  1. 2 ° pieno
  2. 2o differenziale
  3. 3o differenziale

La seguente selezione dimostra che questo ripristino ha avuto esito positivo. Ciò dimostra che un COPY_ONLYbackup completo non interrompe la catena differenziale.

— Sebastian Meine
fonte
Stavo cercando informazioni sull'opportunità di applicare un registro delle transazioni a un backup completo di copy_only. Questa è veramente una buona informazione!
— Brain2000,
2

Ecco cosa succede quando sono coinvolti i differenziali:

CREATE DATABASE BakTst13;
GO
ALTER DATABASE BakTst13 SET RECOVERY FULL;
GO
USE BakTst13;
GO
CREATE TABLE dbo.tst(id INT IDENTITY(1,1));
GO
INSERT INTO dbo.tst DEFAULT VALUES
GO 10 -- 10 rows so far
GO
BACKUP DATABASE BakTst13 
TO DISK = 'BakTst13_Full_1' WITH INIT,FORMAT;
GO
INSERT INTO dbo.tst DEFAULT VALUES
GO 10 -- 20 rows so far
GO
BACKUP DATABASE BakTst13 
TO DISK = 'BakTst13_Diff_1' WITH INIT,FORMAT,DIFFERENTIAL
GO
INSERT INTO dbo.tst DEFAULT VALUES
GO 10 -- 30 rows so far
BACKUP LOG BakTst13 
TO DISK = 'BakTst13_Log_1' WITH INIT,FORMAT;
GO
INSERT INTO dbo.tst DEFAULT VALUES
GO 10 -- 40 rows so far
GO
BACKUP DATABASE BakTst13 
TO DISK = 'BakTst13_Full_2' WITH INIT,FORMAT;
GO
INSERT INTO dbo.tst DEFAULT VALUES
GO 10 -- 50 rows so far
GO
BACKUP DATABASE BakTst13 
TO DISK = 'BakTst13_Full_C' WITH COPY_ONLY,INIT,FORMAT;
GO
INSERT INTO dbo.tst DEFAULT VALUES
GO 10 -- 60 rows so far
GO
BACKUP DATABASE BakTst13 
TO DISK = 'BakTst13_Diff_2' WITH INIT,FORMAT,DIFFERENTIAL
GO
INSERT INTO dbo.tst DEFAULT VALUES
GO 10 -- 70 rows so far
GO
BACKUP LOG BakTst13 
TO DISK = 'BakTst13_Log_2' WITH INIT,FORMAT;
GO


USE tempdb;
GO
DROP DATABASE BakTst13;
GO
RESTORE DATABASE BakTst13 FROM DISK='BakTst13_Full_2' WITH NORECOVERY;
RESTORE DATABASE BakTst13 FROM DISK='BakTst13_Diff_2' WITH NORECOVERY;
RESTORE LOG BakTst13 FROM DISK='BakTst13_Log_2' WITH RECOVERY;
GO
SELECT COUNT(*) FROM BakTst13.dbo.tst; -- Must be 70: log chain not broken
GO
DROP DATABASE BakTst13;
GO
RESTORE DATABASE BakTst13 FROM DISK='BakTst13_Full_C' WITH NORECOVERY;
RESTORE LOG BakTst13 FROM DISK='BakTst13_Log_2' WITH RECOVERY;
GO
SELECT COUNT(*) FROM BakTst13.dbo.tst; -- Must be 70
GO
DROP DATABASE BakTst13;

In una parola: sì, è possibile utilizzare un COPY_ONLYbackup per ripristinare ulteriori backup del registro. Quello che non puoi fare è usare il COPY_ONLYbackup come base differenziale. Ciò significa che non sarà possibile ripristinare alcun backup differenziale sul backup ripristinato COPY_ONLY:

DROP DATABASE BakTst13;
GO
RESTORE DATABASE BakTst13 FROM DISK='BakTst13_Full_C' WITH NORECOVERY;
RESTORE DATABASE BakTst13 FROM DISK='BakTst13_Diff_2' WITH NORECOVERY;

Se provi questo, otterrai un errore:

Processed 160 pages for database 'BakTst13', file 'BakTst13' on file 1.
Processed 2 pages for database 'BakTst13', file 'BakTst13_log' on file 1.
RESTORE DATABASE successfully processed 162 pages in 0.009 seconds (139.811 MB/sec).
Msg 3136, Level 16, State 1, Line 2
This differential backup cannot be restored because the database has not been restored to the correct earlier state.
Msg 3013, Level 16, State 1, Line 2
RESTORE DATABASE is terminating abnormally.

I backup differenziali possono essere difficili da capire e possono ingannare anche DBA esperti.

— spaghettidba
fonte
Utilizzando il nostro sito, riconosci di aver letto e compreso le nostre Informativa sui cookie e Informativa sulla privacy.
Licensed under cc by-sa 3.0 with attribution required.