Come trasporre due argomenti di una funzione in Python?

Come posso scambiare due argomenti in una chiamata a una funzione Python?

Se inserissi pointlo spazio tra questi due argomenti:

self.assertEqual(json.loads(some.data), json_data)

e poi M-t( transpose-words), ottengo:

self.assertEqual(json.loads(some.json), data_data)

D'altra parte con CMt ( transpose-sexps) ottengo:

self.assertEqual(json.loadsjson_data, (some.data))

Quello che voglio è:

self.assertEqual(json_data, json.loads(some.data))

C'è un comando che lo farà?

Questo è qualcosa che anch'io volevo avere da molto tempo, e qui ho trovato un po 'di motivazione per lavorarci su. Probabilmente non è molto robusto, ma al primo tentativo sembra coprire i casi che ho provato:

(defun my/calculate-stops ()
  (save-excursion
    (let ((start
           (condition-case e
               (while t (backward-sexp))
             (error (point))))
          stops)
      (push start stops)
      (condition-case e
          (while t
            (forward-sexp)
            (when (looking-at "\\s-*,")
              (push (point) stops)))
        (error (push (point) stops)))
      (nreverse stops))))

(defun my/transpose-args ()
  (interactive)
  (when (looking-at "\\s-") (backward-sexp))
  (cl-loop with p = (point)
           with previous = nil
           for stop on (my/calculate-stops)
           for i upfrom 0
           when (<= p (car stop)) do
           (when previous
             (let* ((end (cadr stop))
                    (whole (buffer-substring previous end))
                    middle last)
               (delete-region previous end)
               (goto-char previous)
               (setf middle (if (> i 1) (- (car stop) previous)
                              (string-match "[^, \\t]" whole 
                                            (- (car stop) previous)))
                     last (if (> i 1) (substring whole 0 middle)
                            (concat (substring whole (- (car stop) previous) middle)
                                    (substring whole 0 (- (car stop) previous)))))
               (insert (substring whole middle) last)))
           (cl-return)
           end do (setf previous (car stop))))

Uso una variante di transpose-sexpsciò che cerca il caso che descrivi e traspone le cose separate da virgole, o semplicemente fa regolarmente transpose-sexps. Inoltre lascia il cursore in posizione invece di trascinarlo in avanti, il che è un po 'diverso ma personalmente mi piace.

(defun my-transpose-sexps ()
  "If point is after certain chars transpose chunks around that.
Otherwise transpose sexps."
  (interactive "*")
  (if (not (looking-back "[,]\\s-*" (point-at-bol)))
      (progn (transpose-sexps 1) (forward-sexp -1))
    (let ((beg (point)) end rhs lhs)
      (while (and (not (eobp))
                  (not (looking-at "\\s-*\\([,]\\|\\s)\\)")))
        (forward-sexp 1))
      (setq rhs (buffer-substring beg (point)))
      (delete-region beg (point))
      (re-search-backward "[,]\\s-*" nil t)
      (setq beg (point))
      (while (and (not (bobp))
                  (not (looking-back "\\([,]\\|\\s(\\)\\s-*" (point-at-bol))))
        (forward-sexp -1))
      (setq lhs (buffer-substring beg (point)))
      (delete-region beg (point))
      (insert rhs)
      (re-search-forward "[,]\\s-*" nil t)
      (save-excursion
        (insert lhs)))))

Nelle modalità che usano SMIE, transpose-sexpdovrebbero funzionare correttamente per quel caso. Falliranno comunque quando il simbolo infisso (aka "separatore") non è un ,(o un ;) ma è una parola (ad es and.).

Quindi, la mia opinione è che il comando per quello è transpose-sexpe quando questo non funziona correttamente, lo considero un bug (ma un bug che può essere difficile e / o richiedere del tempo per risolvere e avere bassa priorità, quindi non trattenere il respiro). Il modo per risolverlo è impostare forward-sexp-functionuna funzione che sappia che "dopo che vedo una virgola, faccio un salto sull'intero argomento".