Emacs consigli vincolati

Vorrei sostituire temporaneamente una funzione in un pezzo di codice.

Prendi ad esempio quanto segue:

(defun nadvice/load-quiet (args)
  (cl-destructuring-bind
      (file &optional noerror nomessage nosuffix must-suffix)
      args
    (list file noerror t nosuffix must-suffix)))

(defun nadvice/idle-require-quiet (old-fun &rest args)
    (advice-add 'load :filter-args #'nadvice/load-quiet)
    (apply old-fun args)
    (advice-remove #'load #'nadvice/load-quiet))

(advice-add 'idle-require-load-next :around #'nadvice/idle-require-quiet)

Cosa non funziona:

• Questo. Sarebbe molto più pulito se potessi evitare di abilitare e disabilitare manualmente i consigli e fidarmi della natura a thread singolo di Emacs per occuparsi delle cose.
• cl-letfnon mi permette di fare riferimento alla funzione originale, quindi non posso implementare cose che :filter-argsnormalmente farebbero.
• cl-flet impossibile ignorare le funzioni in altre funzioni.
• nofletè un pacchetto esterno, che vorrei evitare. (Fa anche molto più del necessario)

Non potresti usare (cl-)letffacendo riferimento alla funzione originale tu stesso?

Qualcosa come questo:

;; Original function
(defun my-fun (arg)
  (message "my-fun (%s)" arg))


;; Standard call
(my-fun "arg") ;; => my-fun (arg)


;; Temporary overriding (more or less like an around advice)
(let ((orig-fun (symbol-function 'my-fun)))
  (letf (((symbol-function 'my-fun)
          (lambda (arg)
            ;; filter arguments
            (funcall orig-fun (concat "modified-" arg)))))
    (my-fun "arg")))
;; => my-fun (modified-arg)


;; The overriding was only temporary
(my-fun "arg") ;; => my-fun (arg)

Puoi anche racchiuderlo in una macro se prevedi di riutilizzarlo:

(defmacro with-advice (args &rest body)
  (declare (indent 1))
  (let ((fun-name (car args))
        (advice   (cadr args))
        (orig-sym (make-symbol "orig")))
    `(cl-letf* ((,orig-sym  (symbol-function ',fun-name))
                ((symbol-function ',fun-name)
                 (lambda (&rest args)
                   (apply ,advice ,orig-sym args))))
       ,@body)))

L'esempio sopra può quindi essere riscritto come segue:

(defun my-fun (arg)
  (message "my-fun (%s)" arg))


(my-fun "my-arg")

(with-advice (my-fun
              (lambda (orig-fun arg)
                (funcall orig-fun (concat "modified-" arg))))
  (my-fun "my-arg"))

(my-fun "my-arg")