Modo per nascondere i delimitatori di blocchi SRC

13

c'è un modo per mantenere solo il codice sorgente all'interno del codice sorgente, ovvero rendere invisibili # + BEGIN_SRC e # + END_SRC? È cosmetico ma rende le cose più chiare quando si ha a che fare con molti frammenti di codici brevi. Per esempio:

(defun org-xor (a b)
          "Exclusive or."
          (if a (not b) b))

invece di :

  #+BEGIN_SRC emacs-lisp
       (defun org-xor (a b)
          "Exclusive or."
          (if a (not b) b))
  #+END_SRC

org-mode

— loukios
fonte

Il mio commento sotto la domanda in questo thread semi-correlato mostra come nascondere a livello di programmazione le intestazioni / i piè di pagina del blocco sorgente. emacs.stackexchange.com/q/26163/2287 - vale a dire,

(save-excursion (goto-char (point-max)) (while (re-search-backward "#\\+BEGIN_SRC\\|#\\+END_SRC" nil t) (let ((ov (make-overlay (line-beginning-position) (1+ (line-end-position))))) (overlay-put ov 'invisible t))))

per scoprire tutto, usa (remove-overlays). È necessario lavorare ulteriormente per le singole voci e rimuovere solo gli overlay selezionati (anziché tutti gli overlay), ma questa è l'idea generale.

— elenco delle leggi

Grazie, è interessante ... Ci giocherò.

— loukios,

5

#+Viene chiamato il volto di tutte le linee che iniziano con org-meta-line.

Puoi personalizzare questo viso più piccolo, più scuro, ecc. Per renderlo meno visibile.

— Juancho
fonte

Infatti. Ad esempio, l'ho configurato usando (set-face-attribute 'org-meta-line nil :height 0.8 :slant 'normal). Trovo che aiuti parecchio.

— Harald Hanche-Olsen,

Grazie per la tua risposta, aiuta. Ho cambiato l'altezza tra i due ma non ha alcun effetto ...

— loukios

Guarda questa documentazione di Emacs Lisp sulle opzioni che puoi assegnare a org-meta-line gnu.org/software/emacs/manual/html_node/elisp/…

— salotz

4

Uso il seguente pezzo di codice che va in qualche modo. Non è perfetto Forse un minor-modegiorno diventerà un vero e proprio . ( fonte ).

(with-eval-after-load 'org
  (defvar-local rasmus/org-at-src-begin -1
    "Variable that holds whether last position was a ")

  (defvar rasmus/ob-header-symbol ?☰
    "Symbol used for babel headers")

  (defun rasmus/org-prettify-src--update ()
    (let ((case-fold-search t)
          (re "^[ \t]*#\\+begin_src[ \t]+[^ \f\t\n\r\v]+[ \t]*")
          found)
      (save-excursion
        (goto-char (point-min))
        (while (re-search-forward re nil t)
          (goto-char (match-end 0))
          (let ((args (org-trim
                       (buffer-substring-no-properties (point)
                                                       (line-end-position)))))
            (when (org-string-nw-p args)
              (let ((new-cell (cons args rasmus/ob-header-symbol)))
                (cl-pushnew new-cell prettify-symbols-alist :test #'equal)
                (cl-pushnew new-cell found :test #'equal)))))
        (setq prettify-symbols-alist
              (cl-set-difference prettify-symbols-alist
                                 (cl-set-difference
                                  (cl-remove-if-not
                                   (lambda (elm)
                                     (eq (cdr elm) rasmus/ob-header-symbol))
                                   prettify-symbols-alist)
                                  found :test #'equal)))
        ;; Clean up old font-lock-keywords.
        (font-lock-remove-keywords nil prettify-symbols--keywords)
        (setq prettify-symbols--keywords (prettify-symbols--make-keywords))
        (font-lock-add-keywords nil prettify-symbols--keywords)
        (while (re-search-forward re nil t)
          (font-lock-flush (line-beginning-position) (line-end-position))))))

  (defun rasmus/org-prettify-src ()
    "Hide src options via `prettify-symbols-mode'.

  `prettify-symbols-mode' is used because it has uncollpasing. It's
  may not be efficient."
    (let* ((case-fold-search t)
           (at-src-block (save-excursion
                           (beginning-of-line)
                           (looking-at "^[ \t]*#\\+begin_src[ \t]+[^ \f\t\n\r\v]+[ \t]*"))))
      ;; Test if we moved out of a block.
      (when (or (and rasmus/org-at-src-begin
                     (not at-src-block))
                ;; File was just opened.
                (eq rasmus/org-at-src-begin -1))
        (rasmus/org-prettify-src--update))
      ;; Remove composition if at line; doesn't work properly.
      ;; (when at-src-block
      ;;   (with-silent-modifications
      ;;     (remove-text-properties (match-end 0)
      ;;                             (1+ (line-end-position))
      ;;                             '(composition))))
      (setq rasmus/org-at-src-begin at-src-block)))

  (defun rasmus/org-prettify-symbols ()
    (mapc (apply-partially 'add-to-list 'prettify-symbols-alist)
          (cl-reduce 'append
                     (mapcar (lambda (x) (list x (cons (upcase (car x)) (cdr x))))
                             `(("#+begin_src" . ?✎) ;; ➤ 🖝 ➟ ➤ ✎
                               ("#+end_src"   . ?□) ;; ⏹
                               ("#+header:" . ,rasmus/ob-header-symbol)
                               ("#+begin_quote" . ?»)
                               ("#+end_quote" . ?«)))))
    (turn-on-prettify-symbols-mode)
    (add-hook 'post-command-hook 'rasmus/org-prettify-src t t))
  (add-hook 'org-mode-hook #'rasmus/org-prettify-symbols))

— rasmus
fonte