Inserimento automatico degli ultimi valori usati in apice / apice nelle formule matematiche

Uso AUCTeX per impostare testi matematici. Spesso devo digitare equazioni con somme, integrali ecc. Che hanno tutti gli stessi sottotitoli o apici. Vorrei riempire automaticamente l'attuale sottotitolo / apice con il valore che aveva prima. Esempio:

\sum_{i=1}^{\infty} a_i = \sum…

Quando premo _sull'equazione sopra, Emacs dovrebbe scrivere _{i=1}. Opzionale sarebbe utile se anche il secondo apice fosse compilato.

Come può essere realizzato?

Aggiungi al tuo file init:

(defvar mg-TeX-insert-subscript-history nil)
(defvar mg-TeX-insert-superscript-history nil)

(defun TeX-insert-sub-or-superscript (arg)
  "Insert typed key ARG times and possibly a pair of braces.
Brace insertion is only done if point is in a math construct and
`TeX-electric-sub-and-superscript' has a non-nil value."
  (interactive "*p")
  (self-insert-command arg)
  (when (and TeX-electric-sub-and-superscript (texmathp))
    (let* ((history (cond
             ((equal last-input-event ?_)
              'mg-TeX-insert-subscript-history)
             ((equal last-input-event ?^)
              'mg-TeX-insert-superscript-history)))
       (content (read-string "Content: " (car (symbol-value history)) history)))
      (insert (concat TeX-grop content TeX-grcl))
      (if (zerop (length content))
      (backward-char)))))

Assicurarsi che TeX-electric-sub-and-superscriptsia impostato su zero.

Ecco una versione che inserisce in modo non interattivo l'ultimo sub / super-script che si verifica per il token nel punto:

(defun my/electric-sub-super-script (arg)
  "Insert typed character ARG times and possibly a sub/super-script.
Sub/super-script insertion is done only in a (La)TeX math mode region.
The inserted sub/super-script is copied from the last occurence of a
sub/superscript for the token at point."
  (interactive "p")
  (self-insert-command arg)
  (when (texmathp)
    (insert
     (save-excursion
       (let ((current-token (let ((end (point)))
                              (backward-sexp 1)
                              (buffer-substring-no-properties (point) end))))
         (if (search-backward current-token nil t)
             (progn
               (search-forward current-token)
               (let ((begin (point)))
                 (forward-sexp 1)
                 (buffer-substring-no-properties begin (point))))
           ""))))))

(define-key TeX-mode-map (kbd "_") #'my/electric-sub-super-script)
(define-key TeX-mode-map (kbd "^") #'my/electric-sub-super-script)

Prendendo l'esempio nella domanda, di seguito è riportata la sequenza degli stati del buffer ottenuta iniziando con la prima riga e digitando _^SPCa_:

\sum_{i=1}^{\infty} a_i = \sum▮
\sum_{i=1}^{\infty} a_i = \sum_{i=1}▮
\sum_{i=1}^{\infty} a_i = \sum_{i=1}^{\infty}▮
\sum_{i=1}^{\infty} a_i = \sum_{i=1}^{\infty} a▮
\sum_{i=1}^{\infty} a_i = \sum_{i=1}^{\infty} a_i▮