fai in modo che `delete-duplicate-lines` ignori le righe vuote e certe parole

Sto modificando un testo in modalità org, vengono ripetute più righe poiché fanno parte di file diversi dallo stesso argomento.

Voglio usare delete-duplicate-linesper eliminare le righe ripetute, tuttavia, il comando rimuove anche le righe vuote, il che è qualcosa che non voglio (altrimenti non avrei paragrafi!). Voglio ignorare alcune parole che esistono da sole nelle righe, ad esempio "Riprendi" , è ripetuto molte volte nel testo, ma voglio mantenerlo poiché è necessario.

text-editing

— shackra
fonte

Ignorando le righe vuote

Puoi dire delete-duplicate-linesdi ignorare le righe vuote chiamandolo tramite

C-u C-u C-u M-x delete-duplicate-lines RET

Se non vuoi colpire C-ucosì tante volte quando chiami delete-duplicate-lines, puoi racchiuderlo in un comando personalizzato e associare quel comando a una sequenza di tasti a tua scelta:

(defun delete-duplicate-lines-keep-blanks ()
  (interactive)
  (delete-duplicate-lines (region-beginning) (region-end) nil nil t))

(global-set-key (kbd "C-c d") 'delete-duplicate-lines-keep-blanks)

Ignorando le righe corrispondenti a regexp

Per quanto riguarda la seconda parte della tua domanda, non credo che tu possa ottenere ciò che desideri utilizzando la versione integrata di delete-duplicate-lines. Puoi, tuttavia, utilizzare una versione modificata del comando (che mantiene anche le righe vuote per impostazione predefinita):

(defun delete-duplicate-lines
    (beg end keep &optional reverse adjacent keep-blanks interactive)
  (interactive
   (progn
     (barf-if-buffer-read-only)
     (list (region-beginning) (region-end)
           (read-string "Keep lines matching regexp: ") ; Prompt for regexp to keep
           (equal current-prefix-arg '(4))
           (equal current-prefix-arg '(16))
           t                                            ; Keep blanks by default
           t)))
  (let ((lines (unless adjacent (make-hash-table :test 'equal)))
        line prev-line
        (count 0)
        (beg (copy-marker beg))
        (end (copy-marker end)))
    (save-excursion
      (goto-char (if reverse end beg))
      (if (and reverse (bolp)) (forward-char -1))
      (while (if reverse
             (and (> (point) beg) (not (bobp)))
               (and (< (point) end) (not (eobp))))
        (setq line (buffer-substring-no-properties
                (line-beginning-position) (line-end-position)))
        (if (or (and keep-blanks (string= "" line))
                (string-match keep line))               ; Ignore line if it
                                                        ; matches regexp to keep
            (forward-line 1)
          (if (if adjacent (equal line prev-line) (gethash line lines))
              (progn
                (delete-region (progn (forward-line 0) (point))
                               (progn (forward-line 1) (point)))
                (if reverse (forward-line -1))
                (setq count (1+ count)))
            (if adjacent (setq prev-line line) (puthash line t lines))
            (forward-line (if reverse -1 1))))))
    (set-marker beg nil)
    (set-marker end nil)
    (when interactive
      (message "Deleted %d %sduplicate line%s%s"
               count
               (if adjacent "adjacent " "")
               (if (= count 1) "" "s")
               (if reverse " backward" "")))
    count))

Questa versione delete-duplicate-linesti chiederà una regexp e manterrà tutte le righe che corrispondono alla regexp. Ad esempio, per mantenere tutte le righe costituite dalla parola Resumedovresti fare:

M-x delete-duplicate-lines RET ^Resume$ RET

— itsjeyd
fonte