Come accedere alla modalità di sola visualizzazione durante la navigazione del codice sorgente di Emacs dalla guida?

Quando sfoglio la guida di Emacs per le funzioni tramite C-h f, spesso voglio dare un'occhiata all'implementazione di Elisp / C. Voglio inserire view-modeautomaticamente quando accedo al codice sorgente in questo modo per evitare modifiche non necessarie. C'è un gancio o una funzione che posso consigliare di realizzare questo?

Aggiornamento (dopo una notte di sonno): questa risposta ha un grosso difetto: si abilita view-modequando si naviga verso qualsiasi funzione, non solo con le fonti Emacs. Questo può essere risolto, ma è meglio usare la risposta di @phils .

Facendo C-h f describe-function RETe quindi leggere il codice sorgente di describe-functionho scoperto che crea un "bottone" di un tipo speciale per i collegamenti alle definizioni di funzioni: help-function-def.

Correre zrgrepcon questa stringa (" help-function-def") mi ha indicato help-mode.el.gz.

Dopo tutto questo scavare possiamo sostituire questo tipo di pulsante con il nostro (notare il commento nel codice):

(define-button-type 'help-function-def
  :supertype 'help-xref
  'help-function (lambda (fun file)
               (require 'find-func)
               (when (eq file 'C-source)
                 (setq file
                       (help-C-file-name (indirect-function fun) 'fun)))
               ;; Don't use find-function-noselect because it follows
               ;; aliases (which fails for built-in functions).
               (let ((location
                      (find-function-search-for-symbol fun nil file)))
                 (pop-to-buffer (car location))
                 (if (cdr location)
                     (goto-char (cdr location))
                   (message "Unable to find location in file")))
                   (view-mode t)) ; <= new line: enable view-mode
  'help-echo (purecopy "mouse-2, RET: find function's definition"))

Per quanto posso dire non c'è alcuna funzione per aggiungere consigli a: Emacs usa un lambdaqui. D'altra parte (come sottolineato da @rationalrevolt ) si può sostituire la help-functionproprietà del help-function-deftipo di pulsante:

(require 'help-mode)
(let ((help-func (button-type-get 'help-function-def 'help-function)))
  (button-type-put 'help-function-def 'help-function
                   `(lambda (func file)
                      (funcall ,help-func func file) (view-mode t))))

Puoi utilizzare le variabili locali della directory per rendere i file sorgente di Emacs di sola lettura per impostazione predefinita. (Vedi anche C-hig (emacs) Directory Variables RET).

Creare un file chiamato .dir-locals.elnella radice dell'albero delle directory che si desidera proteggere, con i seguenti contenuti:

((nil . ((eval . (view-mode 1)))))

Modifica: Michał Politowski sottolinea nei commenti che abilitare view-modein questo modo è problematico, perché quando si elimina il buffer con qesso disabilita anche la modalità, il che significa che la prossima volta che si visita quel buffer view-modenon sarà abilitato.

Modifica 2: Costantino ha fornito una soluzione a questo problema nei commenti seguenti:

((nil . ((eval . (when buffer-file-name (view-mode-enter nil #'kill-buffer))))))

Questo aggiunge utilmente un test per assicurarsi che il buffer stia già visitando un file, ma la modifica della chiave è l'uso di view-mode-enterinvece di view-mode, poiché il primo accetta un EXIT-ACTIONargomento che determina cosa fare quando qviene digitato. In questo caso, l'azione di uscita consiste nell'uccidere il buffer, assicurandosi che alla successiva visita del file finisca nuovamente view-mode.

Modifica 3: Seguendo quel percorso, possiamo anche vedere che lo specifico EXIT-ACTIONviene infine passato alla view-mode-exitfunzione e il suo docstring ci offre una soluzione alternativa:

view-no-disable-on-exit is a variable defined in `view.el'.
Its value is nil

Documentation:
If non-nil, View mode "exit" commands don't actually disable View mode.
Instead, these commands just switch buffers or windows.
This is set in certain buffers by specialized features such as help commands
that use View mode automatically.

Quindi possiamo usare quanto segue:

((nil . ((eval . (when buffer-file-name
                   (setq-local view-no-disable-on-exit t)
                   (view-mode-enter))))))

Uso un approccio alternativo che puoi specificare interamente nel tuo file init (invece di creare un .dir-locals.elfile), e faccio semplicemente i file in sola lettura piuttosto che usare view-mode. La mia configurazione è simile a questa:

;; Emacs
(dir-locals-set-class-variables
 'emacs
 '((nil . ((buffer-read-only . t)
           (show-trailing-whitespace . nil)
           (tab-width . 8)
           (eval . (whitespace-mode -1))))))

(dir-locals-set-directory-class "/usr/local/src/emacs" 'emacs)
(dir-locals-set-directory-class "/usr/local/share/emacs" 'emacs)
(dir-locals-set-directory-class "/usr/share/emacs" 'emacs)

Ovviamente puoi fare la stessa cosa per la tua directory elpa e qualsiasi altra directory che contiene codice sorgente di terze parti.

Penso che tutto ciò che serve sia aggiungere un hook :

(add-hook 'find-function-after-hook 'view-mode)

Questo non risolve il tuo caso specifico, ma il caso più generale di passare view-modeogni volta che visiti un file sorgente da un buffer della guida. Lo sto offrendo in alternativa alla risposta di @Costantina, poiché non era leggibile come commento.

Sembra che ho originariamente preso questo da EmacsWiki .

(defadvice find-function-search-for-symbol (after view-function-source last (symbol type library) activate)
  "When visiting function source via Help, switch to view-mode"
  (with-current-buffer (car ad-return-value)
    (view-mode 1)))

(defadvice find-variable-noselect (after view-var-source last (variable &optional file) activate)
  "When visiting variable source via Help, switch to view-mode"
  (with-current-buffer (car ad-return-value)
    (view-mode 1)))

Ecco una soluzione che funziona per la documentazione integrata e un esempio che mostra come estenderlo a ELPA. Funziona abbinando il percorso al file corrente con alcune regex e applicando read-only-modese uno di essi corrisponde.

Nota che il buffer è di sola lettura se lo visiti anche attraverso dired, non solo attraverso l'aiuto.

Ho aggiunto un hook che viene eseguito dopo aver inserito emacs-lisp-modeche controlla se il percorso del file corrisponde /\.el\.gz$/e applica la modalità di sola lettura se lo fa.

(defun readonly-if-el-gz ()
  (cond
   ((string-match "\\.el\\.gz\\'" (or (buffer-file-name) ""))
    (read-only-mode +1))))

(add-hook 'emacs-lisp-mode-hook 'readonly-if-el-gz)

Ecco un esempio che controlla anche ELPA, usando l'euristica che qualsiasi percorso contenente .emacs.d/elpasia in realtà un codice ELPA.

(defun readonly-if-internal ()
  (let
      ((name (or (buffer-file-name) "")))
    (cond
     ((string-match "\\.el\\.gz\\'" name) (read-only-mode +1))
     ((string-match "\\.emacs\\.d/elpa" name) (read-only-mode +1)))))

(add-hook 'emacs-lisp-mode-hook 'readonly-if-internal)