È possibile aggiungere modelli diversi da # + BEGIN_ # + END

9

Ho notato che org-struttura-template-alist è cambiato (sto usando org-mode versione 9.2) per espandermi automaticamente #+BEGIN_<some block tag> #+END_<some block tag>. Mi chiedo se sia possibile aggiungere diversi tipi di modelli. Ad esempio un :PROPERTIES:<some properties>:END:modello.

È possibile o dovrei passare a un altro pacchetto come yasnippet?

org-mode

— PierreB
fonte

9

AGGIORNARE:

Non ho notato che la Modalità Org 9.2 ha cambiato il meccanismo di espansione del modello, dove org-structure-template-alistè solo per i blocchi definiti da "#+BEGIN_"e "#+END_". E l'ingresso come ("p" ":PROPERTIES:?:END:")non è più accettato.

Come menzionato nel link sopra, altri template "complessi" possono essere definiti per funzione tempo-define-template, e org-tempo deve essere caricato ( (require 'org-tempo)). In realtà le voci di org-structure-template-alist vengono convertite in org-tempo-tagsvia tempo-define-templateda org-tempoe per org-tempo-tagsimpostazione predefinita sono:

(("<i" . tempo-template-org-index)
 ("<A" . tempo-template-org-ascii)
 ("<H" . tempo-template-org-html)
 ("<L" . tempo-template-org-latex)
 ("<v" . tempo-template-org-verse)
 ("<s" . tempo-template-org-src)
 ("<q" . tempo-template-org-quote)
 ("<l" . tempo-template-org-export-latex)
 ("<h" . tempo-template-org-export-html)
 ("<E" . tempo-template-org-export)
 ("<e" . tempo-template-org-example)
 ("<C" . tempo-template-org-comment)
 ("<c" . tempo-template-org-center)
 ("<a" . tempo-template-org-export-ascii)
 ("<I" . tempo-template-org-include))

Per il tuo caso, puoi definire un modello per:

(tempo-define-template "my-property"
               '(":PROPERTIES:" p ":END:" >)
               "<p"
               "Insert a property tempate")

La risposta di seguito funziona solo per la versione in modalità Org precedente alla 9.2

Sì, è possibile aggiungere una voce in questo modo:

(add-to-list 'org-structure-template-alist '("p" ":PROPERTIES:?:END:"))

Quindi, nel file org, digiti <pe TAB, si espanderà in proprietà e lascerà il punto nella posizione di ?.

E puoi trovare maggiori dettagli nella documentazione della variabile digitando C-h v org-structure-template-alist RET.

— whatacold
fonte

Risposta molto utile, grazie. A proposito, il >simbolo è tempo-define-templatesull'errore di battitura? In caso contrario ... Qual è il ruolo nella definizione?

— Dox,

1

Sono contento che aiuta :) Non è un errore di battitura, significa che la linea sarebbe rientrato, tempo-define-templateè built-in defun, vedere la docstring per i dettagli.

— whatacold

2

La frequenza con cui introducono cambiamenti incompatibili nella personalizzazione della modalità org è davvero un peccato.

Il codice seguente fornisce i vecchi modelli di struttura della modalità org precedente alla versione 9.2. La funzione org-complete-expand-structure-templateè una copia pura dalla versione 9.1 ed org-try-structure-completionè una versione leggermente modificata di quella della 9.1. (Ho aggiunto un controllo del tipo lì.)

Dopo aver installato quel codice, puoi semplicemente utilizzare
(add-to-list 'org-structure-template-alist '("p" ":PROPERTIES:?:END:"))
nuovamente il tuo vecchio modello .

(defvar org-structure-template-alist)

(defun org+-avoid-old-structure-templates (fun &rest args)
  "Call FUN with ARGS with modified `org-structure-template-alist'.
Use a copy of `org-structure-template-alist' with all
old structure templates removed."
  (let ((org-structure-template-alist
     (cl-remove-if
      (lambda (template)
        (null (stringp (cdr template))))
      org-structure-template-alist)))
    (apply fun args)))

(eval-after-load "org"
  '(when (version<= "9.2" (org-version))
     (defun org-try-structure-completion ()
       "Try to complete a structure template before point.
This looks for strings like \"<e\" on an otherwise empty line and
expands them."
       (let ((l (buffer-substring (point-at-bol) (point)))
         a)
     (when (and (looking-at "[ \t]*$")
            (string-match "^[ \t]*<\\([a-zA-Z]+\\)$" l)
            (setq a (assoc (match-string 1 l) org-structure-template-alist))
            (null (stringp (cdr a))))
       (org-complete-expand-structure-template (+ -1 (point-at-bol)
                              (match-beginning 1)) a)
       t)))

     (defun org-complete-expand-structure-template (start cell)
       "Expand a structure template."
       (let ((rpl (nth 1 cell))
         (ind ""))
     (delete-region start (point))
     (when (string-match "\\`[ \t]*#\\+" rpl)
       (cond
        ((bolp))
        ((not (string-match "\\S-" (buffer-substring (point-at-bol) (point))))
         (setq ind (buffer-substring (point-at-bol) (point))))
        (t (newline))))
     (setq start (point))
     (when (string-match "%file" rpl)
       (setq rpl (replace-match
              (concat
               "\""
               (save-match-data
             (abbreviate-file-name (read-file-name "Include file: ")))
               "\"")
              t t rpl)))
     (setq rpl (mapconcat 'identity (split-string rpl "\n")
                  (concat "\n" ind)))
     (insert rpl)
     (when (re-search-backward "\\?" start t) (delete-char 1))))

     (advice-add 'org-tempo-add-templates :around #'org+-avoid-old-structure-templates)

     (add-hook 'org-tab-after-check-for-cycling-hook #'org-try-structure-completion)

     (require 'org-tempo)
     ))

— Tobias
fonte

È possibile aggiungere modelli diversi da # + BEGIN_ # + END_ a org-struttura-template-alist?