Come posso passare rapidamente da un file a un buffer * scratch * con la stessa modalità principale?

A volte, mentre si lavora su un codice, è utile aprire rapidamente un buffer * scratch * per incollare uno snippet da quel file di codice.

Se sto lavorando a uno script Perl, vorrei aprire rapidamente un buffer * scratch * con in cperl-mode. Sarebbe anche bello tornare rapidamente al buffer di codice in cui stavo lavorando originariamente.

major-mode scratch-buffer

— Kaushal Modi
fonte

Sarà conveniente associare la funzione di seguito a un'associazione di tasti a scelta. Se si sta attualmente lavorando su un FILEbuffer, la chiamata della funzione seguente commuta tra il buffer FILE* scratch * specifico della modalità principale chiamato *scratch-MAJOR-MODE*e il FILEbuffer.

Dato l'esempio in questione, se sto lavorando su uno script Perl chiamato myperl.pl, chiamando questa funzione si alternerà tra myperl.ple *scratch-cperl-mode*.

(defun modi/switch-to-scratch-and-back (&optional arg)
  "Toggle between *scratch-MODE* buffer and the current buffer.
If a scratch buffer does not exist, create it with the major mode set to that
of the buffer from where this function is called.

        COMMAND -> Open/switch to a scratch buffer in the current buffer's major mode
    C-0 COMMAND -> Open/switch to a scratch buffer in `fundamental-mode'
    C-u COMMAND -> Open/switch to a scratch buffer in `org-mode'
C-u C-u COMMAND -> Open/switch to a scratch buffer in `emacs-elisp-mode'

Even if the current major mode is a read-only mode (derived from `special-mode'
or `dired-mode'), we would want to be able to write in the scratch buffer. So
the scratch major mode is set to `org-mode' for such cases.

Return the scratch buffer opened."
  (interactive "p")
  (if (and (or (null arg)               ; no prefix
               (= arg 1))
           (string-match-p "\\*scratch" (buffer-name)))
      (switch-to-buffer (other-buffer))
    (let* ((mode-str (cl-case arg
                       (0  "fundamental-mode") ; C-0
                       (4  "org-mode") ; C-u
                       (16 "emacs-lisp-mode") ; C-u C-u
                       ;; If the major mode turns out to be a `special-mode'
                       ;; derived mode, a read-only mode like `help-mode', open
                       ;; an `org-mode' scratch buffer instead.
                       (t (if (or (derived-mode-p 'special-mode) ; no prefix
                                  (derived-mode-p 'dired-mode))
                              "org-mode"
                            (format "%s" major-mode)))))
           (buf (get-buffer-create (concat "*scratch-" mode-str "*"))))
      (switch-to-buffer buf)
      (funcall (intern mode-str))   ; http://stackoverflow.com/a/7539787/1219634
      buf)))

— Kaushal Modi
fonte

Come posso escludere la modalità diretta, la modalità termine e altre modalità non modificabili per questa funzione?

— godblessfq

@godblessfq Avevo risolto questo problema di recente nella mia configurazione . Per ora puoi ottenere quella versione da lì. Aggiornerò questa risposta quando arrivo a un computer.

— Kaushal Modi,

@godblessfq Ho aggiornato la risposta. Provalo e vedi se funziona per te.

— Kaushal Modi,

funziona come un fascino!

— godblessfq,