Esiste uno yasnippet che produce un commento doxygen prepopolato?

10

Per la seguente funzione C ++:

bool importantStuff(double a, double b);

Dovrebbe generare il seguente frammento, forse senza i tag:

/**
 * <Insert description of importantStuff>
 *
 * @param a <Insert description of a>
 * @param b <Insert description of b>
 * @return <Insert description of the return value>
 */

Ho guardato intorno alla rete, ma il più vicino a cui ho ottenuto una risposta è questa vecchia domanda SO in cui la risposta dipende dalla modalità doxymacs non più mantenuta.

yasnippet c++

— Rovanion
fonte

Penso che c-sharp-modeabbia qualcosa che lo faccia.

— erikstokes

Vuoi farlo per nuove funzioni o per quelle esistenti?

— itsjeyd

Quando ho posto la domanda, pensavo al commento doxygen generato dalla firma della funzione.

— Rovanion,

4

Uso il seguente che è un mashup di uno standard basato su doxymac e uno a base semantica a bordo menzionato come risposta già - questo richiede solo semantico e yasnippet. Questo pre-popola alcuni dei segnaposto yasnippet con informazioni pertinenti e anche rispetto alla versione di abo-abo.


# -*- mode: snippet -*-
# name: dox
# key: dox
# type: command
# --
(unless (and (fboundp 'semantic-current-tag)
             semantic-mode)
  (error "Semantic required to use dox snippet"))
(let ((tag (senator-next-tag)))
  (while (or (null tag)
             (not (semantic-tag-of-class-p tag 'function)))
    (setq tag (senator-next-tag)))
  (let* ((name (semantic-tag-name tag))
         (attrs (semantic-tag-attributes tag))
         (args (plist-get attrs :arguments))
         (return-name (plist-get attrs :type))
         (idx 1))
    (if (listp return-name)
      (setq return-name (car return-name)))
    (yas/expand-snippet
     (format
      "/**
* @brief ${1:%s}
*
%s
%s*/
"
      name
      (mapconcat
       (lambda (x)
         (format "* @param %s ${%d:Description of %s}"
                 (car x) (incf idx) (car x)))
       args
       "\n")
      (if (and return-name (not (string-equal "void" return-name)))
          (format " * @return ${%d:%s}\n" (incf idx) return-name)
        "")))))

— alexmurray
fonte

Questa soluzione funziona assolutamente, ma dover aspettare che la modalità semantica riesca a sfogliare tutto il codice richiesto è leggermente ingombrante. Ho anche fatto emacs rimanere bloccato in loop infiniti se invece scrivo dox <tab> prima di una variabile. Ma non si può avere tutto in questo mondo: D

— Rovanion,

questo dovrebbe essere votato più in alto di quanto sopra, in quanto è più ricco di moo-doxygen

— Alejandro Erickson

3

Ho appena aggiunto questa funzione a function-args .

Ecco il codice, se sei interessato. Sta usando CEDET:

(defun moo-doxygen ()
  "Generate a doxygen yasnippet and expand it with `aya-expand'.
The point should be on the top-level function name."
  (interactive)
  (move-beginning-of-line nil)
  (let ((tag (semantic-current-tag)))
    (unless (semantic-tag-of-class-p tag 'function)
      (error "Expected function, got %S" tag))
    (let* ((name (semantic-tag-name tag))
           (attrs (semantic-tag-attributes tag))
           (args (plist-get attrs :arguments))
           (ord 1))
      (setq aya-current
            (format
             "/**
* $1
*
%s
* @return $%d
*/
"
             (mapconcat
              (lambda (x)
                (format "* @param %s $%d"
                        (car x) (incf ord)))
              args
              "\n")
             (incf ord)))
      (aya-expand))))

È inoltre necessario lo yasnippet automatico . Entrambi i pacchetti sono disponibili in MELPA.

— ABO-abo
fonte