org: Come ordinare i titoli per TODO e quindi per priorità?

Ho spesso un elenco come questo:

* Main heading
** TODO [#A] Make world better
** TODO [#B] Make Emacs better 
** TODO [#B] Customize emacs 
** DONE [#C] some task
** TODO [#A] Launch rocket to mars

Vorrei prima ordinarlo in base alla taskword "TODO". Quindi gli articoli all'interno del TODO ordinato vorrei ordinare per priorità. (sarebbe quindi piacevole ordinare ulteriormente per "Sforzo").

E intendo che attualmente posso fare clic sull'intestazione principale e ordinare i bambini già per priorità o per parola chiave, ma non per entrambi.

L'ordinamento per entrambi è possibile come una strategia di ordinamento?

Attualmente ho due titoli

* Tasks
** TODO [#A] meh
** TODO [#B] meh2
* Completed.
** DONE [#B] meh3.

Ma il problema con questo approccio è che devo costantemente mescolare i compiti quando li completo.

[EDIT]
Questo è un po 'simile a questo, tranne per il fatto che non potevo dare un senso alla sua risposta per trasferirla ai miei bisogni?

Sarebbe bello se ci fosse qualcosa di simile con org-agenda-sorting-stratagycui lavorare org-sort-entries, ma non sembra esserci. Possiamo falsificarlo poiché org-sort-entriespossiamo prendere un argomento specificando una funzione che assegna una chiave (stringa o numero) a ciascuna intestazione, che verrà utilizzata per ordinare le voci quando ?fviene fornito il tipo di ordinamento. Tutto quello che dobbiamo fare è ottenere una stringa per le proprietà TODO e PRIORITY. Il trucco è che vogliamo ordinare la proprietà TODO in base alla sua posizione org-todo-keywords, non in ordine alfabetico.

(require 'cl)
(require 'dash)

(defun todo-to-int (todo)
    (first (-non-nil
            (mapcar (lambda (keywords)
                      (let ((todo-seq
                             (-map (lambda (x) (first (split-string  x "(")))
                                   (rest keywords)))) 
                        (cl-position-if (lambda (x) (string= x todo)) todo-seq)))
                    org-todo-keywords))))

(defun my/org-sort-key ()
  (let* ((todo-max (apply #'max (mapcar #'length org-todo-keywords)))
         (todo (org-entry-get (point) "TODO"))
         (todo-int (if todo (todo-to-int todo) todo-max))
         (priority (org-entry-get (point) "PRIORITY"))
         (priority-int (if priority (string-to-char priority) org-default-priority)))
    (format "%03d %03d" todo-int priority-int)
    ))

(defun my/org-sort-entries ()
  (interactive)
  (org-sort-entries nil ?f #'my/org-sort-key))

M-x my/org-sort-entriesordinerà per parola chiave TODO e romperà i legami con PRIORITY (usando org-default-priorityquando non viene data priorità). Questo si interromperà se hai più di 1000 parole chiave TODO, il che è una buona ragione per non farlo.

Aggiungi quanto segue al tuo file:

#+ARCHIVE: :: * Completed.

E il mescolamento diventa l' archiviazione

Invece di ordinare le voci, che ne dici di una vista ordinata?

(setq org-agenda-custom-commands
      '(("cx" "TODOs sorted by state, priority, effort"
         todo "*"
         ((org-agenda-overriding-header "\nTODOs sorted by state, priority, effort")
          (org-agenda-sorting-strategy '(todo-state-down priority-down effort-up))))))

Limitare il file corrente con <. È possibile contrassegnare FATTO e archiviare dalla vista ordinata.

È inoltre possibile definire una org-agenda-cmp-user-definedfunzione e aggiungerla a org-agenda-sorting-strategy. Questo è quello che ho creato come esempio.

(setq org-todo-sort-order '("WAIT" "TODO" "DOING" "CANCELED" "DONE"))

(defun my:user-todo-sort (a b)
  "Sort todo based on which I want to see first"
  (when-let ((state-a (get-text-property 14 'todo-state a))
             (state-b (get-text-property 14 'todo-state b))
             (cmp (--map (cl-position-if (lambda (x)
                                           (equal x it))
                                         org-todo-sort-order)
                         (list state-a state-b))))
    (cond ((apply '> cmp) 1)
          ((apply '< cmp) -1)
          (t nil))))
(setq org-agenda-cmp-user-defined 'my:user-todo-sort)

Puoi utilizzare questa libreria creata da me: https://github.com/felipelalli/org-sort-tasks

Utilizza l'alge Merge Sort chiedendo all'utente se un'attività A è più importante di B, quindi crea un elenco ordinato.