Creazione di un nome file come timestamp in un lavoro batch

Abbiamo un lavoro batch che viene eseguito ogni giorno e copia un file in una cartella di prelievo. Voglio anche prendere una copia di quel file e rilasciarlo in una cartella di archivio con il nome del file

 yyyy-MM-dd.log

Qual è il modo più semplice per farlo in un lavoro batch di Windows?

Fondamentalmente sto cercando un equivalente di questo comando Unix:

cp source.log `date +%F`.log

CP source.log %DATE:~-4%-%DATE:~4,2%-%DATE:~7,2%.log

Ma dipende dalla località. Non sono sicuro che %DATE%sia localizzato o dipenda dal formato specificato per la data breve in Windows.

Ecco un modo indipendente dalle impostazioni locali per estrarre la data corrente da questa risposta , ma dipende da WMICe FOR /F:

FOR /F %%A IN ('WMIC OS GET LocalDateTime ^| FINDSTR \.') DO @SET B=%%A
CP source.log %B:~0,4%-%B:~4,2%-%B:~6,2%.log

Questo ha funzionato per me ed era una soluzione sicura per i nomi di file (sebbene generi un formato MM-gg-AAAA):

C:\ set SAVESTAMP=%DATE:/=-%@%TIME::=-%
C:\ set SAVESTAMP=%SAVESTAMP: =%
C:\ set SAVESTAMP=%SAVESTAMP:,=.%.jpg
C:\ echo %SAVESTAMP%
11-04-2012@20-52-42.79.jpg

Il primo comando prende una DATA e la sostituisce /con -, prende l'ora e la sostituisce :con -e le combina nel formato DATE @ TIME. La seconda setdichiarazione rimuove tutti gli spazi, e il terzo setsostituisce ,con .e aggiunge il .jpgprolungamento.

Il codice sopra viene utilizzato in un piccolo script che estrae le immagini da una telecamera IP di sicurezza per ulteriori elaborazioni:

:while
set SAVESTAMP=%DATE:/=-%@%TIME::=-%
set SAVESTAMP=%SAVESTAMP: =%
set SAVESTAMP=%SAVESTAMP:,=.%.jpg
wget-1.10.2.exe --tries=0 -O %SAVESTAMP% http://admin:<password>@<ip address>:<port>/snapshot.cgi
timeout 1
GOTO while

SOLO per le impostazioni internazionali francesi (Francia) , fare attenzione perché /appare nella data:

echo %DATE%
08/09/2013

Per il nostro problema di file di registro, ecco la mia proposta SOLO per le impostazioni internazionali francesi :

SETLOCAL
set LOGFILE_DATE=%DATE:~6,4%.%DATE:~3,2%.%DATE:~0,2%
set LOGFILE_TIME=%TIME:~0,2%.%TIME:~3,2%
set LOGFILE=log-%LOGFILE_DATE%-%LOGFILE_TIME%.txt
rem log-2014.05.19-22.18.txt
command > %LOGFILE%

Ecco una soluzione indipendente dalla locale (copia in un file denominato SetDateTimeComponents.cmd):

@echo off
REM This script taken from the following URL:
REM http://www.winnetmag.com/windowsscripting/article/articleid/9177/windowsscripting_9177.html

REM Create the date and time elements.
for /f "tokens=1-7 delims=:/-, " %%i in ('echo exit^|cmd /q /k"prompt $d $t"') do (
   for /f "tokens=2-4 delims=/-,() skip=1" %%a in ('echo.^|date') do (
      set dow=%%i
      set %%a=%%j
      set %%b=%%k
      set %%c=%%l
      set hh=%%m
      set min=%%n
      set ss=%%o
   )
)

REM Let's see the result.
echo %dow% %yy%-%mm%-%dd% @ %hh%:%min%:%ss%

Ho messo tutti i miei script .cmd nella stessa cartella (% SCRIPTROOT%); qualsiasi script che necessita di valori di data / ora chiamerà SetDateTimeComponents.cmd come nell'esempio seguente:

setlocal

@echo Initializing...
set SCRIPTROOT=%~dp0
set ERRLOG=C:\Oopsies.err

:: Log start time
call "%SCRIPTROOT%\SetDateTimeComponents.cmd" >nul
@echo === %dow% %yy%-%mm%-%dd% @ %hh%:%min%:%ss% : Start === >> %ERRLOG%

:: Perform some long running action and log errors to ERRLOG.

:: Log end time
call "%SCRIPTROOT%\SetDateTimeComponents.cmd" >nul
@echo === %dow% %yy%-%mm%-%dd% @ %hh%:%min%:%ss% : End === >> %ERRLOG%

Come mostra l'esempio, puoi chiamare SetDateTimeComponents.cmd ogni volta che devi aggiornare i valori di data / ora. Nascondere lo script di analisi del tempo nel proprio file SetDateTimeComponents.cmd è un bel modo per nascondere i dettagli orribili e, soprattutto, evitare errori di battitura.

Poiché l'idea di strapparli %DATE%e %TIME%separarli e schiacciarli insieme sembra fragile nel migliore dei casi, ecco un'alternativa che utilizza un oneliner powershell:

for /f %i in ('powershell -c "get-date -format yyyy-MM-dd--HH-mm-ss"') do @set DATETIME=%i
set LOGFILE=my-script-%DATETIME%.txt

Il riferimento per get-dateè qui , con opzioni di formato sia per lo stile .NET che per lo stile UNIX.

Lo uso spesso e metto tutto in un unico comando di copia. Il seguente copia example.txt come example_YYYYMMDD_HHMMSS.txt e ovviamente puoi modificarlo per adattarlo al tuo formato preferito. Le virgolette sono necessarie solo se sono presenti spazi nel filespec. Se desideri riutilizzare la stessa identica data / ora, devi memorizzarla in una variabile.

copy "{path}\example.txt" "{path}\_%date:~10,4%%date:~4,2%%date:~7,2%_%time:~0,2%%time:~3,2%%time:~6,2%.txt"

Ciò garantirà che l'output sia un valore a 2 cifre ... puoi riorganizzare l'output a tuo piacimento e testare annullando i commenti nella sezione diagnostica. Godere!

(Ho preso in prestito molto di questo da altri forum ...)

:: ------------------ Date and Time Modifier ------------------------

@echo off
setlocal

:: THIS CODE WILL DISPLAY A 2-DIGIT TIMESTAMP FOR USE IN APPENDING FILENAMES

:: CREATE VARIABLE %TIMESTAMP%

for /f "tokens=1-8 delims=.:/-, " %%i in ('echo exit^|cmd /q /k"prompt $D $T"') do (
   for /f "tokens=2-4 skip=1 delims=/-,()" %%a in ('echo.^|date') do (
set dow=%%i
set %%a=%%j
set %%b=%%k
set %%c=%%l
set hh=%%m
set min=%%n
set sec=%%o
set hsec=%%p
)
)

:: ensure that hour is always 2 digits

if %hh%==0 set hh=00
if %hh%==1 set hh=01
if %hh%==2 set hh=02
if %hh%==3 set hh=03
if %hh%==4 set hh=04
if %hh%==5 set hh=05
if %hh%==6 set hh=06
if %hh%==7 set hh=07
if %hh%==8 set hh=08
if %hh%==9 set hh=09


:: --------- TIME STAMP DIAGNOSTICS -------------------------

:: Un-comment these lines to test output

:: echo dayOfWeek = %dow%
:: echo year = %yy%
:: echo month = %mm%
:: echo day = %dd%
:: echo hour = %hh%
:: echo minute = %min%
:: echo second = %sec%
:: echo hundredthsSecond = %hsec%
:: echo.
:: echo Hello! 
:: echo Today is %dow%, %mm%/%dd%. 
:: echo.
:: echo. 
:: echo.
:: echo.
:: pause

:: --------- END TIME STAMP DIAGNOSTICS ----------------------

:: assign timeStamp:
:: Add the date and time parameters as necessary - " yy-mm-dd-dow-min-sec-hsec "

endlocal & set timeStamp=%yy%%mm%%dd%_%hh%-%min%-%sec%
echo %timeStamp%

Crea un file con la data corrente come nome file (es. 2008-11-08.dat)

echo hello > %date%.dat    

Con la data corrente ma senza il "-" (es. 20081108.dat)

echo hello > %date:-=%.dat   

Forse questo può aiutare:

echo off
@prompt set date=$d$_ set time=$t$h$h$h
echo some log >> %date% %time%.log
exit

o

echo off
set v=%date%.log
echo some log >> %v%

Ho messo insieme un piccolo programma in C per stampare il timestamp corrente (locale sicuro, nessun cattivo carattere ...). Quindi, utilizzo il comando FOR per salvare il risultato in una variabile di ambiente:

:: Get the timestamp
for /f %%x in ('@timestamp') do set TIMESTAMP=%%x

:: Use it to generate a filename
for /r %%x in (.\processed\*) do move "%%~x" ".\archived\%%~nx-%TIMESTAMP%%%~xx"

Ecco un collegamento:

https://github.com/HarryPehkonen/dos-timestamp

So che questo thread è vecchio ma voglio solo aggiungerlo qui perché mi ha aiutato molto a cercare di capire tutto ed è pulito. La cosa bella di questo è che potresti metterlo in un ciclo per un file batch sempre in esecuzione. Registro dei tempi di attività del server o qualcosa del genere. È per questo che lo uso comunque. Spero che questo aiuti qualcuno un giorno.

@setlocal enableextensions enabledelayedexpansion
@echo off

call :timestamp freshtime freshdate
echo %freshdate% - %freshtime% - Some data >> "%freshdate - Somelog.log"

:timestamp
set hour=%time:~0,2%
if "%hour:~0,1%" == " " set hour=0%hour:~1,1%
set min=%time:~3,2%
if "%min:~0,1%" == " " set min=0%min:~1,1%
set secs=%time:~6,2%
if "%secs:~0,1%" == " " set secs=0%secs:~1,1%
set FreshTime=%hour%:%min%:%secs%

set year=%date:~-4%
set month=%date:~4,2%
if "%month:~0,1%" == " " set month=0%month:~1,1%
set day=%date:~7,2%
if "%day:~0,1%" == " " set day=0%day:~1,1%
set FreshDate=%month%.%day%.%year%

Puoi semplicemente rilevare il formato locale corrente e ottenere la data nel tuo formato, ad esempio:

::for 30.10.2016 dd.MM.yyyy
if %date:~2,1%==. set d=%date:~-4%%date:~3,2%%date:~,2%
::for 10/30/2016 MM/dd/yyyy
if %date:~2,1%==/ set d=%date:~-4%%date:~,2%%date:~3,2%
::for 2016-10-30 yyyy-MM-dd
if %date:~4,1%==- set d=%date:~,4%%date:~5,2%%date:~-2%
::variable %d% have now value: 2016103 (yyyyMMdd)
set t=%time::=%
set t=%t:,=%
::variable %t% have now time without delimiters
cp source.log %d%_%t%.log

So che questo è un vecchio post, ma c'è una risposta molto più semplice (anche se forse funziona solo nelle versioni più recenti di Windows). Usa semplicemente il parametro / t per i comandi DATE e TIME dos per mostrare solo la data o l'ora e non chiederti di impostarla, in questo modo:

@echo off
echo Starting test batch file > testlog.txt
date /t >> testlog.txt
time /t >> testlog.txt

1) Puoi scaricare GNU coreutils fornito con GNU date

2) puoi usare VBScript , che semplifica la manipolazione della data in Windows:

Set objFS = CreateObject("Scripting.FileSystemObject")
strFolder = "c:\test"
Set objFolder = objFS.GetFolder(strFolder)
current = Now
mth = Month(current)
d = Day(current)
yr = Year(current)
If Len(mth) <2 Then
    mth="0"&mth
End If
If Len(d) < 2 Then
    d = "0"&d
End If
timestamp=yr & "-" & mth &"-"& d
For Each strFile In objFolder.Files
    strFileName = strFile.Name
    If InStr(strFileName,"file_name_here") > 0 Then
        BaseName = objFS.GetBaseName(strFileName)
        Extension = objFS.GetExtensionName(strFileName)
        NewName = BaseName & "-" & timestamp & "." & Extension
        strFile.Name = NewName
    End If
Next

Esegui lo script come:

c:\test> cscript /nologo myscript.vbs

Funziona bene con la (mia) lingua tedesca, dovrebbe essere possibile adattarla alle tue esigenze ...

forfiles /p *PATH* /m *filepattern* /c "cmd /c ren @file 
%DATE:~6,4%%DATE:~3,2%%DATE:~0,2%_@file"

Per i file zip di grandi dimensioni per la distribuzione, utilizzo i quarti d'ora. Nessun altro in questa pagina ne aveva parlato prima, quindi inserirò il mio piccolo script qui:

set /a "quarter_hours=%time:~0,2%*4 + %time:~3,2% / 15"
set "zip_file=release_%DATE:~-4%.%DATE:~4,2%.%DATE:~7,2%.%quarter_hours%.zip"

Non è ancora azzerato il quarto d'ora da mezzanotte alle 5 del mattino, ma lo fa comunque in modo da poter avere un rilascio timbrato più volte al giorno con poche collisioni.

Spero che aiuti.

ha usato il suggerimento di Martin con un piccolo aggiustamento per aggiungere il timestamp al nome del file:

forfiles /p [foldername] /m rsync2.log /c "cmd /c ren @file %DATE:~6,4%%DATE:~3,2%%DATE:~0,2%_%time:~-11,2%-%time:~-8,2%-%time:~-5,2%-@file

Per il 23/10/2019 10:17:21 Il risultato è:

20191023_10-17-21-rsync2.log