Come evitare l'uso di Seleziona in Excel VBA

Ho sentito molto parlare della comprensibile disgusto dell'uso .Selectin Excel VBA, ma non sono sicuro di come evitarlo. Sto scoprendo che il mio codice sarebbe più riutilizzabile se fossi in grado di utilizzare le variabili anziché le Selectfunzioni. Tuttavia, non sono sicuro di come fare riferimento a cose (come le ActiveCellecc.) Se non utilizzate Select.

Ho trovato questo articolo sulle gamme e questo esempio sui vantaggi di non usare select ma non riesci a trovare nulla su come ?

Alcuni esempi di come evitare la selezione

Usa Dimle variabili

Dim rng as Range

Setla variabile nell'intervallo richiesto. Esistono molti modi per fare riferimento a un intervallo di celle singole

Set rng = Range("A1")
Set rng = Cells(1,1)
Set rng = Range("NamedRange")

o un intervallo multi-cella

Set rng = Range("A1:B10")
Set rng = Range("A1", "B10")
Set rng = Range(Cells(1,1), Cells(10,2))
Set rng = Range("AnotherNamedRange")
Set rng = Range("A1").Resize(10,2)

È possibile utilizzare il collegamento al Evaluatemetodo, ma questo è meno efficiente e generalmente dovrebbe essere evitato nel codice di produzione.

Set rng = [A1]
Set rng = [A1:B10]

Tutti gli esempi sopra riportati si riferiscono alle celle sul foglio attivo . A meno che tu non voglia specificamente lavorare solo con il foglio attivo, è meglio anche Dimmerare una Worksheetvariabile

Dim ws As Worksheet
Set ws = Worksheets("Sheet1")
Set rng = ws.Cells(1,1)
With ws
    Set rng = .Range(.Cells(1,1), .Cells(2,10))
End With

Se non vogliono lavorare con il ActiveSheet, per chiarezza è meglio essere espliciti. Ma attenzione, poiché alcuni Worksheetmetodi cambiano il foglio attivo.

Set rng = ActiveSheet.Range("A1")

Ancora una volta, questo si riferisce alla cartella di lavoro attiva . A meno che tu non voglia specificamente lavorare solo con ActiveWorkbooko ThisWorkbook, è meglio oscurare anche una Workbookvariabile.

Dim wb As Workbook
Set wb = Application.Workbooks("Book1")
Set rng = wb.Worksheets("Sheet1").Range("A1")

Se non vogliono lavorare con il ActiveWorkbook, per chiarezza è meglio essere espliciti. Ma attenzione, poiché molti WorkBookmetodi cambiano il libro attivo.

Set rng = ActiveWorkbook.Worksheets("Sheet1").Range("A1")

È inoltre possibile utilizzare l' ThisWorkbookoggetto per fare riferimento al libro contenente il codice in esecuzione.

Set rng = ThisWorkbook.Worksheets("Sheet1").Range("A1")

Un pezzo di codice (cattivo) comune è aprire un libro, recuperare alcuni dati e richiuderlo

Questo non va bene:

Sub foo()
    Dim v as Variant
    Workbooks("Book1.xlsx").Sheets(1).Range("A1").Clear
    Workbooks.Open("C:\Path\To\SomeClosedBook.xlsx")
    v = ActiveWorkbook.Sheets(1).Range("A1").Value
    Workbooks("SomeAlreadyOpenBook.xlsx").Activate
    ActiveWorkbook.Sheets("SomeSheet").Range("A1").Value = v
    Workbooks(2).Activate
    ActiveWorkbook.Close()
End Sub

E sarebbe meglio come:

Sub foo()
    Dim v as Variant
    Dim wb1 as Workbook
    Dim  wb2 as Workbook
    Set wb1 = Workbooks("SomeAlreadyOpenBook.xlsx")
    Set wb2 = Workbooks.Open("C:\Path\To\SomeClosedBook.xlsx")
    v = wb2.Sheets("SomeSheet").Range("A1").Value
    wb1.Sheets("SomeOtherSheet").Range("A1").Value = v
    wb2.Close()
End Sub

Passa gli intervalli alle tue Subs e Functions come variabili di intervallo

Sub ClearRange(r as Range)
    r.ClearContents
    '....
End Sub

Sub MyMacro()
    Dim rng as Range
    Set rng = ThisWorkbook.Worksheets("SomeSheet").Range("A1:B10")
    ClearRange rng
End Sub

È inoltre necessario applicare i metodi (come Finde Copy) alle variabili

Dim rng1 As Range
Dim rng2 As Range
Set rng1 = ThisWorkbook.Worksheets("SomeSheet").Range("A1:A10")
Set rng2 = ThisWorkbook.Worksheets("SomeSheet").Range("B1:B10")
rng1.Copy rng2

Se esegui il ciclo su un intervallo di celle, spesso è meglio (più veloce) copiare prima i valori dell'intervallo su un array di varianti e passare sopra quello

Dim dat As Variant
Dim rng As Range
Dim i As Long

Set rng = ThisWorkbook.Worksheets("SomeSheet").Range("A1:A10000")
dat = rng.Value  ' dat is now array (1 to 10000, 1 to 1)
for i = LBound(dat, 1) to UBound(dat, 1)
    dat(i,1) = dat(i,1) * 10 'or whatever operation you need to perform
next
rng.Value = dat ' put new values back on sheet

Questo è un piccolo assaggio di ciò che è possibile.

Due motivi principali per cui .Select/ .Activate/ Selection/ Activecell/ Activesheet/ Activeworkbookecc ... dovrebbero essere evitati

1. Rallenta il tuo codice.
2. Di solito è la causa principale di errori di runtime.

Come lo evitiamo?

1) Lavora direttamente con gli oggetti rilevanti

Considera questo codice

Sheets("Sheet1").Activate
Range("A1").Select
Selection.Value = "Blah"
Selection.NumberFormat = "@"

Questo codice può anche essere scritto come

With Sheets("Sheet1").Range("A1")
    .Value = "Blah"
    .NumberFormat = "@"
End With

2) Se necessario, dichiarare le variabili. Lo stesso codice sopra può essere scritto come

Dim ws as worksheet

Set ws = Sheets("Sheet1")

With ws.Range("A1")
    .Value = "Blah"
    .NumberFormat = "@"
End With

Un piccolo punto di enfasi aggiungerò a tutte le eccellenti risposte fornite sopra:

Probabilmente la cosa più grande che puoi fare per evitare di usare Select è, per quanto possibile, usare intervalli nominali (combinati con nomi di variabili significative) nel tuo codice VBA . Questo punto è stato menzionato sopra, ma è stato leggermente sopraffatto; tuttavia, merita un'attenzione speciale.

Qui ci sono un paio di ragioni in più per fare un uso liberale delle gamme nominate, anche se sono sicuro che potrei pensare di più.

Gli intervalli denominati semplificano la lettura e la comprensione del codice.

Esempio:

Dim Months As Range
Dim MonthlySales As Range

Set Months = Range("Months")
'e.g, "Months" might be a named range referring to A1:A12

Set MonthlySales = Range("MonthlySales")
'e.g, "Monthly Sales" might be a named range referring to B1:B12

Dim Month As Range
For Each Month in Months
    Debug.Print MonthlySales(Month.Row)
Next Month

È abbastanza ovvio cosa contengono gli intervalli denominati Monthse MonthlySalescontengono e cosa sta facendo la procedura.

Perché questo è importante? In parte perché è più facile per le altre persone capirlo, ma anche se sei l'unica persona che vedrà o userà mai il tuo codice, dovresti comunque usare intervalli nominali e nomi di variabili buone perché dimenticherai cosa volevi fare con esso un anno dopo, e perderai 30 minuti solo a capire cosa sta facendo il tuo codice.

Gli intervalli denominati assicurano che le tue macro non si rompano quando (non se!) La configurazione del foglio di calcolo cambia.

Considera, se l'esempio sopra fosse stato scritto in questo modo:

Dim rng1 As Range
Dim rng2 As Range

Set rng1 = Range("A1:A12")
Set rng2 = Range("B1:B12")

Dim rng3 As Range
For Each rng3 in rng1 
    Debug.Print rng2(rng3.Row)
Next rng3

All'inizio questo codice funzionerà bene, fino a quando tu o un futuro utente non deciderete "Accidenti, penso che aggiungerò una nuova colonna con l'anno in Colonna A!" O inserirò una colonna di spesa tra i mesi e colonne di vendita o aggiungi un'intestazione a ciascuna colonna. Ora il tuo codice è rotto. E poiché hai usato nomi di variabili terribili, ci vorrà molto più tempo per capire come risolverlo di quanto dovrebbe impiegare.

Se avevi usato gli intervalli nominati per cominciare, le colonne Monthse Salespotrebbero essere spostate in tutto ciò che desideri e il tuo codice continuerà a funzionare bene.

Darò la risposta breve dato che tutti gli altri hanno dato quella lunga.

Riceverai .select e .activate ogni volta che registri macro e riutilizzale. Quando selezioni una cella o un foglio, la rendi attiva. Da quel momento in poi ogni volta che usi riferimenti non qualificati come Range.Valueloro usano semplicemente la cella e il foglio attivi. Questo può anche essere problematico se non guardi dove si trova il tuo codice o se un utente fa clic sulla cartella di lavoro.

Quindi, puoi eliminare questi problemi facendo direttamente riferimento alle tue celle. Che va:

'create and set a range
Dim Rng As Excel.Range
Set Rng = Workbooks("Book1").Worksheets("Sheet1").Range("A1")
'OR
Set Rng = Workbooks(1).Worksheets(1).Cells(1, 1)

Oppure potresti

'Just deal with the cell directly rather than creating a range
'I want to put the string "Hello" in Range A1 of sheet 1
Workbooks("Book1").Worksheets("Sheet1").Range("A1").value = "Hello"
'OR
Workbooks(1).Worksheets(1).Cells(1, 1).value = "Hello"

Esistono varie combinazioni di questi metodi, ma sarebbe l'idea generale espressa il più presto possibile per le persone impazienti come me.

"... e sto scoprendo che il mio codice sarebbe più riutilizzabile se fossi in grado di utilizzare le variabili anziché le funzioni Seleziona."

Anche se non riesco a pensare ad altro che a una manciata isolata di situazioni in cui .Selectsarebbe una scelta migliore del riferimento diretto alle cellule, vorrei sollevare la difesa Selectione sottolineare che non dovrebbe essere eliminato per gli stessi motivi che .Selectdovrebbero essere evitati.

Ci sono momenti in cui le sub-routine macro brevi e veloci assegnate alle combinazioni di tasti di scelta rapida disponibili con il tocco di un paio di tasti fanno risparmiare molto tempo. Essere in grado di selezionare un gruppo di celle per attuare il codice operativo su meraviglie funziona quando si tratta di dati tascabili che non sono conformi a un formato di dati a livello di foglio di lavoro. Allo stesso modo in cui è possibile selezionare un gruppo di celle e applicare un cambio di formato, selezionare un gruppo di celle per eseguire un codice macro speciale può far risparmiare molto tempo.

Esempi di sub framework basato sulla selezione:

Public Sub Run_on_Selected()
    Dim rng As Range, rSEL As Range
    Set rSEL = Selection    'store the current selection in case it changes
    For Each rng In rSEL
        Debug.Print rng.Address(0, 0)
        'cell-by-cell operational code here
    Next rng
    Set rSEL = Nothing
End Sub

Public Sub Run_on_Selected_Visible()
    'this is better for selected ranges on filtered data or containing hidden rows/columns
    Dim rng As Range, rSEL As Range
    Set rSEL = Selection    'store the current selection in case it changes
    For Each rng In rSEL.SpecialCells(xlCellTypeVisible)
        Debug.Print rng.Address(0, 0)
        'cell-by-cell operational code here
    Next rng
    Set rSEL = Nothing
End Sub

Public Sub Run_on_Discontiguous_Area()
    'this is better for selected ranges of discontiguous areas
    Dim ara As Range, rng As Range, rSEL As Range
    Set rSEL = Selection    'store the current selection in case it changes
    For Each ara In rSEL.Areas
        Debug.Print ara.Address(0, 0)
        'cell group operational code here
        For Each rng In ara.Areas
            Debug.Print rng.Address(0, 0)
            'cell-by-cell operational code here
        Next rng
    Next ara
    Set rSEL = Nothing
End Sub

Il codice effettivo da elaborare potrebbe essere qualsiasi cosa, da una singola riga a più moduli. Ho usato questo metodo per avviare routine di lunga durata su una selezione irregolare di celle contenenti i nomi di file di cartelle di lavoro esterne.

In breve, non scartare a Selectioncausa della sua stretta associazione con .Selecte ActiveCell. Come proprietà del foglio di lavoro ha molti altri scopi.

_{(Sì, so che questa domanda riguardava .Select, non Selectionma volevo rimuovere qualsiasi idea sbagliata che i programmatori VBA principianti potrebbero dedurre.)}

Si noti che di seguito sto confrontando l'approccio Select (quello che l'OP vuole evitare), con l'approccio Range (e questa è la risposta alla domanda). Quindi non smettere di leggere quando vedi la prima selezione.

Dipende davvero da cosa stai cercando di fare. Comunque un semplice esempio potrebbe essere utile. Supponiamo che tu voglia impostare il valore della cella attiva su "pippo". Usando ActiveCell scriverai qualcosa del genere:

Sub Macro1()
    ActiveCell.Value = "foo"
End Sub

Se vuoi usarlo per una cella che non è quella attiva, ad esempio per "B2", dovresti prima selezionarlo, in questo modo:

Sub Macro2()
    Range("B2").Select
    Macro1
End Sub

Usando Ranges puoi scrivere una macro più generica che può essere usata per impostare il valore di ogni cella che vuoi su quello che vuoi:

Sub SetValue(cellAddress As String, aVal As Variant)
    Range(cellAddress).Value = aVal
End Sub

Quindi puoi riscrivere Macro2 come:

Sub Macro2()
    SetCellValue "B2", "foo"
End Sub

E Macro1 come:

Sub Macro1()
    SetValue ActiveCell.Address, "foo"
End Sub

Spero che questo aiuti a chiarire un po 'le cose.

Evitare Selected Activateè la mossa che ti rende un po 'meglio sviluppatore VBA. In generale, Selecte Activatevengono utilizzati quando viene registrata una macro, quindi il Parentfoglio di lavoro o l'intervallo viene sempre considerato quello attivo.

Ecco come evitare Selecte Activatenei seguenti casi:

Aggiunta di un nuovo foglio di lavoro e copia di una cella su di esso:

Da (codice generato con il registratore di macro):

Sub Makro2()
    Range("B2").Select
    Sheets.Add After:=ActiveSheet
    Sheets("Tabelle1").Select
    Sheets("Tabelle1").Name = "NewName"
    ActiveCell.FormulaR1C1 = "12"
    Range("B2").Select
    Selection.Copy
    Range("B3").Select
    ActiveSheet.Paste
    Application.CutCopyMode = False
End Sub

Per:

Sub TestMe()
    Dim ws As Worksheet
    Set ws = Worksheets.Add
    With ws
        .Name = "NewName"
        .Range("B2") = 12
        .Range("B2").Copy Destination:=.Range("B3")
    End With
End Sub

Quando si desidera copiare l'intervallo tra i fogli di lavoro:

A partire dal:

Sheets("Source").Select
Columns("A:D").Select
Selection.Copy
Sheets("Target").Select
Columns("A:D").Select
ActiveSheet.Paste

Per:

Worksheets("Source").Columns("A:D").Copy Destination:=Worksheets("Target").Range("a1")

Usando intervalli nominali di fantasia

Puoi accedervi con [], il che è davvero bello, rispetto all'altro. Controllati:

Dim Months As Range
Dim MonthlySales As Range

Set Months = Range("Months")    
Set MonthlySales = Range("MonthlySales")

Set Months =[Months]
Set MonthlySales = [MonthlySales]

L'esempio dall'alto sarebbe simile al seguente:

Worksheets("Source").Columns("A:D").Copy Destination:=Worksheets("Target").[A1]

Non copiare valori, ma prenderli

Di solito, se sei disposto a farlo select, molto probabilmente stai copiando qualcosa. Se sei interessato solo ai valori, questa è una buona opzione per evitare di selezionare:

Range("B1:B6").Value = Range("A1:A6").Value

Prova sempre a fare riferimento anche al foglio di lavoro

Questo è probabilmente l'errore più comune in VBA. Ogni volta che copi gli intervalli, a volte il foglio di lavoro non viene referenziato e quindi VBA considera il foglio sbagliato come il foglio di lavoro attivo.

'This will work only if the 2. Worksheet is selected!
Public Sub TestMe()
    Dim rng As Range
    Set rng = Worksheets(2).Range(Cells(1, 1), Cells(2, 2)).Copy
End Sub

'This works always!
Public Sub TestMe2()
    Dim rng As Range
    With Worksheets(2)
        .Range(.Cells(1, 1), .Cells(2, 2)).Copy
    End With
End Sub

Non posso davvero mai usare .Selecto .Activateper niente?

• Un buon esempio di quando potresti essere giustificato nell'uso .Activateed .Selectè quando vuoi assicurarti che un foglio di lavoro specifico sia selezionato per motivi visivi. Ad esempio, Excel si aprirà sempre con il foglio di lavoro di copertina selezionato per primo, ignorando quale era il foglio attivo quando il file veniva chiuso.

Quindi, qualcosa come il codice qui sotto è assolutamente OK:

Private Sub Workbook_Open()
    Worksheets("Cover").Activate
End Sub

• Un altro buon esempio è quando è necessario esportare tutti i fogli in un file PDF, come menzionato in questo caso - Come evitare le istruzioni select / active in VBA in questo esempio?

• Quando un comando funziona solo con ActiveWindow.Zoom o ActiveWindow.FreezePanesActiveWindow simili

Indicare sempre la cartella di lavoro, il foglio di lavoro e la cella / intervallo.

Per esempio:

Thisworkbook.Worksheets("fred").cells(1,1)
Workbooks("bob").Worksheets("fred").cells(1,1)

Poiché gli utenti finali faranno sempre clic sui pulsanti e non appena lo stato attivo verrà rimosso dalla cartella di lavoro, il codice vorrà funzionare, quindi le cose andranno completamente male.

E non usare mai l'indice di una cartella di lavoro.

Workbooks(1).Worksheets("fred").cells(1,1)

Non sai quali altre cartelle di lavoro saranno aperte quando l'utente esegue il tuo codice.

Questi metodi sono piuttosto stigmatizzati, quindi assumendo il comando di @Vityata e @Jeeped per il bene di tracciare una linea nella sabbia:

Perché non chiamare .Activate, .Select, Selection, ActiveSomethingi metodi / proprietà

Fondamentalmente perché sono chiamati principalmente per gestire l'input dell'utente attraverso l'interfaccia utente dell'applicazione. Poiché sono i metodi chiamati quando l'utente gestisce gli oggetti attraverso l'interfaccia utente, sono quelli registrati dal registratore di macro ed è per questo che chiamarli è fragile o ridondante per la maggior parte delle situazioni: non è necessario selezionare un oggetto in modo da eseguire un'azione Selectionsubito dopo.

Tuttavia, questa definizione risolve le situazioni in cui sono richieste:

Quando chiamare .Activate, .Select, .Selection, .ActiveSomethingi metodi / proprietà

Fondamentalmente quando ti aspetti che l' utente finale svolga un ruolo nell'esecuzione.

Se stai sviluppando e ti aspetti che l'utente scelga le istanze dell'oggetto da gestire per il tuo codice, allora .Selectiono .ActiveObjectsono appropriate.

D'altra parte, .Selecte .Activatesono utili quando puoi dedurre la prossima azione dell'utente e vuoi che il tuo codice guidi l'utente, risparmiandogli un po 'di tempo e clic del mouse. Ad esempio, se il tuo codice ha appena creato una nuovissima istanza di un grafico o aggiornata, l'utente potrebbe voler verificarlo e potresti chiamarlo .Activateo il suo foglio per risparmiare all'utente il tempo di cercarlo; o se sai che l'utente dovrà aggiornare alcuni valori di intervallo, puoi selezionare programmaticamente quell'intervallo.

L'uso di IMHO .selectproviene da persone, che come me hanno iniziato ad imparare VBA per necessità attraverso la registrazione di macro e quindi la modifica del codice senza rendersene conto .selecte il successivo selectionè solo un inutile intermediario.

.select può essere evitato, come molti già pubblicati, lavorando direttamente con gli oggetti già esistenti, il che consente vari riferimenti indiretti come il calcolo di i e j in modo complesso e quindi la modifica della cella (i, j), ecc.

Altrimenti, non c'è nulla di implicitamente sbagliato in .selectse stesso e puoi trovare facilmente gli usi per questo, ad esempio ho un foglio di calcolo che popolo con la data, attivo macro che fa un po 'di magia con esso ed esporta in un formato accettabile su un foglio separato, che , tuttavia, richiede alcuni input manuali finali (imprevedibili) in una cella adiacente. Quindi ecco che arriva il momento .selectche mi fa risparmiare quel movimento e un clic aggiuntivi del mouse.

Risposta rapida:

Per evitare di utilizzare il .Selectmetodo è possibile impostare una variabile uguale alla proprietà desiderata.

► Ad esempio, se si desidera inserire il valore, Cell A1è possibile impostare una variabile uguale alla proprietà value di quella cella.

• Esempio valOne = Range("A1").Value

► Ad esempio, se si desidera il nome in codice di 'Foglio3`, è possibile impostare una variabile uguale alla proprietà del nome in codice di quel foglio di lavoro.

• Esempio valTwo = Sheets("Sheet3").Codename

Spero che aiuti. Fatemi sapere se avete domande.

Ho notato che nessuna di queste risposte menziona la proprietà .Offset . Questo può anche essere usato per evitare di usare l' Selectazione quando si manipolano determinate celle, in particolare in riferimento a una cella selezionata (come menziona l'OP ActiveCell).

Ecco un paio di esempi.

Presumo anche che "ActiveCell" sia J4 .

ActiveCell.Offset(2, 0).Value = 12

• Questo cambierà la cella J6in un valore di 12
• Un meno -2 avrebbe fatto riferimento a J2

ActiveCell.Offset(0,1).Copy ActiveCell.Offset(,2)

• Questo copierà la cella in k4a L4.
• Si noti che "0" non è necessario nel parametro offset se non necessario (, 2)
• Simile all'esempio precedente sarebbe meno 1 i4

ActiveCell.Offset(, -1).EntireColumn.ClearContents

• Ciò cancellerà i valori in tutte le celle nella colonna k.

Questi non devono dire che sono "migliori" delle opzioni sopra, ma elencano solo le alternative.

Lavorare con la funzione .Parent. Questo esempio mostra come l'impostazione di un solo riferimento myRng consenta l'accesso dinamico all'intero ambiente senza .Select, .Activate, .Activecell, .ActiveWorkbook, .ActiveSheet e così via. (Non c'è genere. Caratteristica per bambini)

Sub ShowParents()
    Dim myRng As Range
    Set myRng = ActiveCell
    Debug.Print myRng.Address                    ' an address of the selected cell
    Debug.Print myRng.Parent.name                ' the name of sheet, where MyRng is in
    Debug.Print myRng.Parent.Parent.name         ' the name of workbook, where MyRng is in
    Debug.Print myRng.Parent.Parent.Parent.name  ' the name of application, where MyRng is in

    ' You may use this feature to set reference to these objects
    Dim mySh    As Worksheet
    Dim myWbk   As Workbook
    Dim myApp   As Application

    Set mySh = myRng.Parent
    Set myWbk = myRng.Parent.Parent
    Set myApp = myRng.Parent.Parent.Parent
    Debug.Print mySh.name, mySh.Cells(10, 1).Value
    Debug.Print myWbk.name, myWbk.Sheets.Count
    Debug.Print myApp.name, myApp.Workbooks.Count

    ' You may use dynamically addressing
    With myRng
        .Copy

       ' pastes in D1 on sheet 2 in the same workbook, where copied cell is
        .Parent.Parent.Sheets(2).Range("D1").PasteSpecial xlValues
    ' or myWbk.Sheets(2).Range("D1").PasteSpecial xlValues

       ' we may dynamically call active application too
        .Parent.Parent.Parent.CutCopyMode = False
    ' or myApp.CutCopyMode = False
    End With
End Sub

Il motivo principale per non usare Select o Activesheet è perché la maggior parte delle persone avrà almeno un'altra coppia di cartelle di lavoro aperte (a volte dozzine) quando eseguono la macro e se fanno clic lontano dal foglio mentre la macro è in esecuzione e fanno clic su un altro libro aperto, quindi il "Foglio attivo" cambia e cambia anche la cartella di lavoro di destinazione per un comando "Seleziona" non qualificato.

Nella migliore delle ipotesi, la tua macro andrà in crash, nel peggiore dei casi potresti finire per scrivere valori o cambiare celle nella cartella di lavoro sbagliata senza un modo per "annullarli".

Ho una semplice regola d'oro che seguo: aggiungi le variabili denominate "wb" e "ws" per un oggetto Cartella di lavoro e un oggetto Foglio di lavoro e utilizzale sempre per fare riferimento al mio libro macro. Se devo fare riferimento a più di un libro o a più di un foglio, aggiungo più variabili.

per esempio

Dim wb as Workbook
Dim ws as Worksheet
Set wb = ThisWorkBook
Set ws = wb.sheets("Output")

Il comando "Set wb = ThisWorkbook" è assolutamente chiave. "ThisWorkbook" è un valore speciale in Excel e indica la cartella di lavoro da cui il tuo codice VBA è attualmente in esecuzione . Un collegamento molto utile per impostare la variabile della cartella di lavoro.

Dopo averlo fatto nella parte superiore del tuo Sottomarino, usarli non potrebbe essere più semplice, basta usarli ovunque tu utilizzi "Selezione":

Quindi, per modificare il valore della cella "A1" in "Output" in "Hello", anziché:

Sheets("Output").Activate
ActiveSheet.Range("A1").Select
Selection.Value = "Hello"

Ora possiamo fare questo:

ws.Range("A1").Value = "Hello"

Che non è solo molto più affidabile e meno soggetto a crash se l'utente sta lavorando con più fogli di calcolo, è anche molto più breve, veloce e facile da scrivere.

Come bonus aggiuntivo, se dai sempre il nome alle tue variabili "wb" e "ws", puoi copiare e incollare il codice da un libro all'altro e di solito funzionerà con eventuali modifiche minime necessarie.

Questo è un esempio che cancellerà il contenuto della cella "A1" (o più se il tipo di selezione è xllastcell, ecc.). Tutto fatto senza dover selezionare le celle.

Application.GoTo Reference:=Workbook(WorkbookName).Worksheets(WorksheetName).Range("A1")
Range(Selection,selection(selectiontype)).clearcontents 

Spero che questo aiuti qualcuno.