UltiSnips e YouCompleteMe

Ho installato bundle ultisnips e youcompleteme sul mio macvim. Il problema è che ultisnips non funziona perché la scheda è rilegata da ycm. Ho provato a metterlo in let g:UltiSnipsExpandTrigger = "<s-tab>"modo da poter attivare il completamento dello snippet con shift-tab, ma non funziona per qualche motivo sconosciuto. Potrei usare i tappi come trigger, ma finora non ho trovato alcun modo per farlo.

Qualcuno di voi usa questi due componenti aggiuntivi insieme? Cosa posso fare per far funzionare il cambio a schede? Puoi consigliare un altro tasto per attivare i frammenti?

Un'altra opzione sta usando il plugin SuperTab:

" if you use Vundle, load plugins:
Bundle 'ervandew/supertab'
Bundle 'Valloric/YouCompleteMe'
Bundle 'SirVer/ultisnips'

" make YCM compatible with UltiSnips (using supertab)
let g:ycm_key_list_select_completion = ['<C-n>', '<Down>']
let g:ycm_key_list_previous_completion = ['<C-p>', '<Up>']
let g:SuperTabDefaultCompletionType = '<C-n>'

" better key bindings for UltiSnipsExpandTrigger
let g:UltiSnipsExpandTrigger = "<tab>"
let g:UltiSnipsJumpForwardTrigger = "<tab>"
let g:UltiSnipsJumpBackwardTrigger = "<s-tab>"

Qui YouCompleteMe è associato a una combinazione diversa Ctrln, ma poi quella combinazione è associata a tab tramite SuperTab. UltiSnips e SuperTab giocano bene insieme, quindi puoi semplicemente associare UltiSnips alla scheda direttamente e tutto funzionerà.

Prova questo suggerimento su una pagina dal tracker dei problemi YouCompleteMe. Nel tuo .vimrc:

let g:UltiSnipsExpandTrigger="<c-j>"

Mentre questa impostazione farà sì che l'espansione di uno snippet condivida la mappatura predefinita per saltare in avanti all'interno di uno snippet , simula il comportamento di TextMates come menzionato nei tag di aiuto di UltiSnips.

Da quando ho mappato il tasto BLOC MAIUSC su Ctrl, questa mappatura funziona in modo abbastanza fluido.

copia il seguente codice su vimrc e divertiti. Questa funzione gestirà tutti i problemi tra YCM e UltiSnips.

function! g:UltiSnips_Complete()
    call UltiSnips#ExpandSnippet()
    if g:ulti_expand_res == 0
        if pumvisible()
            return "\<C-n>"
        else
            call UltiSnips#JumpForwards()
            if g:ulti_jump_forwards_res == 0
               return "\<TAB>"
            endif
        endif
    endif
    return ""
endfunction

au BufEnter * exec "inoremap <silent> " . g:UltiSnipsExpandTrigger . " <C-R>=g:UltiSnips_Complete()<cr>"
let g:UltiSnipsJumpForwardTrigger="<tab>"
let g:UltiSnipsListSnippets="<c-e>"
" this mapping Enter key to <C-y> to chose the current highlight item 
" and close the selection list, same as other IDEs.
" CONFLICT with some plugins like tpope/Endwise
inoremap <expr> <CR> pumvisible() ? "\<C-y>" : "\<C-g>u\<CR>"

ho questo nel mio vimrc

"" YouCompleteMe
let g:ycm_key_list_previous_completion=['<Up>']

"" Ultisnips
let g:UltiSnipsExpandTrigger="<c-tab>"
let g:UltiSnipsListSnippets="<c-s-tab>"

questo è quello che ho fatto al mio primo tentativo, ma ho sbagliato a scrivere UltiSnips con Ultisnips .. vabbè, alla fine ho risolto!

Personalmente ho scelto di non utilizzare <tab>YouCompleteMe ma di navigare manualmente.

Quindi ho aggiunto questo al mio .vimrc:

let g:ycm_key_list_select_completion=[]
let g:ycm_key_list_previous_completion=[]

che disabilita semplicemente la tabchiave per YCM. Utilizzare invece i tasti di spostamento (frecce o CTRL-N/ CTRL-P) e selezionare la voce con CR. UltiSnips funziona come predefinito tab.

Mettendo insieme le risposte di Michaelslec, Joey Liu e insieme alle soluzioni che ho trovato in questo thread di discussione e in quello di questo ragazzo , ora ho questo che ha risolto praticamente tutti i problemi.

function! g:UltiSnips_Complete()
  call UltiSnips#ExpandSnippet()
  if g:ulti_expand_res == 0
    if pumvisible()
      return "\<C-n>"
    else
      call UltiSnips#JumpForwards()
      if g:ulti_jump_forwards_res == 0
        return "\<TAB>"
      endif
    endif
  endif
  return ""
endfunction

function! g:UltiSnips_Reverse()
  call UltiSnips#JumpBackwards()
  if g:ulti_jump_backwards_res == 0
    return "\<C-P>"
  endif

  return ""
endfunction


if !exists("g:UltiSnipsJumpForwardTrigger")
  let g:UltiSnipsJumpForwardTrigger = "<tab>"
endif

if !exists("g:UltiSnipsJumpBackwardTrigger")
  let g:UltiSnipsJumpBackwardTrigger="<s-tab>"
endif

au InsertEnter * exec "inoremap <silent> " . g:UltiSnipsExpandTrigger     . " <C-R>=g:UltiSnips_Complete()<cr>"
au InsertEnter * exec "inoremap <silent> " .     g:UltiSnipsJumpBackwardTrigger . " <C-R>=g:UltiSnips_Reverse()<cr>"

Anche se so che questo post è un po 'vecchio, ho una mia funzione che è un po' più ottimizzata di quella indicata sopra:

function! g:UltiSnips_Complete()
  call UltiSnips#ExpandSnippetOrJump()
  if g:ulti_expand_or_jump_res == 0
    if pumvisible()
      return "\<C-N>"
    else
      return "\<TAB>"
    endif
  endif

  return ""
endfunction

Ovviamente, se mantieni le impostazioni fornite da Joey Liu e poi usi questa funzione, tutto funzionerà perfettamente!

EDIT: Inoltre, utilizzo un'altra funzione per aumentare la funzionalità di back-stepping tra YouCompleteMe e UltiSnips. Ti mostrerò cosa intendo:

function! g:UltiSnips_Reverse()                                                                                               
  call UltiSnips#JumpBackwards()                                                                                              
  if g:ulti_jump_backwards_res == 0        
    return "\<C-P>"                                                                                                           
  endif                                                                                                                       

  return ""                                                                                                                   
endfunction

Quindi inseriscilo nel tuo .vimrc:

au BufEnter * exec "inoremap <silent> " . g:UltiSnipsJumpBackwardTrigger . " <C-R>=g:UltiSnips_Reverse()<cr>"

Così come let g:UltiSnipsJumpBackwardTrigger="<s-tab>"e il tuo set!

Li uso entrambi insieme. Per impostazione predefinita YouCompleteMe si lega <Tab>e <Down>per selezionare l'elemento di completamento successivo e anche <S-Tab>e <Up>per selezionare l'elemento di completamento precedente. È possibile modificare i collegamenti YouCompleteMe con le opzioni g: ycm_key_list_select_completion e g: ycm_key_list_previous_completion . Si noti che i nomi di queste opzioni sono stati recentemente modificati quando l'opzione è stata cambiata da una singola stringa a un elenco di stringhe.

Ho installato il plug-in UltiSnips dopo il plug-in YouCompleteMe, quindi ho pensato che fossero in conflitto, ma in realtà ho avuto qualcosa di più interferente:

set paste

Assicurati di rimuoverlo da .vimrcse è presente.

Mentre molte risposte funzionano bene in questo post, voglio solo dire che il problema è causato dalla collisione dell'associazione dei tasti tra YCM e UltiSnip, mentre YCM supporta gli snippet UltiSnip per impostazione predefinita, prende il trigger di espansione UltiSnip predefinito <tab>come chiave di selezione del completamento, quindi Gli snippet di UltiSnip non verranno espulsi da <tab>. Assegnare loro una diversa associazione di tasti risolverà il problema, io personalmente uso <c-ne <c-p>per YCM e utilizzo l'impostazione predefinita <tab>per UltiSnip. Puoi ottenere maggiori dettagli con help youcompletemedoc in vim.

Sulla base della risposta di Siegfried, sto usando quanto segue che sembra più naturale:

let g:ycm_key_list_select_completion = ['<C-j>']
let g:ycm_key_list_previous_completion = ['<C-k>']

let g:UltiSnipsExpandTrigger = "<C-l>"
let g:UltiSnipsJumpForwardTrigger = "<C-j>"
let g:UltiSnipsJumpBackwardTrigger = "<C-k>"

Uso anche i c-hjklcollegamenti da qualche altra parte (passando da un riquadro all'altro), ma sarebbe solo in modalità normale, quindi non c'è problema.

Uso ;per espandere UltiSnips, è così elegante per me

let g:UltiSnipsExpandTrigger = ";"

Io uso kj. Questo è ciò che è nel mio .vimrc:

let g:UltisnipsExpandTrigger="kj".

Raramente succede che mi imbatto nella parola che ha kjdentro. In questo caso, aspetterei solo un paio di secondi dopo aver digitato ke quel tipo j.

Come menzionato da altri, mappare Cj su ultisnips funziona alla grande.
let g:UltiSnipsExpandTrigger="<c-j>"

Ora, se vai un po 'oltre e installi xcape e use
xcape -e "Shift_L=Control_R|J"

Scatena il potere di usare solo il tasto Maiusc per utlitsnips.