Aggiornamento giugno 2015, 6 anni dopo:
Come spiegato in " git mergetool winmerge ", un semplice git config diff.tool winmergesarà sufficiente.
Git 2.5+ (Q2, 2015) è ora a conoscenza di Winmerge come strumento di differenza o unione!
Risposta originale (2009-2012)
(msysgit, 1.6.5, sessione DOS)
La prima parte (usando winmerge) è descritta in " Come posso visualizzare l'output di 'git diff' con il programma visual diff? "
C:\myGitRepo>git config --replace --global diff.tool winmerge
C:\myGitRepo>git config --replace --global difftool.winmerge.cmd "winmerge.sh \"$LOCAL\" \"$REMOTE\""
C:\myGitRepo>git config --replace --global difftool.prompt false
Con winmerge.shmemorizzato in una directory parte del tuo PATH:
#!/bin/sh
echo Launching WinMergeU.exe: $1 $2
"$PROGRAMFILES/WinMerge/WinMergeU.exe" -e -u -dl "Local" -dr "Remote" "$1" "$2"
(vedi Opzioni della riga di comando di WinMerge )
git difftool
lancerà ora WinMerge.
Se vuoi git diffavviare WinMerge, imposta semplicemente:
set GIT_EXTERNAL_DIFF=winmerge.sh
Ma il vero valore aggiunto deriva dalla possibilità di utilizzare lo stesso strumento diff per presentare tutte le differenze in un batch invece di presentarle in sequenza, costringendoti a chiudere le finestre dello strumento diff un file alla volta.
Aggiornamento giugno 2012 (2 anni e mezzo dopo):
Il confronto tra directory invece di file per file sarà presto disponibile:
Vedi [ANNOUNCE] Git 1.7.11.rc1 :
" git difftool" appreso " --dir-diff" l'opzione per generare strumenti di diff esterni che possono confrontare due gerarchie di directory contemporaneamente dopo aver popolato due directory temporanee, invece di eseguire un'istanza dello strumento esterno una volta per coppia di file .
Vedere " Patch difftool: insegnare difftoola gestire le differenze di directory " e la risposta " Confronto di directory dei rami Git " per maggiori dettagli.
Difftool originale per script directory (dicembre 2009)
Come afferma Seba Illingworth nella sua risposta , uno script git-diffall.sh (inserito anche nel percorso) può fare proprio questo:
#!/bin/sh
git diff --name-only "$@" | while read filename; do
git difftool "$@" --no-prompt "$filename" &
done
Ma funziona solo aprendo n finestre per n file (se provi a utilizzare l' -sopzione di WinMerge, non funzionerà perché i file temporanei vengono eliminati troppo presto dal difftool)
Questo è il motivo per cui mi piace l'approccio di GitDiff.bat - power-diffing con GI , che consente di rivedere l'elenco dei file con una differenza, prima di selezionarne uno per esaminarne le differenze interne.
L'ho ottimizzato per utilizzare solo comandi DOS
@echo off
setlocal
if "%1" == "-?" (
echo GitDiff - enables diffing of file lists, instead of having to serially
echo diff files without being able to go back to a previous file.
echo Command-line options are passed through to git diff.
echo If GIT_FOLDER_DIFF is set, it is used to diff the file lists. Default is windff.
goto END
)
if "%GIT_DIFF_COPY_FILES%"=="" (
rd /s /q %TEMP%\GitDiff
mkdir %TEMP%\GitDiff
mkdir %TEMP%\GitDiff\old
mkdir %TEMP%\GitDiff\new
REM This batch file will be called by git diff. This env var indicates whether it is
REM being called directly, or inside git diff
set GIT_DIFF_COPY_FILES=1
set GIT_DIFF_OLD_FILES=%TEMP%\GitDiff\old
set GIT_DIFF_NEW_FILES=%TEMP%\GitDiff\new
set GIT_EXTERNAL_DIFF=%~dp0\GitDiff.bat
echo Please wait and press q when you see "(END)" printed in reverse color...
call git diff %*
if defined GIT_FOLDER_DIFF (
REM This command using GIT_FOLDER_DIFF just does not work for some reason.
%GIT_FOLDER_DIFF% %TEMP%\GitDiff\old %TEMP%\GitDiff\new
goto END
)
if exist "%ProgramFiles%\Beyond Compare 2\BC2.exe" (
set GIT_FOLDER_DIFF="%ProgramFiles%\Beyond Compare 2\BC2.exe"
"%ProgramFiles%\Beyond Compare 2\BC2.exe" %TEMP%\GitDiff\old %TEMP%\GitDiff\new
goto END
)
"%ProgramFiles(x86)%\WinMerge\WinMergeU.exe" -r -e -dl "Local" -dr "Remote" %TEMP%\GitDiff\old %TEMP%\GitDiff\new
goto END
)
REM diff is called by git with 7 parameters:
REM path old-file old-hex old-mode new-file new-hex new-mode
copy %TEMP%\%~nx2 %GIT_DIFF_OLD_FILES%\%1
copy %5 %GIT_DIFF_NEW_FILES%
:END
Non è abbastanza robusto per gestire file con lo stesso nome in directory diverse, ma ti dà un'idea generale di cosa è possibile:
qui si aprirà solo un WinMerge, con l'elenco dei file con differenze interne. Puoi fare clic su quelli che vuoi esaminare, quindi un semplice ESCchiuderà l'intera WinMerge-diffsessione.