Reindirizzamento dell'output dall'interno del file Batch

Sto creando un file batch con alcuni semplici comandi per raccogliere informazioni da un sistema. Il file batch contiene comandi per ottenere l'ora, le informazioni IP, gli utenti, ecc.

Ho assemblato tutti i comandi in un file batch e viene eseguito, ma vorrei che il file batch, una volta eseguito, restituisse i risultati in un file di testo (log). C'è un comando che posso aggiungere al batch che lo farebbe?

Tieni presente che non voglio eseguire il batch da cmd, quindi reindirizzare l'output; Voglio reindirizzare l'output dall'interno del batch, se possibile.

Il modo semplice e ingenuo che è lento perché apre e posiziona il puntatore del file su Fine file più volte.

@echo off
command1 >output.txt
command2 >>output.txt
...
commandN >>output.txt

Un modo migliore: più facile da scrivere e più veloce perché il file viene aperto e posizionato una sola volta.

@echo off
>output.txt (
  command1
  command2
  ...
  commandN
)

Un altro modo buono e veloce che apre e posiziona il file solo una volta

@echo off
call :sub >output.txt
exit /b

:sub
command1
command2
...
commandN

Modifica 2020-04-17

Di tanto in tanto potresti voler scrivere ripetutamente su due o più file. Potresti anche volere messaggi diversi sullo schermo. È ancora possibile farlo in modo efficiente reindirizzando a handle non definiti all'esterno di un blocco o subroutine tra parentesi e quindi utilizzare la &notazione per fare riferimento ai file già aperti.

call :sub 9>File1.txt 8>File2.txt
exit /b

:sub
echo Screen message 1
>&9 File 1 message 1
>&8 File 2 message 1
echo Screen message 2
>&9 File 1 message 2
>&8 File 2 message 2
exit /b

Ho scelto di utilizzare gli handle 9 e 8 in ordine inverso perché in questo modo è più probabile che eviti un potenziale reindirizzamento permanente a causa di un difetto di progettazione dell'implementazione del reindirizzamento Microsoft quando si eseguono reindirizzamenti multipli sullo stesso comando. È altamente improbabile, ma anche quell'approccio potrebbe esporre il bug se ci provi abbastanza. Se metti in scena il reindirizzamento, hai la garanzia di evitare il problema.

3>File1.txt ( 4>File2.txt call :sub)
exit /b

:sub
etc.

se vuoi reindirizzare i flussi sia out che err

dir >> a.txt 2>&1

So che questo è un post più vecchio, ma qualcuno si imbatterà in esso in una ricerca su Google e sembra anche che alcune domande poste dall'OP nei commenti non siano state specificamente affrontate. Inoltre, per favore vacci piano con me poiché questa è la mia prima risposta pubblicata su SO. :)

Per reindirizzare l'output a un file utilizzando un nome di file generato dinamicamente, il mio approccio go-to (leggi: veloce e sporco) è la seconda soluzione offerta da @dbenham. Quindi, ad esempio, questo:

@echo off
> filename_prefix-%DATE:~-4%-%DATE:~4,2%-%DATE:~7,2%_%time:~0,2%%time:~3,2%%time:~6,2%.log (
echo Your Name Here
echo Beginning Date/Time: %DATE:~-4%-%DATE:~4,2%-%DATE:~7,2%_%time:~0,2%%time:~3,2%%time:~6,2%.log
REM do some stuff here
echo Your Name Here
echo Ending Date/Time: %DATE:~-4%-%DATE:~4,2%-%DATE:~7,2%_%time:~0,2%%time:~3,2%%time:~6,2%.log
)

Creerà un file come quello che vedi in questo screenshot del file nella directory di destinazione

Che conterrà questo output:

Your Name Here
Beginning Date/Time: 2016-09-16_141048.log
Your Name Here
Ending Date/Time: 2016-09-16_141048.log

Inoltre, tieni presente che questa soluzione dipende dalle impostazioni locali, quindi fai attenzione a come / quando la usi.

echo some output >"your logfile"

o

(
 echo some output
 echo more output
)>"Your logfile"

dovrebbe riempire il conto.

Se vuoi APPENDl'output, usa >>invece di >. >inizierà un nuovo file di registro.

@echo off
>output.txt (
echo Checking your system infor, Please wating...

systeminfo | findstr /c:"Host Name" 
systeminfo | findstr /c:"Domain"

ipconfig /all | find "Physical Address" 

ipconfig | find "IPv4" 
ipconfig | find "Default Gateway"

)

@pause

C'è un piccolo programma interessante che puoi usare per reindirizzare l'output su un file e sulla console

some_command  ^|  TEE.BAT  [ -a ]  filename 

@ECHO OFF
:: Check Windows version
IF NOT "%OS%"=="Windows_NT" GOTO Syntax

:: Keep variables local
SETLOCAL

:: Check command line arguments
SET Append=0
IF /I [%1]==[-a] (
	SET Append=1
	SHIFT
)
IF     [%1]==[] GOTO Syntax
IF NOT [%2]==[] GOTO Syntax

:: Test for invalid wildcards
SET Counter=0
FOR /F %%A IN ('DIR /A /B %1 2^>NUL') DO CALL :Count "%%~fA"
IF %Counter% GTR 1 (
	SET Counter=
	GOTO Syntax
)

:: A valid filename seems to have been specified
SET File=%1

:: Check if a directory with the specified name exists
DIR /AD %File% >NUL 2>NUL
IF NOT ERRORLEVEL 1 (
	SET File=
	GOTO Syntax
)

:: Specify /Y switch for Windows 2000 / XP COPY command
SET Y=
VER | FIND "Windows NT" > NUL
IF ERRORLEVEL 1 SET Y=/Y

:: Flush existing file or create new one if -a wasn't specified
IF %Append%==0 (COPY %Y% NUL %File% > NUL 2>&1)

:: Actual TEE
FOR /F "tokens=1* delims=]" %%A IN ('FIND /N /V ""') DO (
	>  CON    ECHO.%%B
	>> %File% ECHO.%%B
)

:: Done
ENDLOCAL
GOTO:EOF

:Count
SET /A Counter += 1
SET File=%1
GOTO:EOF

:Syntax
ECHO.
ECHO Tee.bat,  Version 2.11a for Windows NT 4 / 2000 / XP
ECHO Display text on screen and redirect it to a file simultaneously
ECHO.
IF NOT "%OS%"=="Windows_NT" ECHO Usage:  some_command  ³  TEE.BAT  [ -a ]  filename
IF NOT "%OS%"=="Windows_NT" GOTO Skip
ECHO Usage:  some_command  ^|  TEE.BAT  [ -a ]  filename
:Skip
ECHO.
ECHO Where:  "some_command" is the command whose output should be redirected
ECHO         "filename"     is the file the output should be redirected to
ECHO         -a             appends the output of the command to the file,
ECHO                        rather than overwriting the file
ECHO.
ECHO Written by Rob van der Woude
ECHO http://www.robvanderwoude.com
ECHO Modified by Kees Couprie
ECHO http://kees.couprie.org
ECHO and Andrew Cameron

Aggiungi queste due linee nella parte superiore del tuo file batch, tutto lo stdout e lo stderr dopo verranno reindirizzati a log.txt:

if not "%1"=="STDOUT_TO_FILE"  %0 STDOUT_TO_FILE %*  >log.txt 2>&1
shift /1

@echo OFF
[your command] >> [Your log file name].txt

Ho usato il comando sopra nel mio file batch e funziona. Nel file di registro, mostra i risultati del mio comando.

Ciò potrebbe non riuscire nel caso di caratteri "tossici" nell'input. Considerare un input come questoIsAnIn ^^^^ put è un buon modo per capire cosa sta succedendo. Sicuramente esiste una regola per cui una stringa di input DEVE essere racchiusa tra virgolette doppie, ma ho la sensazione che questa regola sia una regola valida solo se il significato dell'input è una posizione su una partizione NTFS (forse è una regola per gli URL I non sono sicuro). Ma ovviamente non è una regola per una stringa di input arbitraria (è "una buona pratica" ma non puoi contarci).

L'aggiunta delle seguenti righe nella parte inferiore del file batch acquisirà tutto esattamente come visualizzato nella finestra CMD ed esporterà in un file di testo:

powershell -c "$wshell = New-Object -ComObject wscript.shell; $wshell.SendKeys('^a')
powershell -c "$wshell = New-Object -ComObject wscript.shell; $wshell.SendKeys('^c')
powershell Get-Clipboard > MyLog.txt

Fondamentalmente esegue un seleziona tutto -> copia negli appunti -> incolla nel file di testo .