Devo verificare se è impostata o meno una variabile. Ho provato diverse tecniche ma sembrano fallire ogni volta che %1è racchiuso tra virgolette come nel caso in cui lo %1è "c:\some path with spaces".

IF NOT %1 GOTO MyLabel // This is invalid syntax
IF "%1" == "" GOTO MyLabel // Works unless %1 has double quotes which fatally kills bat execution
IF %1 == GOTO MyLabel // Gives an unexpected GOTO error.

Secondo questo sito , questi sono i IFtipi di sintassi supportati . Quindi, non vedo un modo per farlo.

IF [NOT] ERRORLEVEL number command
IF [NOT] string1==string2 command
IF [NOT] EXIST filename command

Utilizzare le parentesi quadre anziché le virgolette:

IF [%1] == [] GOTO MyLabel

Le parentesi non sono sicure : utilizzare solo parentesi quadre.

Puoi usare:

IF "%~1" == "" GOTO MyLabel

per eliminare l'insieme esterno di virgolette. In generale, questo è un metodo più affidabile rispetto all'utilizzo di parentesi quadre perché funzionerà anche se la variabile contiene spazi.

Una delle migliori soluzioni semi è copiare %1in una variabile e quindi utilizzare l'espansione ritardata, come delayedExp. è sempre sicuro contro qualsiasi contenuto.

set "param1=%~1"
setlocal EnableDelayedExpansion
if "!param1!"=="" ( echo it is empty )
rem ... or use the DEFINED keyword now
if defined param1 echo There is something

Il vantaggio di questo è che gestire param1 è assolutamente sicuro.

E l'impostazione di param1 funzionerà in molti casi, come

test.bat hello"this is"a"test
test.bat you^&me

Ma fallisce ancora con strani contenuti come

test.bat ^&"&

Essere in grado di ottenere una risposta corretta al 100% per l'esistenza

Rileva se %1è vuoto, ma per alcuni contenuti non può recuperarli.
Questo può anche essere utile per distinguere tra un vuoto %1e uno con "".
Usa la capacità del CALLcomando di fallire senza interrompere il file batch.

@echo off
setlocal EnableDelayedExpansion
set "arg1="
call set "arg1=%%1"

if defined arg1 goto :arg_exists

set "arg1=#"
call set "arg1=%%1"
if "!arg1!" EQU "#" (
    echo arg1 exists, but can't assigned to a variable
    REM Try to fetch it a second time without quotes
    (call set arg1=%%1)
    goto :arg_exists
)

echo arg1 is missing
exit /b

:arg_exists
echo arg1 exists, perhaps the content is '!arg1!'

Se vuoi essere al 100% a prova di proiettile per recuperare il contenuto, potresti leggere Come ricevere anche i parametri della riga di comando più strani?

Da IF / ?:

Se le estensioni di comando sono abilitate, SE cambia come segue:

IF [/I] string1 compare-op string2 command
IF CMDEXTVERSION number command
IF DEFINED variable command

......

Il condizionale DEFINED funziona esattamente come EXISTS tranne per il fatto che prende un nome di variabile di ambiente e restituisce true se la variabile di ambiente è definita.

Purtroppo non ho abbastanza reputazione per commentare o votare le risposte attuali a cui ho dovuto scrivere la mia.

Inizialmente la domanda del PO diceva "variabile" anziché "parametro", il che diventava molto confuso, soprattutto perché questo era il collegamento numero uno in Google per cercare come verificare le variabili vuote. Dalla mia risposta originale, Stephan ha modificato la domanda originale per utilizzare la terminologia corretta, ma invece di eliminare la mia risposta ho deciso di lasciarla per aiutare a chiarire qualsiasi confusione, soprattutto nel caso in cui Google stia ancora inviando persone qui per le variabili:

% 1 NON È UN VARIABILE! È UN PARAMETRO DELLA LINEA DI COMANDO.

Distinzione molto importante. Un singolo segno di percentuale con un numero dopo che fa riferimento a un parametro della riga di comando e non a una variabile.

Le variabili vengono impostate utilizzando il comando set e vengono richiamate utilizzando i segni del 2 percento, uno prima e uno dopo. Ad esempio% myvar%

Per verificare una variabile vuota, utilizzare la sintassi "se non definita" (i comandi esplicitamente per le variabili non richiedono alcun segno di percentuale), ad esempio:

set myvar1=foo  
if not defined myvar1 echo You won't see this because %myvar1% is defined.  
if not defined myvar2 echo You will see this because %myvar2% isn't defined.

(Se vuoi testare i parametri della riga di comando, ti consiglio di fare riferimento alla risposta di jamesdlin.)

Utilizzare "IF DEFINED command command" per testare la variabile nel file batch.

Ma se vuoi testare i parametri batch, prova sotto i codici per evitare input difficili (come "1 2" o ab ^> cd)

set tmp="%1"
if "%tmp:"=.%"==".." (
    echo empty
) else (
    echo not empty
)

Ho provato con il codice qui sotto ed è tutto a posto.

@echo off

set varEmpty=
if not "%varEmpty%"=="" (
    echo varEmpty is not empty
) else (
    echo varEmpty is empty
)
set varNotEmpty=hasValue
if not "%varNotEmpty%"=="" (
    echo varNotEmpty is not empty
) else (
    echo varNotEmpty is empty
)

Di solito lo uso:

IF "%1."=="." GOTO MyLabel

Se% 1 è vuoto, l'IF confronterà "." per "." che valuterà come vero.

Ho creato questo piccolo script batch basato sulle risposte qui, poiché ce ne sono molte valide. Sentiti libero di aggiungere a questo finché segui lo stesso formato:

REM Parameter-testing

Setlocal EnableDelayedExpansion EnableExtensions

IF NOT "%~1"=="" (echo Percent Tilde 1 failed with quotes) ELSE (echo SUCCESS)
IF NOT [%~1]==[] (echo Percent Tilde 1 failed with brackets) ELSE (echo SUCCESS)
IF NOT  "%1"=="" (echo Quotes one failed) ELSE (echo SUCCESS)
IF NOT [%1]==[] (echo Brackets one failed) ELSE (echo SUCCESS)
IF NOT "%1."=="." (echo Appended dot quotes one failed) ELSE (echo SUCCESS)
IF NOT [%1.]==[.] (echo Appended dot brackets one failed) ELSE (echo SUCCESS)

pause

La stringa vuota è una coppia di double-quotes/ "", possiamo solo testare la lunghezza:

set ARG=%1
if not defined ARG goto nomore

set CHAR=%ARG:~2,1%
if defined CHAR goto goon

quindi prova 2 caratteri contro double-quotes:

if ^%ARG:~1,1% == ^" if ^%ARG:~0,1% == ^" goto blank
::else
goto goon

Ecco uno script batch con cui puoi giocare. Penso che catturi correttamente la stringa vuota.

Questo è solo un esempio, devi solo personalizzare 2 (o 3?) Passaggi in base al tuo script.

@echo off
if not "%OS%"=="Windows_NT" goto EOF
:: I guess we need enableExtensions, CMIIW
setLocal enableExtensions
set i=0
set script=%0

:LOOP
set /a i=%i%+1

set A1=%1
if not defined A1 goto nomore

:: Assumption:
:: Empty string is (exactly) a pair of double-quotes ("")

:: Step out if str length is more than 2
set C3=%A1:~2,1%
if defined C3 goto goon

:: Check the first and second char for double-quotes
:: Any characters will do fine since we test it *literally*
if ^%A1:~1,1% == ^" if ^%A1:~0,1% == ^" goto blank
goto goon

:goon
echo.args[%i%]: [%1]
shift
goto LOOP

:blank
echo.args[%i%]: [%1] is empty string
shift
goto LOOP

:nomore
echo.
echo.command line:
echo.%script% %*

:EOF

Questo risultato del test di tortura:

.test.bat :: ""  ">"""bl" " "< "">"  (")(") "" :: ""-"  " "( )"">\>" ""
args[1]: [::]
args[2]: [""] is empty string
args[3]: [">"""bl" "]
args[4]: ["< "">"]
args[5]: [(")(")]
args[6]: [""] is empty string
args[7]: [::]
args[8]: [""-"  "]
args[9]: ["( )"">\>"]
args[10]: [""] is empty string

command line:
.test.bat :: ""  ">"""bl" " "< "">"  (")(") "" :: ""-"  " "( )"">\>" ""

Puoi usare

if defined (variable) echo That's defined!
if not defined (variable) echo Nope. Undefined.

Script 1:

Input ("Rimuovi Quotes.cmd" "Questo è un test")

@ECHO OFF

REM Set "string" variable to "first" command line parameter
SET STRING=%1

REM Remove Quotes [Only Remove Quotes if NOT Null]
IF DEFINED STRING SET STRING=%STRING:"=%

REM IF %1 [or String] is NULL GOTO MyLabel
IF NOT DEFINED STRING GOTO MyLabel


REM   OR   IF "." equals "." GOTO MyLabel
IF "%STRING%." == "." GOTO MyLabel

REM GOTO End of File
GOTO :EOF

:MyLabel
ECHO Welcome!

PAUSE

Output (nessuno,% 1 NON era vuoto, vuoto o NULL):

Esegui ("Rimuovi Quotes.cmd") senza parametri con lo script sopra 1

Output (% 1 è vuoto, vuoto o NULL):

Welcome!

Press any key to continue . . .

Nota: se si imposta una variabile all'interno di IF ( ) ELSE ( )un'istruzione, questa non sarà disponibile su DEFINED fino a quando non esce dall'istruzione "IF" (a meno che non sia abilitata "Espansione ritardata variabile"; una volta abilitata utilizzare un punto esclamativo "!" Al posto del simbolo "%" percentuale}.

Per esempio:

Script 2:

Input ("Rimuovi Quotes.cmd" "Questo è un test")

@ECHO OFF

SETLOCAL EnableDelayedExpansion

SET STRING=%0
IF 1==1 (
  SET STRING=%1
  ECHO String in IF Statement='%STRING%'
  ECHO String in IF Statement [delayed expansion]='!STRING!'
) 

ECHO String out of IF Statement='%STRING%'

REM Remove Quotes [Only Remove Quotes if NOT Null]
IF DEFINED STRING SET STRING=%STRING:"=%

ECHO String without Quotes=%STRING% 

REM IF %1 is NULL GOTO MyLabel
IF NOT DEFINED STRING GOTO MyLabel

REM GOTO End of File
GOTO :EOF

:MyLabel
ECHO Welcome!

ENDLOCAL
PAUSE

Produzione:

C:\Users\Test>"C:\Users\Test\Documents\Batch Files\Remove Quotes.cmd" "This is a Test"  
String in IF Statement='"C:\Users\Test\Documents\Batch Files\Remove Quotes.cmd"'  
String in IF Statement [delayed expansion]='"This is a Test"'  
String out of IF Statement='"This is a Test"'  
String without Quotes=This is a Test  

C:\Users\Test>  

Nota: rimuoverà anche le virgolette dall'interno della stringa.

Ad esempio (utilizzando lo script 1 o 2): C: \ Users \ Test \ Documents \ Batch Files> "Rimuovi Quotes.cmd" "Questo è" un "Test"

Output (Script 2):

String in IF Statement='"C:\Users\Test\Documents\Batch Files\Remove Quotes.cmd"'  
String in IF Statement [delayed expansion]='"This is "a" Test"'  
String out of IF Statement='"This is "a" Test"'  
String without Quotes=This is a Test  

Eseguire ("Rimuovi Quotes.cmd") senza parametri nello Script 2:

Produzione:

Welcome!

Press any key to continue . . .

Per riassumere:

set str=%~1
if not defined str ( echo Empty string )

Questo codice genererà "Stringa vuota" se% 1 è "" o "o vuoto. Aggiunto alla risposta accettata che al momento non è corretta.

Ho avuto molti problemi con molte risposte in rete. La maggior parte funziona per la maggior parte delle cose, ma c'è sempre un caso d'angolo che rompe ciascuno.
Forse non funziona se ha virgolette, forse si rompe se non ha virgolette, errore di sintassi se var ha uno spazio, alcuni funzioneranno solo su parametri (al contrario di variabili d'ambiente), altre tecniche consentono un vuoto serie di virgolette da passare come 'definite', e alcune più complicate non ti permetteranno di fare una catena elsedopo

Ecco una soluzione di cui sono felice, per favore fatemi sapere se trovate un caso d'angolo per cui non funzionerà.

:ifSet
if "%~1"=="" (Exit /B 1) else (Exit /B 0)

Avere quella subroutine in uno script, o nel suo .bat, dovrebbe funzionare.
Quindi se vuoi scrivere (in pseudo):

if (var)
then something
else somethingElse

Tu puoi scrivere:

(Call :ifSet %var% && (
    Echo something
)) || (
    Echo something else
)

Ha funzionato per tutti i miei test:

(Call :ifSet && ECHO y) || ECHO n
(Call :ifSet a && ECHO y) || ECHO n
(Call :ifSet "" && ECHO y) || ECHO n
(Call :ifSet "a" && ECHO y) || ECHO n
(Call :ifSet "a a" && ECHO y) || ECHO n

Echo'd n, y, n, y,y

Altri esempi:

• Vuoi solo controllare if?Call :ifSet %var% && Echo set
• Solo se non (solo l'altro)? Call :ifSet %var% || Echo set
• Verifica di un argomento passato; funziona bene.Call :ifSet %1 && Echo set
• Non volevi ostruire i tuoi script / codice duplicato, quindi lo hai inserito nel suo ifSet.bat? Nessun problema:((Call ifSet.bat %var%) && Echo set) || (Echo not set)

Usando! anziché "per controllo stringa vuoto

@echo off
SET a=
SET b=Hello
IF !%a%! == !! echo String a is empty
IF !%b%! == !! echo String b is empty

Sono entrato da poco meno di un mese (anche se mi è stato chiesto 8 anni fa) ... Spero che ormai sia andato oltre i file batch. ;-) Lo facevo sempre. Non sono sicuro di quale sia l'obiettivo finale, però. Se è pigro come me, il mio go.bat funziona per cose del genere. (Vedi sotto) Ma, 1, il comando nell'OP potrebbe non essere valido se si utilizza direttamente l'input come comando. vale a dire,

"C:/Users/Me"

è un comando non valido (o utilizzato in precedenza su un'unità diversa). Devi romperlo in due parti.

C:
cd /Users/Me

E, 2, cosa significa "definito" o "non definito"? GIGO. Uso il valore predefinito per rilevare errori. Se l'input non viene catturato, scende per aiutare (o un comando predefinito). Quindi, nessun input non è un errore. Puoi provare a inserire un cd all'ingresso e catturare l'errore se ce n'è uno. (Ok, usando go "download (solo una parentesi) viene catturato da DOS. (Duro!))

cd "%1"
if %errorlevel% neq 0 goto :error

E, 3, le virgolette sono necessarie solo attorno al percorso, non al comando. vale a dire,

"cd C:\Users" 

era cattivo (o usato ai vecchi tempi) a meno che tu non fossi su un altro disco.

cd "\Users" 

è funzionale.

cd "\Users\Dr Whos infinite storage space"

funziona se hai spazi nel tuo percorso.

@REM go.bat
@REM The @ sigh prevents echo on the current command
@REM The echo on/off turns on/off the echo command. Turn on for debugging
@REM You can't see this.
@echo off
if "help" == "%1" goto :help

if "c" == "%1" C:
if "c" == "%1" goto :done

if "d" == "%1" D:
if "d" == "%1" goto :done

if "home"=="%1" %homedrive%
if "home"=="%1" cd %homepath%
if "home"=="%1" if %errorlevel% neq 0 goto :error
if "home"=="%1" goto :done

if "docs" == "%1" goto :docs

@REM goto :help
echo Default command
cd %1
if %errorlevel% neq 0 goto :error
goto :done

:help
echo "Type go and a code for a location/directory
echo For example
echo go D
echo will change disks (D:)
echo go home
echo will change directories to the users home directory (%homepath%)
echo go pictures
echo will change directories to %homepath%\pictures
echo Notes
echo @ sigh prevents echo on the current command
echo The echo on/off turns on/off the echo command. Turn on for debugging
echo Paths (only) with folder names with spaces need to be inclosed in         quotes (not the ommand)
goto :done

:docs
echo executing "%homedrive%%homepath%\Documents"
%homedrive%
cd "%homepath%\Documents"\test error\
if %errorlevel% neq 0 goto :error
goto :done

:error
echo Error: Input (%1 %2 %3 %4 %5 %6 %7 %8 %9) or command is invalid
echo go help for help
goto :done

:done