Query di Google SpreadSheet: posso rimuovere l'intestazione di colonna?

99

Sto eseguendo questa query sul mio foglio di lavoro Google:

=QUERY(H4:L35;"select sum(L) where H='First Week'"; -1)

Ma restituisce una piccola tabella con "somma" come intestazione e risultato sotto di essa. Quello che voglio è solo il risultato! Come rimuovo l'intestazione? Posso?

— Poliane Brito
fonte

Questo sembra più semplice: stackoverflow.com/a/41797729/5316231

— user19581

190

Prova questo:

=QUERY(H4:L35,"select sum(L) where H='First Week' label sum(L) ''")

Spero che aiuti!

— KRR
fonte

3

L'ho appena testato in uno dei miei fogli e rimuove l'intestazione dai risultati restituiti; questo dovrebbe essere contrassegnato come la risposta corretta. :)

— FooBar

1

È fantastico e funziona, ma qualcuno potrebbe spiegare perché sono necessarie le due virgolette singole alla fine? Cosa fa dal punto di vista della sintassi?

— y-i_guy

2

La virgoletta singola sostituisce l'intestazione della somma con uno spazio vuoto. Spero che questo spieghi la tua domanda !!

— KRR

2

Grazie per la risposta! Devo fare lo stesso con più di una colonna ma non posso ottenerlo! Mi aspettavo che funzionasse: = QUERY (H4: L35, "select sum (L), sum (H) where H = 'First Week' label sum (L) '' label sum (H) ''")

— Emilio Nicolás

11

LABEL B 'Label1', C 'Label2'per più colonne

— sojim2

30

=QUERY(QUERY(A1:D, "SELECT *", 1), "SELECT * OFFSET 1", 0)

La query esterna: "SELECT * OFFSET 1"esclude la prima riga (l'intestazione).

La query interna specifica esplicitamente una riga di intestazioni (tramite il terzo argomento fornito a QUERY), mentre la query esterna non ne specifica nessuna.

— user280150
fonte

3

Un po 'di spiegazione?

— J Fabian Meier

Perché il secondo è QUERYnecessario? Il parametro "0" non fa cadere le intestazioni, quindi puoi usarlo sul primo QUERY, in questo modo: QUERY('Form responses 3'!$A$2:$P$1017, "SELECT max(E),max(C), max(D) WHERE B='" & B14 & "' GROUP BY B LIMIT 1 ", 0)

— Steven M. Mortimer

3

Credo che OFFSET 1la seconda query lascerà cadere la prima riga del set di dati restituito, non le intestazioni nella prima riga.

— Steven M. Mortimer

2

Questa risposta può essere più dettagliata ma è anche più affidabile e può essere utilizzata senza la necessità di duplicare le stringhe di aggregazione delle colonne. Può anche essere usato con pivot, che non funziona con nessun'altra risposta qui.

— 7yl4r

1

A meno che non mi sbagli, questo in realtà non risolve la sfida specifica offerta dal poster originale, ovvero la rimozione delle intestazioni generate automaticamente da QUERY quando si utilizzano funzioni di aggregazione come SUM. Quando si utilizza SUM (o qualsiasi altra funzione di aggregazione), QUERY crea automaticamente una riga di intestazione che specifica l'aggregazione eseguita, ad esempio "sum". Lo farà anche se imposti le intestazioni su 0 e anche se applichi la clausola OFFSET 1. La formula seguente restituisce ancora le intestazioni. = QUERY (Sheet1! A: B, "SELECT A, SUM (B) GROUP BY A OFFSET 1", 0) La risposta accettata risolve questa sfida.

— Dave Meindl

0

Ho una QUERY che restituisce i primi 3. Non sono riuscito a farlo funzionare restituendo più righe. Ho finito per nascondere la riga con la formula e ora vengono mostrate solo le risposte.

— Brian Wochele
fonte

0

=INDEX(QUERY(H4:L35;"select sum(L) where H='First Week'"; -1),2,1)

Questo analizza semplicemente la matrice restituita e seleziona il secondo record restituito nella prima colonna.

Puoi farlo anche con la funzione di filtro che richiede meno risorse di calcolo.

=SUM(FILTER(L4:L35, H4:H35 = "First Week"))

— Dean Falconer
fonte

-3

Vedi il formato qui .

Esempio:

=QUERY(B4:C38,
   "SELECT C, sum(B) where C!='' group by C label C 'Member', sum(B) 'Sum'"
)

— Andy
fonte

2

L'esempio fornito non restituisce un risultato senza intestazioni.

— Rubén