Risposte:
dancavallaro ha ragione, %*
per tutti i parametri della riga di comando (escluso il nome dello script stesso). Potresti anche trovare questi utili:
%0
- il comando utilizzato per chiamare il file batch (potrebbe essere foo
, ..\foo
, c:\bats\foo.bat
, etc.)
%1
è il primo parametro di riga di comando,
%2
è il secondo parametro di riga di comando,
e così via fino %9
(e SHIFT
può essere utilizzato per coloro che dopo il 9 °).
%~nx0
- il nome effettivo del file batch, indipendentemente dal metodo di chiamata (some-batch.bat)
%~dp0
- unità e percorso dello script (d: \ scripts)
%~dpnx0
- è il nome percorso completo dello script (d: \ scripts \ some -batch.bat)
Maggiori informazioni su https://www.ss64.com/nt/syntax-args.html e https://www.robvanderwoude.com/parameters.html
%~dpn0
restituirà l'unità e il percorso allo script più il nome del file batch, ma non l'estensione. L'ho trovato particolarmente utile durante la creazione di script batch che chiamano un .ps1
file con lo stesso nome. In sostanza, si d
riferisce all'unità, si p
riferisce al percorso, si n
riferisce al nome del file e si x
riferisce all'estensione. Con queste informazioni, puoi fare abbastanza.
@echo %~n0.my_ext
%*
sembra contenere tutti gli argomenti passati allo script.
&
? Quando provo a recuperare diversi percorsi di diversi file selezionati (usando il menu Invia a e "% *" che passano gli arg a un .py), interrompe la lista su & car characters. Quindi, se ad esempio il secondo file contiene un &
nel suo nome, la parte del nome dopo il &
sarà ignorata e anche i file rimanenti.)
&
è un personaggio speciale che significa stop this command and start another one
. Un nome di file contenente un &
DEVE essere citato.
%1
... %n
e %*
contiene gli argomenti, ma può essere difficile accedervi, perché il contenuto verrà interpretato.
Pertanto è impossibile gestire qualcosa del genere con normali dichiarazioni
myBatch.bat "&"^&
Ogni riga non riesce, poiché cmd.exe tenta di eseguire una delle e commerciali (il contenuto di% 1 è "&"&
)
set var=%1
set "var=%1"
set var=%~1
set "var=%~1"
Ma esiste una soluzione alternativa con un file temporaneo
@echo off
SETLOCAL DisableDelayedExpansion
SETLOCAL
for %%a in (1) do (
set "prompt=$_"
echo on
for %%b in (1) do rem * #%1#
@echo off
) > param.txt
ENDLOCAL
for /F "delims=" %%L in (param.txt) do (
set "param1=%%L"
)
SETLOCAL EnableDelayedExpansion
set "param1=!param1:*#=!"
set "param1=!param1:~0,-2!"
echo %%1 is '!param1!'
Il trucco è abilitare echo on
ed espandere l' istruzione %1
after rem
(funziona anche con% 2 ..% *).
Ma per essere in grado di reindirizzare l'output diecho on
, sono necessari i due FOR-LOOPS.
I caratteri extra * #
sono usati per essere sicuri contro contenuti come /?
(mostrerebbe l'aiuto per REM).
Oppure un cursore ^ alla fine della riga potrebbe funzionare come un personaggio multilinea.
Il FOR / F dovrebbe funzionare con l'espansione ritardata disattivata, altrimenti i contenuti con "!" sarebbe distrutto.
Dopo aver rimosso i personaggi extra param1
e hai capito.
E per utilizzare param1
in modo sicuro, abilitare l'espansione ritardata.
Modifica: un'osservazione a% 0
%0
contiene il comando usato per chiamare il batch, preservando anche il caso come in FoO.BaT
Ma dopo una chiamata a una funzione %0
e anche in %~0
contiene il nome della funzione (o meglio la stringa che è stata usata per chiamare la funzione).
Ma con %~f0
te puoi ancora ricordare il nome del file.
@echo off
echo main %0, %~0, %~f0
call :myLabel+xyz
exit /b
:MYlabel
echo func %0, %~0, %~f0
exit /b
Produzione
main test.bat, test.bat, C:\temp\test.bat
func :myLabel+xyz, :myLabel+xyz, C:\temp\test.bat
%~f0
trucco è totalmente inaspettato, fantastico e potenzialmente molto utile :-) Non sorprende che gli altri modificatori funzionino allo stesso modo, operando sempre sul file batch padre, anche quando si trovano in una subroutine chiamata. Questo sembra degno del proprio Q&A - "Come accedere al nome del batch in esecuzione quando si è in una subroutine chiamata?"
L'ho scoperto la prossima volta che hai bisogno di cercare queste informazioni. Invece di aprire un browser e cercarlo su Google, puoi semplicemente digitare il call /?
tuo cmd e otterrai:
...
%* in a batch script refers to all the arguments (e.g. %1 %2 %3
%4 %5 ...)
Substitution of batch parameters (%n) has been enhanced. You can
now use the following optional syntax:
%~1 - expands %1 removing any surrounding quotes (")
%~f1 - expands %1 to a fully qualified path name
%~d1 - expands %1 to a drive letter only
%~p1 - expands %1 to a path only
%~n1 - expands %1 to a file name only
%~x1 - expands %1 to a file extension only
%~s1 - expanded path contains short names only
%~a1 - expands %1 to file attributes
%~t1 - expands %1 to date/time of file
%~z1 - expands %1 to size of file
%~$PATH:1 - searches the directories listed in the PATH
environment variable and expands %1 to the fully
qualified name of the first one found. If the
environment variable name is not defined or the
file is not found by the search, then this
modifier expands to the empty string
The modifiers can be combined to get compound results:
%~dp1 - expands %1 to a drive letter and path only
%~nx1 - expands %1 to a file name and extension only
%~dp$PATH:1 - searches the directories listed in the PATH
environment variable for %1 and expands to the
drive letter and path of the first one found.
%~ftza1 - expands %1 to a DIR like output line
In the above examples %1 and PATH can be replaced by other
valid values. The %~ syntax is terminated by a valid argument
number. The %~ modifiers may not be used with %*
Il modo per recuperare tutti gli argomenti in uno script è qui:
@ECHO off
ECHO The %~nx0 script args are...
for %%I IN (%*) DO ECHO %%I
pause
%%I
interpretare e potrebbe rompere la tua sceneggiatura.
Ecco un modo abbastanza semplice per ottenere gli arg e impostarli come env vars. In questo esempio mi limiterò a chiamarli chiavi e valori.
Salvare il seguente esempio di codice come "args.bat". Quindi chiama il file batch che hai salvato da una riga di comando. esempio: arg.bat --x 90 --y 120
Ho fornito alcuni comandi echo per guidarti nel processo. Ma il risultato finale è che --x avrà un valore di 90 e - avrà un valore di 120 (cioè se si esegue l'esempio come sopra specificato ;-)).
È quindi possibile utilizzare l'istruzione condizionale 'se definita' per determinare se eseguire o meno il blocco di codice. Quindi diciamo run: "arg.bat --x hello-world" Potrei quindi usare la frase "IF DEFINED --x echo% - x%" ei risultati sarebbero "hello-world". Dovrebbe avere più senso se si esegue il batch.
@setlocal enableextensions enabledelayedexpansion
@ECHO off
ECHO.
ECHO :::::::::::::::::::::::::: arg.bat example :::::::::::::::::::::::::::::::
ECHO :: By: User2631477, 2013-07-29 ::
ECHO :: Version: 1.0 ::
ECHO :: Purpose: Checks the args passed to the batch. ::
ECHO :: ::
ECHO :: Start by gathering all the args with the %%* in a for loop. ::
ECHO :: ::
ECHO :: Now we use a 'for' loop to search for our keys which are identified ::
ECHO :: by the text '--'. The function then sets the --arg ^= to the next ::
ECHO :: arg. "CALL:Function_GetValue" ^<search for --^> ^<each arg^> ::
ECHO :: ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO :: From the command line you could pass... arg.bat --x 90 --y 220 ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
ECHO.Checking Args:"%*"
FOR %%a IN (%*) do (
CALL:Function_GetValue "--","%%a"
)
ECHO.
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO :: Now lets check which args were set to variables... ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO :: For this we are using the CALL:Function_Show_Defined "--x,--y,--z" ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
CALL:Function_Show_Defined "--x,--y,--z"
endlocal
goto done
:Function_GetValue
REM First we use find string to locate and search for the text.
echo.%~2 | findstr /C:"%~1" 1>nul
REM Next we check the errorlevel return to see if it contains a key or a value
REM and set the appropriate action.
if not errorlevel 1 (
SET KEY=%~2
) ELSE (
SET VALUE=%~2
)
IF DEFINED VALUE (
SET %KEY%=%~2
ECHO.
ECHO ::::::::::::::::::::::::: %~0 ::::::::::::::::::::::::::::::
ECHO :: The KEY:'%KEY%' is now set to the VALUE:'%VALUE%' ::
ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
ECHO %KEY%=%~2
ECHO.
REM It's important to clear the definitions for the key and value in order to
REM search for the next key value set.
SET KEY=
SET VALUE=
)
GOTO:EOF
:Function_Show_Defined
ECHO.
ECHO ::::::::::::::::::: %~0 ::::::::::::::::::::::::::::::::
ECHO :: Checks which args were defined i.e. %~2
ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
SET ARGS=%~1
for %%s in (%ARGS%) DO (
ECHO.
ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO :: For the ARG: '%%s'
IF DEFINED %%s (
ECHO :: Defined as: '%%s=!%%s!'
) else (
ECHO :: Not Defined '%%s' and thus has no value.
)
ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
)
goto:EOF
:done
Per utilizzare il loop per ottenere tutti gli argomenti e in batch puro:
Obs: per l'utilizzo senza:?*&<>
@echo off && setlocal EnableDelayedExpansion
for %%Z in (%*)do set "_arg_=%%Z" && set/a "_cnt+=1+0" && call set "_arg_[!_cnt!]=!_arg_!")
:: write/test these arguments/parameters ::
for /l %%l in (1 1 !_cnt!)do echo/ The argument n:%%l is: !_arg_[%%l]!
goto :eof
Il tuo codice è pronto a fare qualcosa con il numero dell'argomento di cui ha bisogno, come ...
@echo off && setlocal EnableDelayedExpansion
for %%Z in (%*)do set "_arg_=%%Z" && set/a "_cnt+=1+0" && call set "_arg_[!_cnt!]=!_arg_!"
echo= !_arg_[1]! !_arg_[2]! !_arg_[2]!> log.txt
Il codice seguente simula un array (' params
'): accetta i parametri ricevuti dallo script e li memorizza nelle variabili params_1
.. params_n
, dove n
= params_0
= il numero di elementi dell'array:
@echo off
rem Storing the program parameters into the array 'params':
rem Delayed expansion is left disabled in order not to interpret "!" in program parameters' values;
rem however, if a parameter is not quoted, special characters in it (like "^", "&", "|") get interpreted at program launch
set /a count=0
:repeat
set /a count+=1
set "params_%count%=%~1"
shift
if defined params_%count% (
goto :repeat
) else (
set /a count-=1
)
set /a params_0=count
rem Printing the program parameters stored in the array 'params':
rem After the variables params_1 .. params_n are set with the program parameters' values, delayed expansion can
rem be enabled and "!" are not interpreted in the variables params_1 .. params_n values
setlocal enabledelayedexpansion
for /l %%i in (1,1,!params_0!) do (
echo params_%%i: "!params_%%i!"
)
endlocal
pause
goto :eof
Se hai virgolette tra virgolette che contengono spazi, %*
non funzionerà correttamente. La migliore soluzione che ho trovato è di avere un ciclo che unisce tutti gli argomenti: https://serverfault.com/a/22541
set args=%1
shift
:start
if [%1] == [] goto done
set args=%args% %1
shift
goto start
:done
(use %args% here)
È possibile utilizzare For
Commad per ottenere l'elenco di Arg.
Aiuto : For /?
Aiuto:Setlocal /?
Ecco la mia strada =
@echo off
::For Run Use This = cmd /c ""Args.cmd" Hello USER Scientist etc"
setlocal EnableDelayedExpansion
set /a Count=0
for %%I IN (%*) DO (
Echo Arg_!Count! = %%I
set /a Count+=1
)
Echo Count Of Args = !Count!
Endlocal
Non è necessario il comando Maiusc.
@echo off :inizio :: Inserisci qui il tuo codice echo. %% 1 ora è:% ~ 1 :: End inserisci qui il tuo codice se "% ~ 2" NEQ "" ( cambio goto: start )
Molte delle informazioni di cui sopra mi hanno portato a ulteriori ricerche e, in definitiva, alla mia risposta, quindi volevo contribuire a ciò che ho finito facendo nella speranza che aiuti qualcun altro:
Volevo anche passare un numero vario di variabili a un file batch in modo che potessero essere elaborate all'interno del file.
Sono andato bene passandoli al file batch usando le virgolette
Vorrei che fossero elaborati in modo simile al seguente, ma usando un ciclo invece di scrivere manualmente:
Quindi volevo eseguire questo:
prog_ZipDeleteFiles.bat "_appPath=C:\Services\Logs\PCAP" "_appFile=PCAP*.?"
E tramite la magia di for loop, esegui questa operazione nel file batch:
set "_appPath=C:\Services\Logs\PCAP"
set "_appFile=PCAP*.?"
Il problema che stavo riscontrando è che tutti i miei tentativi di utilizzare un ciclo for non funzionavano. L'esempio seguente:
for /f "tokens* delims= " in %%A (%*) DO (
set %%A
)
farebbe solo:
set "_appPath=C:\Services\Logs\PCAP"
e non:
set "_appPath=C:\Services\Logs\PCAP"
set "_appFile=PCAP*.?"
anche dopo l'impostazione
SETLOCAL EnableDelayedExpansion
Il motivo era che il ciclo for ha letto l'intera riga e assegnato il mio secondo parametro a %% B durante la prima iterazione del ciclo. Poiché% * rappresenta tutti gli argomenti, c'è solo una singola riga da elaborare - ergo accade solo un passaggio del ciclo for. Questo è in base alla progettazione che risulta e la mia logica era sbagliata.
Quindi ho smesso di provare a usare un ciclo for e ho semplificato quello che stavo cercando di fare usando if, shift e un'istruzione goto. D'accordo, è un po 'un trucco ma è più adatto alle mie esigenze. Posso scorrere tutti gli argomenti e quindi utilizzare un'istruzione if per uscire dal ciclo una volta elaborati tutti.
La dichiarazione vincente per quello che stavo cercando di realizzare:
echo on
:processArguments
:: Process all arguments in the order received
if defined %1 then (
set %1
shift
goto:processArguments
) ELSE (
echo off
)
AGGIORNAMENTO - Ho dovuto modificare quanto segue, mentre esponevo tutte le variabili di ambiente quando provavo a fare riferimento a% 1 e usando shift in questo modo:
echo on
shift
:processArguments
:: Process all arguments in the order received
if defined %0 then (
set %0
shift
goto:processArguments
) ELSE (
echo off
)
A volte ho bisogno di estrarre diversi parametri della riga di comando, ma non tutti e non dal primo. Supponiamo che la seguente chiamata:
Test.bat uno dos tres cuatro cinco seis siete
Naturalmente, l'estensione ".bat" non è necessaria, almeno hai test.exe nella stessa cartella. Ciò che vogliamo è ottenere l'output "tres cuatro cinco" (non importa se una riga o tre). L'obiettivo è che solo io ho bisogno di tre parametri e partire dal terzo. Per avere un semplice esempio, l'azione per ognuno è solo "eco", ma puoi pensare in qualche altra azione più complessa sui parametri selezionati.
Ho prodotto alcuni esempi (opzioni) per poter vedere quale consideri migliore per te. Sfortunatamente, non esiste un modo piacevole (o non lo so) basato su un ciclo for nell'intervallo come "per %% i in (% 3, 1,% 5)".
@echo off
setlocal EnableDelayedExpansion
echo Option 1: one by one (same line)
echo %3, %4, %5
echo.
echo Option 2: Loop For one by one
for %%a in (%3, %4, %5) do echo %%a
echo.
echo Option 3: Loop For with check of limits
set i=0
for %%a in (%*) do (
set /A i=i+1
If !i! GTR 2 if !i! LSS 6 echo %%a
)
echo.
echo Option 4: Loop For with auxiliary list
for /l %%i in (3,1,5) do (
set a=%%i
set b=echo %%
set b=!b!!a!
call !b!
)
echo.
echo Option 5: Assigning to an array of elements previously
set e[0]=%0
set i=0
for %%a in (%*) do (
set /A i=i+1
set e[!i!]=%%a
)
for /l %%i in (3,1,5) do (
echo !e[%%i]!
)
echo.
echo Option 6: using shift and goto loop. It doesn't work with for loop
set i=2
:loop6
set /A i=i+1
echo %3
shift
If %i% LSS 5 goto :loop6
Probabilmente puoi trovare più opzioni o combinarne diverse. Goditeli.