Hai aggiunto un pulsante al tuo DataGridViewe vuoi eseguire un po 'di codice quando viene cliccato.
Facile, basta seguire questi passaggi:
Cosa non fare:
Innanzitutto, ecco cosa NON fare:
Vorrei evitare i suggerimenti in alcune delle altre risposte qui e persino forniti dalla documentazione su MSDN per codificare a fondo l'indice di colonna o il nome della colonna al fine di determinare se è stato fatto clic su un pulsante. L'evento click si registra per l'intera griglia, quindi in qualche modo devi determinare che è stato fatto clic su un pulsante, ma non dovresti farlo supponendo che il tuo pulsante risieda in un particolare nome di colonna o indice ... c'è un modo più semplice ...
Inoltre, fai attenzione a quale evento vuoi gestire. Ancora una volta, la documentazione e molti esempi hanno sbagliato. La maggior parte degli esempi gestisce l' CellClickevento che genererà:
quando si fa clic su qualsiasi parte di una cella.
... ma si attiva anche ogni volta che si fa clic sull'intestazione della riga . Ciò richiede l'aggiunta di un codice aggiuntivo semplicemente per determinare se il e.RowIndexvalore è inferiore a 0
Gestisci invece ciò CellContentClickche si verifica solo:
quando si fa clic sul contenuto all'interno di una cella
Per qualsiasi motivo, anche l' intestazione della colonna è considerata "contenuto" all'interno di una cella, quindi dovremo comunque verificarlo di seguito.
dos:
Quindi, ecco cosa dovresti fare:
Innanzitutto, cast il mittente da digitare DataGridViewper esporre le sue proprietà interne in fase di progettazione. È possibile modificare il tipo sul parametro, ma ciò a volte può rendere complicata l'aggiunta o la rimozione di gestori.
Quindi, per vedere se è stato fatto clic su un pulsante, basta verificare che la colonna che solleva l'evento sia di tipo DataGridViewButtonColumn. Poiché abbiamo già trasmesso il mittente al tipo DataGridView, possiamo ottenere la Columnsraccolta e selezionare la colonna corrente utilizzando e.ColumnIndex. Quindi controlla se l'oggetto è di tipo DataGridViewButtonColumn.
Naturalmente, se devi distinguere tra più pulsanti per griglia, puoi selezionare in base al nome della colonna o all'indice, ma non dovrebbe essere il tuo primo controllo. Assicurati sempre di aver fatto clic prima su un pulsante, quindi gestisci qualsiasi altra cosa in modo appropriato. Nella maggior parte dei casi in cui hai un solo pulsante per griglia, puoi saltare direttamente alle gare.
Mettere tutto insieme:
C # :
private void dataGridView1_CellContentClick(object sender, DataGridViewCellEventArgs e)
{
var senderGrid = (DataGridView)sender;
if (senderGrid.Columns[e.ColumnIndex] is DataGridViewButtonColumn &&
e.RowIndex >= 0)
{
//TODO - Button Clicked - Execute Code Here
}
}
VB :
Private Sub DataGridView1_CellContentClick(sender As System.Object, e As DataGridViewCellEventArgs) _
Handles DataGridView1.CellContentClick
Dim senderGrid = DirectCast(sender, DataGridView)
If TypeOf senderGrid.Columns(e.ColumnIndex) Is DataGridViewButtonColumn AndAlso
e.RowIndex >= 0 Then
'TODO - Button Clicked - Execute Code Here
End If
End Sub
Aggiornamento 1 - Evento personalizzato
Se vuoi divertirti un po ', puoi aggiungere il tuo evento da sollevare ogni volta che fai clic su un pulsante su DataGrid. Non è possibile aggiungerlo al DataGrid stesso, senza diventare disordinato con l'ereditarietà ecc., Ma è possibile aggiungere un evento personalizzato al modulo e attivarlo quando appropriato. È un po 'più di codice, ma il lato positivo è che hai separato ciò che vuoi fare quando si fa clic su un pulsante con come determinare se è stato fatto clic su un pulsante.
Basta dichiarare un evento, sollevarlo quando appropriato e gestirlo. Sarà simile a questo:
Event DataGridView1ButtonClick(sender As DataGridView, e As DataGridViewCellEventArgs)
Private Sub DataGridView1_CellContentClick(sender As System.Object, e As DataGridViewCellEventArgs) Handles DataGridView1.CellContentClick
Dim senderGrid = DirectCast(sender, DataGridView)
If TypeOf senderGrid.Columns(e.ColumnIndex) Is DataGridViewButtonColumn AndAlso e.RowIndex >= 0 Then
RaiseEvent DataGridView1ButtonClick(senderGrid, e)
End If
End Sub
Private Sub DataGridView1_ButtonClick(sender As DataGridView, e As DataGridViewCellEventArgs) Handles Me.DataGridView1ButtonClick
'TODO - Button Clicked - Execute Code Here
End Sub
Aggiornamento 2 - Griglia estesa
Ciò che sarebbe fantastico sarebbe se stessimo lavorando con una griglia che faceva proprio queste cose per noi. Potremmo rispondere alla domanda iniziale facilmente: you've added a button to your DataGridView and you want to run some code when it's clicked. Ecco un approccio che estende il DataGridView. Potrebbe non valere la pena dover fornire un controllo personalizzato con ogni libreria, ma almeno riutilizza al massimo il codice utilizzato per determinare se è stato fatto clic su un pulsante.
Basta aggiungere questo al tuo assieme:
Public Class DataGridViewExt : Inherits DataGridView
Event CellButtonClick(sender As DataGridView, e As DataGridViewCellEventArgs)
Private Sub CellContentClicked(sender As System.Object, e As DataGridViewCellEventArgs) Handles Me.CellContentClick
If TypeOf Me.Columns(e.ColumnIndex) Is DataGridViewButtonColumn AndAlso e.RowIndex >= 0 Then
RaiseEvent CellButtonClick(Me, e)
End If
End Sub
End Class
Questo è tutto. Non toccarlo mai più. Assicurati che il tuo DataGrid sia di tipo DataGridViewExtche dovrebbe funzionare esattamente come un DataGridView. Tranne che genererà anche un ulteriore evento che puoi gestire in questo modo:
Private Sub DataGridView1_ButtonClick(sender As DataGridView, e As DataGridViewCellEventArgs) _
Handles DataGridView1.CellButtonClick
'TODO - Button Clicked - Execute Code Here
End Sub
