Vim: creazione di directory padre al salvataggio

Se invoco vim foo/bar/somefilema foo/barnon esisto già, Vim si rifiuta di salvare.

So che potrei passare a una shell o farlo :!mkdir foo/barda Vim ma sono pigro :) C'è un modo per far sì che Vim lo faccia automaticamente quando salva il buffer?

augroup BWCCreateDir
    autocmd!
    autocmd BufWritePre * if expand("<afile>")!~#'^\w\+:/' && !isdirectory(expand("%:h")) | execute "silent! !mkdir -p ".shellescape(expand('%:h'), 1) | redraw! | endif
augroup END

Notare le condizioni: expand("<afile>")!~#'^\w\+:/'impedirà a vim di creare directory per file come ftp://*e !isdirectoryimpedirà costose chiamate a mkdir.

Aggiornamento : soluzione leggermente migliore che controlla anche il buftype non vuoto e utilizza mkdir():

function s:MkNonExDir(file, buf)
    if empty(getbufvar(a:buf, '&buftype')) && a:file!~#'\v^\w+\:\/'
        let dir=fnamemodify(a:file, ':h')
        if !isdirectory(dir)
            call mkdir(dir, 'p')
        endif
    endif
endfunction
augroup BWCCreateDir
    autocmd!
    autocmd BufWritePre * :call s:MkNonExDir(expand('<afile>'), +expand('<abuf>'))
augroup END

Sulla base dei suggerimenti alla mia domanda, ecco cosa ho ottenuto:

function WriteCreatingDirs()
    execute ':silent !mkdir -p %:h'
    write
endfunction
command W call WriteCreatingDirs()

Questo definisce il :Wcomando. Idealmente, mi piacerebbe avere tutti :w!, :wq, :wq!, :wallecc lavorare lo stesso, ma non sono sicuro se è possibile, senza praticamente tutti reimplementare con funzioni personalizzate.

L'ho aggiunto al mio ~ / .vimrc

cnoremap mk. !mkdir -p <c-r>=expand("%:h")<cr>/

Se ho bisogno di creare la directory in cui mi trovo, la digito :mk.e la sostituisce con "! Mkdir -p / path / to / my / file /" e mi permette di rivedere il comando prima di invocarlo.

Ho :saveas!creato la directory se mancante: https://github.com/henrik/dotfiles/commit/54cc9474b345332cf54cf25b51ddb8a9bd00a0bb

Questo codice ti chiederà di creare la directory con :wo semplicemente di farlo con :w!:

augroup vimrc-auto-mkdir
  autocmd!
  autocmd BufWritePre * call s:auto_mkdir(expand('<afile>:p:h'), v:cmdbang)
  function! s:auto_mkdir(dir, force)
    if !isdirectory(a:dir)
          \   && (a:force
          \       || input("'" . a:dir . "' does not exist. Create? [y/N]") =~? '^y\%[es]$')
      call mkdir(iconv(a:dir, &encoding, &termencoding), 'p')
    endif
  endfunction
augroup END

Penso di essere riuscito a farlo in tre righe, combinando ciò che gli altri dicono su questa risposta.

Questo sembra fare il trucco:

if has("autocmd")
  autocmd BufWritePre * :silent !mkdir -p %:p:h
end

Tenta di creare la cartella automaticamente durante il salvataggio di un buffer. Se succede qualcosa di brutto (ad esempio problemi di autorizzazione) si spegnerà e lascerà che la scrittura del file fallisca.

Se qualcuno vede dei difetti evidenti, per favore pubblica un commento. Non sono molto esperto in vimscript.

EDIT: Note grazie a ZyX

• Questo non funzionerà se le tue cartelle contengono spazi (apparentemente non sono stati correttamente salvati o qualcosa del genere)
• O se stai creando pseudo file.
• O se stai cercando il tuo file vimrc.
• Ma figlio, è breve.