Come trovo dove è installato JDK sul mio computer Windows?

Devo sapere dove si trova JDK sulla mia macchina.

In esecuzione Java -versionin cmd , mostra la versione come '1.6.xx'. Per trovare la posizione di questo SDK sulla mia macchina ho provato a usarlo echo %JAVA_HOME%ma mostra solo "JAVA_HOME" (in quanto non è presente alcuna variante "JAVA_PATH" nelle variabili di ambiente).

Se si utilizza Linux / Unix / Mac OS X:

Prova questo:

$ which java

Dovrebbe produrre la posizione esatta.

Successivamente, puoi impostare JAVA_HOMEtu stesso la variabile di ambiente.

Nel mio computer (Mac OS X - Snow Leopard):

$ which java
/usr/bin/java
$ ls -l /usr/bin/java
lrwxr-xr-x  1 root  wheel  74 Nov  7 07:59 /usr/bin/java -> /System/Library/Frameworks/JavaVM.framework/Versions/Current/Commands/java

Se stai usando Windows:

c:\> for %i in (java.exe) do @echo.   %~$PATH:i

Windows> Start> cmd>

C:> for %i in (javac.exe) do @echo.   %~$PATH:i

Se è installato un JDK, viene visualizzato il percorso,
ad esempio:C:\Program Files\Java\jdk1.6.0_30\bin\javac.exe

In Windows al prompt dei comandi

where javac

In Windows il valore predefinito è: C:\Program Files\Java\jdk1.6.0_14(dove i numeri possono differire, poiché sono la versione).

Il programma di installazione Java inserisce diversi file nella cartella% WinDir% \ System32 (java.exe, javaws.exe e alcuni altri). Quando si digita java.exe nella riga di comando o si crea un processo senza percorso completo, Windows li esegue come ultima risorsa se mancano nelle cartelle% PATH%.

È possibile cercare tutte le versioni di Java installate nel registro. Dai un'occhiata a HKLM \ SOFTWARE \ JavaSoft \ Java Runtime Environment e HKLM \ SOFTWARE \ Wow6432Node \ JavaSoft \ Java Runtime Environment per Java a 32 bit su Windows a 64 bit.

Ecco come java stesso scopre diverse versioni installate. Questo è il motivo per cui entrambe le versioni a 32 e 64 bit possono coesistere e funzionano bene senza interferire.

Chiaro e semplice su piattaforme Windows:

dove java

Lo script batch di seguito stamperà il JRE predefinito esistente. Può essere facilmente modificato per trovare la versione JDK installata sostituendo Java Runtime Environment con Java Development Kit .

@echo off

setlocal

::- Get the Java Version
set KEY="HKLM\SOFTWARE\JavaSoft\Java Runtime Environment"
set VALUE=CurrentVersion
reg query %KEY% /v %VALUE% 2>nul || (
    echo JRE not installed 
    exit /b 1
)
set JRE_VERSION=
for /f "tokens=2,*" %%a in ('reg query %KEY% /v %VALUE% ^| findstr %VALUE%') do (
    set JRE_VERSION=%%b
)

echo JRE VERSION: %JRE_VERSION%

::- Get the JavaHome
set KEY="HKLM\SOFTWARE\JavaSoft\Java Runtime Environment\%JRE_VERSION%"
set VALUE=JavaHome
reg query %KEY% /v %VALUE% 2>nul || (
    echo JavaHome not installed
    exit /b 1
)

set JAVAHOME=
for /f "tokens=2,*" %%a in ('reg query %KEY% /v %VALUE% ^| findstr %VALUE%') do (
    set JAVAHOME=%%b
)

echo JavaHome: %JAVAHOME%

endlocal

Su Windows 10 puoi scoprire il percorso andando su Pannello di controllo> Java. Nel pannello che appare, puoi trovare il percorso come mostrato nello screenshot qui sotto. Nel pannello di controllo Java, vai alla scheda "Java" e fai clic sul pulsante "Visualizza" sotto la descrizione "Visualizza e gestisci le versioni e le impostazioni di Java Runtime per le applicazioni e le applet Java".

Questo dovrebbe funzionare su Windows 7 e possibilmente su altre versioni recenti di Windows.

Al prompt dei comandi di Windows, digitare:

set java_home

Oppure, se non ti piace l'ambiente di comando, puoi controllarlo da:

Menu Start> Computer> Proprietà del sistema> Proprietà di sistema avanzate. Quindi apri la scheda Avanzate> Variabili d'ambiente e nella variabile di sistema prova a trovare JAVA_HOME.

Sotto Windows, puoi usare

C:>dir /b /s java.exe

per stampare il percorso completo di ogni "java.exe" sull'unità C: indipendentemente dal fatto che si trovino sulla variabile di ambiente PATH.

Altro su Windows ... java.home non è sempre nella stessa posizione del file binario che viene eseguito.

Come dice Denis The Menace, il programma di installazione inserisce i file Java in Programmi , ma anche java.exe in System32 . Senza nulla di Java relativo al percorso java -version può ancora funzionare. Tuttavia, quando viene eseguito il programma di PeterMmm , riporta il valore di Program Files come java.home , questo non è sbagliato (Java è installato lì) ma il binario effettivo in esecuzione si trova in System32 .

Un modo per dare la caccia alla posizione del file binario java.exe , aggiungere la seguente riga al codice di PeterMmm per mantenere il programma in esecuzione per un po 'di più:

try{Thread.sleep(60000);}catch(Exception e) {}

Compilalo ed eseguilo, quindi dai la caccia alla posizione dell'immagine java.exe . Ad esempio, in Windows 7, apri il task manager, trova la voce java.exe , fai clic con il tasto destro e seleziona 'apri posizione file', questo apre la posizione esatta del binario Java. In questo caso sarebbe System32 .

Esegui questo programma dalla riga di comando:

// File: Main.java
public class Main {

    public static void main(String[] args) {
       System.out.println(System.getProperty("java.home"));
    }

}


$ javac Main.java
$ java Main

Powershell one liner:

$p='HKLM:\SOFTWARE\JavaSoft\Java Development Kit'; $v=(gp $p).CurrentVersion; (gp $p/$v).JavaHome

Hai provato a guardare la tua variabile% PATH%. Questo è ciò che Windows utilizza per trovare qualsiasi eseguibile.

Esegui semplicemente il setcomando nella tua riga di comando. Quindi vedi tutte le variabili di ambiente che hai impostato.

O se su Unix puoi semplificarlo:

$ set | grep "JAVA_HOME" 

Questo è specifico del sistema operativo. Su Unix:

which java

visualizzerà il percorso dell'eseguibile. Non conosco un equivalente di Windows, ma in genere hai la bincartella dell'installazione JDK nel sistema PATH:

echo %PATH%

Nessuna di queste risposte è corretta per Linux se stai cercando la home che include i sottodir come bin, documenti, include, jre, lib, ecc.

Su Ubuntu per openjdk1.8.0, questo è in: /usr/lib/jvm/java-1.8.0-openjdk-amd64

e potresti preferire usarlo per JAVA_HOMEpoiché sarai in grado di trovare le intestazioni se costruisci i file sorgente JNI. Sebbene sia vero which javafornirà il percorso binario, non è la vera home JDK.

Su macOS, esegui:

cd /tmp && echo 'public class Main {public static void main(String[] args) {System.out.println(System.getProperty("java.home"));}}' > Main.java && javac Main.java && java Main

Sulla mia macchina, questo stampa:

/Library/Java/JavaVirtualMachines/jdk-9.0.4.jdk/Contents/Home

Si noti che l'esecuzione which javanon mostra l'ubicazione JDK, poiché il javacomando è invece parte di JavaVM.framework, che avvolge il JDK reale:

$ which java
/usr/bin/java
/private/tmp
$ ls -l /usr/bin/java
lrwxr-xr-x  1 root  wheel  74 14 Nov 17:37 /usr/bin/java -> /System/Library/Frameworks/JavaVM.framework/Versions/Current/Commands/java

in Windows cmd:

set "JAVA_HOME" 

#!/bin/bash

if [[ $(which ${JAVA_HOME}/bin/java) ]]; then
    exe="${JAVA_HOME}/bin/java"
elif [[ $(which java) ]]; then
    exe="java"
else 
    echo "Java environment is not detected."
    exit 1
fi

${exe} -version

Per windows:

@echo off
if "%JAVA_HOME%" == "" goto nojavahome

echo Using JAVA_HOME            :   %JAVA_HOME%

"%JAVA_HOME%/bin/java.exe" -version
goto exit

:nojavahome
echo The JAVA_HOME environment variable is not defined correctly
echo This environment variable is needed to run this program.
goto exit

:exit

Questo link potrebbe aiutare a spiegare come trovare java eseguibile da bash: http://srcode.org/2014/05/07/detect-java-executable/

Ho migliorato la risposta di munsingh sopra testando la chiave di registro nei registri a 64 e 32 bit, se necessario:

::- Test for the registry location  
SET VALUE=CurrentVersion
SET KEY_1="HKLM\SOFTWARE\JavaSoft\Java Development Kit"
SET KEY_2=HKLM\SOFTWARE\JavaSoft\JDK
SET REG_1=reg.exe
SET REG_2="C:\Windows\sysnative\reg.exe"
SET REG_3="C:\Windows\syswow64\reg.exe"

SET KEY=%KEY_1%
SET REG=%REG_1%
%REG% QUERY %KEY% /v %VALUE% 2>nul
IF %ERRORLEVEL% EQU 0 GOTO _set_value

SET KEY=%KEY_2%
SET REG=%REG_1%
%REG% QUERY %KEY% /v %VALUE% 2>nul
IF %ERRORLEVEL% EQU 0 GOTO _set_value

::- %REG_2% is for 64-bit installations, using "C:\Windows\sysnative"
SET KEY=%KEY_1%
SET REG=%REG_2%
%REG% QUERY %KEY% /v %VALUE% 2>nul
IF %ERRORLEVEL% EQU 0 GOTO _set_value

SET KEY=%KEY_2%
SET REG=%REG_2%
%REG% QUERY %KEY% /v %VALUE% 2>nul
IF %ERRORLEVEL% EQU 0 GOTO _set_value

::- %REG_3% is for 32-bit installations on a 64-bit system, using "C:\Windows\syswow64"
SET KEY=%KEY_1%
SET REG=%REG_3%
%REG% QUERY %KEY% /v %VALUE% 2>nul
IF %ERRORLEVEL% EQU 0 GOTO _set_value

SET KEY=%KEY_2%
SET REG=%REG_3%
%REG% QUERY %KEY% /v %VALUE% 2>nul
IF %ERRORLEVEL% EQU 0 GOTO _set_value

:_set_value
FOR /F "tokens=2,*" %%a IN ('%REG% QUERY %KEY% /v %VALUE%') DO (
    SET JDK_VERSION=%%b
)
SET KEY=%KEY%\%JDK_VERSION%
SET VALUE=JavaHome
FOR /F "tokens=2,*" %%a IN ('%REG% QUERY %KEY% /v %VALUE%') DO (
    SET JAVAHOME=%%b
)
ECHO "%JAVAHOME%"
::- SETX JAVA_HOME "%JAVAHOME%"

riferimento per l'accesso al registro a 64 bit

Script per Windows a 32/64 bit.

@echo off

setlocal enabledelayedexpansion

::- Get the Java Version
set KEY="HKLM\SOFTWARE\JavaSoft\Java Runtime Environment"
set KEY64="HKLM\SOFTWARE\WOW6432Node\JavaSoft\Java Runtime Environment"
set VALUE=CurrentVersion
reg query %KEY% /v %VALUE% 2>nul || (
    set KEY=!KEY64!
    reg query !KEY! /v %VALUE% 2>nul || (
    echo JRE not installed 
    exit /b 1
)
)

set JRE_VERSION=
for /f "tokens=2,*" %%a in ('reg query %KEY% /v %VALUE% ^| findstr %VALUE%') do (
    set JRE_VERSION=%%b
)

echo JRE VERSION: %JRE_VERSION%

::- Get the JavaHome
set KEY="HKLM\SOFTWARE\JavaSoft\Java Runtime Environment\%JRE_VERSION%"
set KEY64="HKLM\SOFTWARE\WOW6432Node\JavaSoft\Java Runtime Environment\%JRE_VERSION%"
set VALUE=JavaHome
reg query %KEY% /v %VALUE% 2>nul || (
    set KEY=!KEY64!
    reg query !KEY! /v %VALUE% 2>nul || (
    echo JavaHome not installed
    exit /b 1
)
)

set JAVAHOME=
for /f "tokens=2,*" %%a in ('reg query %KEY% /v %VALUE% ^| findstr %VALUE%') do (
    set JAVAHOME=%%b
)

echo JavaHome: %JAVAHOME%

endlocal