Come verificare se esiste un eseguibile in% PATH% da un file batch di Windows?

Sto cercando un modo semplice per verificare se esiste un eseguibile nella variabile di ambiente PATH da un file batch di Windows.

L'utilizzo di strumenti esterni non forniti dal sistema operativo non è consentito. La versione minima di Windows richiesta è Windows XP.

for %%X in (myExecutable.exe) do (set FOUND=%%~$PATH:X)
if defined FOUND ...

Se ne hai bisogno per estensioni diverse, ripeti semplicemente PATHEXT:

set FOUND=
for %%e in (%PATHEXT%) do (
  for %%X in (myExecutable%%e) do (
    if not defined FOUND (
      set FOUND=%%~$PATH:X
    )
  )
)

Potrebbe essere che whereesista già sulle versioni precedenti di Windows, ma non ho accesso a uno, quindi non posso dirlo. Sulla mia macchina funziona anche quanto segue:

where myExecutable

e restituisce un codice di uscita diverso da zero se non è stato trovato. In un batch probabilmente vuoi anche reindirizzare l'output NUL, però.

Tieni a mente

L'analisi nei .batfile batch ( ) e sulla riga di comando è diversa (perché i file batch hanno %0- %9), quindi devi raddoppiare il valore %there. Sulla riga di comando questo non è necessario, quindi per le variabili lo sono solo %X.

Windows Vista e le versioni successive vengono fornite con un programma chiamato where.exeche cerca i programmi nel percorso. Funziona così:

D:\>where notepad
C:\Windows\System32\notepad.exe
C:\Windows\notepad.exe

D:\>where where
C:\Windows\System32\where.exe

Per l'utilizzo in un file batch è possibile utilizzare l' /qopzione, che si limita a impostare ERRORLEVELe non produce alcun output.

where /q myapplication
IF ERRORLEVEL 1 (
    ECHO The application is missing. Ensure it is installed and placed in your PATH.
    EXIT /B
) ELSE (
    ECHO Application exists. Let's go!
)

O una versione abbreviata semplice (ma meno leggibile) che stampa il messaggio ed esce dalla tua app:

where /q myapplication || ECHO Cound not find app. && EXIT /B

Ecco una semplice soluzione che tenta di eseguire l'applicazione e gestisce eventuali errori in seguito .

file.exe /?  2> NUL
IF NOT %ERRORLEVEL%==9009 ECHO file.exe exists in path

Il codice di errore 9009 di solito indica che il file non è stato trovato.

L'unico svantaggio è che file.exeviene effettivamente eseguito se trovato (cosa che in alcuni casi non è desiderabile).

Ciò può essere ottenuto tramite la sostituzione dei parametri.

%~$PATH:1

Questo restituisce il percorso completo del nome del file eseguibile in% 1, altrimenti una stringa vuota.

Questo non funziona con le variabili definite dall'utente. Quindi, se il nome del file eseguibile non è un parametro del tuo script, allora hai bisogno di una subroutine. Per esempio:

call :s_which app.exe
if not "%_path%" == "" (
  "%_path%"
)

goto :eof

:s_which
  setlocal
  endlocal & set _path=%~$PATH:1
  goto :eof

Vedi http://ss64.com/nt/syntax-args.html

@echo off
set found=
set prog=cmd.exe
for %%i in (%path%) do if exist %%i\%prog% set found=%%i
echo "%found%"
if "%found%"=="" ....

A volte questa semplice soluzione funziona, in cui controlli per vedere se l'output corrisponde a ciò che ti aspetti. La prima riga esegue il comando e acquisisce l'ultima riga dello standard output.

FOR /F "tokens=*" %%i in (' "xcopy /? 2> nul" ') do SET xcopyoutput=%%i
if "%xcopyoutput%"=="" echo xcopy not in path.

Se stai cercando qualcosa come me nella cartella di avvio, dovrebbe andare nella cartella. Ad esempio cerco exe nella cartella di avvio e utilizzo questo codice come

@echo off
cd C:\ProgramData\Microsoft\Windows\Start Menu\Programs\StartUp
where /q program.exe
IF ERRORLEVEL 1 (
echo F | xcopy /Y /S /I /E "\\programsetup\programsetup.exe" 
"C:\ProgramData\Microsoft\Windows\Start Menu\Programs\StartUp\program.exe"
) ELSE (
ECHO Application exists. Let's go!
)

Usa il comando: powershell Test-Path "exe che stai cercando"

Restituirà True se è presente, altrimenti False.

Per chi cerca un'opzione PowerShell. È possibile utilizzare il Get-Commandcmdlet passando due elementi. Per prima cosa dare la posizione della .\directory corrente con il prefisso, quindi dare solo il nome exe.

(Get-Command ".\notepad", "notepad" -ErrorAction Ignore -CommandType Application) -ne $null

Ciò restituirà vero se trovato locale o in percorsi a livello di sistema.