Suggerimenti e trucchi per Vim e Ctags [chiuso]

Ho appena installato Ctags (per aiutare lo sviluppo in C ++) con il mio Vim (o piuttosto gVim) e vorrei scoprire i tuoi comandi preferiti, macro, scorciatoie, suggerimenti che lo accompagnano ...

Condividi il tuo miglior arsenale. Quali altri componenti aggiuntivi di Vim consiglieresti per C ++ sullo sviluppo di Vim?

EDIT Quale altro componente aggiuntivo utilizzeresti insieme a Ctags?

EDIT2 Quale versione di gVim usi con i tag? Fa la differenza?

EDIT3 Come migliorate la vostra esperienza di programmazione per progetti grandi e piccoli?

Ctrl+ ]- vai alla definizione
Ctrl+ T- Torna indietro dalla definizione.
Ctrl+ W Ctrl+ ]- Apre la definizione in una divisione orizzontale

Aggiungi queste righe in vimrc
map <C-\> :tab split<CR>:exec("tag ".expand("<cword>"))<CR>
map <A-]> :vsp <CR>:exec("tag ".expand("<cword>"))<CR>

Ctrl+ \- Apre la definizione in una nuova scheda
Alt+ ]- Apre la definizione in una divisione verticale

Dopo che i tag sono stati generati. È possibile utilizzare i seguenti tasti per taggare e taggare le funzioni:

Ctrl+ Left MouseClick- Vai alla definizione
Ctrl+ Right MouseClick- Torna indietro dalla definizione

Una riga che va sempre nel mio .vimrc:

set tags=./tags;/

Questo cercherà "tag" nella directory corrente e lavorerà l'albero verso root fino a quando non ne verrà trovato uno. IOW, puoi essere ovunque nell'albero dei sorgenti anziché solo alla radice di esso.

Un altro plugin utile per lo sviluppo C è cscope Proprio come Ctags consente di passare alle definizioni, Cscope salta agli chiamata funzioni.

Se hai cscope nella tua directory ~ / bin /, aggiungi quanto segue al tuo .vimrc e usa g ^] per andare alla funzione chiamante (vedi: help cscope).

if has("cscope")
    set csprg=~/bin/cscope
    set csto=0
    set cst
    set nocsverb
    " add any database in current directory
    if filereadable("cscope.out")
        cs add cscope.out
        " else add database pointed to by environment
    elseif $CSCOPE_DB != ""
        cs add $CSCOPE_DB
    endif
endif

Quasi dimenticato ... Proprio come ctags - devi generare (e aggiornare periodicamente) il database. Uso il seguente script

select_files > cscope.files
ctags -L cscope.files
ctags -e -L cscope.files
cscope -ub -i cscope.files

Dove 'select_files' è un altro script che estrae l'elenco di file C e header dal Makefile. In questo modo indicizzo solo i file effettivamente utilizzati dal progetto.

È possibile aggiungere directory alla ricerca dei tag. Ad esempio, ho un indice ctags creato per Qt4 e lo ho nel mio .vimrc:

set tags+=/usr/local/share/ctags/qt4

Tutto quanto sopra e ...

code_complete: parametro della funzione completo, frammenti di codice e molto altro.

• http://www.vim.org/scripts/script.php?script_id=1764

taglist.vim: browser del codice sorgente (supporta C / C ++, java, perl, python, tcl, sql, php, ecc.)

• http://www.vim.org/scripts/script.php?script_id=273

Uso ALT-sinistra e ALT-destra per far apparire / spingere da / verso lo stack di tag.

" Alt-right/left to navigate forward/backward in the tags stack
map <M-Left> <C-T>
map <M-Right> <C-]>

Se usi hjklper il movimento puoi mappare <M-h>e <M-l>invece.

Diverse definizioni con lo stesso nome

<C-w>g<C-]>apri la definizione in una divisione, ma fai anche ciò :tjumpche va alla definizione o, se ci sono diverse definizioni, ti presenta un elenco di definizioni tra cui scegliere.

Il comando che sto usando di più è C-] che passa alla definizione della funzione sotto il cursore. Puoi usarlo più spesso per seguire più chiamate. Dopodiché, Co ti riporterà indietro di un livello, Ci andrà ancora più in profondità.

Ho trovato il plug-in taglist indispensabile . Elenca tutti i tag che conosce (file che hai aperto) in una finestra separata e semplifica la navigazione di file più grandi.

Lo uso principalmente per lo sviluppo di Python, ma può essere migliore solo per C / C ++.

Ho incapsulato la manipolazione dei tag in un mio plug-in sperimentale .

Per quanto riguarda lo sviluppo del C ++ in vim, ho già risposto lì : uso la mia suite e alcuni altri plugin.

Ho adattato i miei plugin vim per due anni per supportare un progetto c ++ abbastanza grande. Puoi dare un'occhiata a loro.

Usano ctags e cscsope.

http://www.vim.org/scripts/script.php?script_id=1638
http://www.vim.org/scripts/script.php?script_id=2507

Ho inserito quanto segue nel mio file .gvimrc, che cerca l'albero da qualsiasi punto per un file tag all'avvio di gvim:

function SetTags()
    let curdir = getcwd()

    while !filereadable("tags") && getcwd() != "/"
        cd ..
    endwhile

    if filereadable("tags")
        execute "set tags=" . getcwd() . "/tags"
    endif

    execute "cd " . curdir
endfunction

call SetTags()

Quindi, rigenerare periodicamente un file di tag nella parte superiore della mia struttura di origine con uno script simile al seguente:

#!/bin/bash

find . -regex ".*\.\(c\|h\|hpp\|cc\|cpp\)" -print | ctags --totals --recurse --extra="+qf" --fields="+i" -L -

Uso vim in macos e i tag originali non funzionano bene, quindi scarico il più recente e configuro make make install. Installo ctgas in / usr / local / bin / ctags (per conservare quello originale)

"taglist
let Tlist_Ctags_Cmd = "/usr/local/bin/ctags"
let Tlist_WinWidth = 50
map <leader>ta :TlistToggle<cr>
map <leader>bta :!/usr/local/bin/ctags -R .<CR>
set tags=tags;/
map <M-j> <C-]>
map <M-k> <C-T>

Ho adattato la funzione di ricerca SetTags () sopra (che dovrebbe essere sostituita dall'equivalente set tags+=./tags;/) per funzionare con cscope. Sembra funzionare!

"cscope file-searching alternative
function SetCscope()
    let curdir = getcwd()

    while !filereadable("cscope.out") && getcwd() != "/"
            cd ..
                endwhile

    if filereadable("cscope.out")
            execute "cs add " . getcwd() . "/cscope.out"
                endif

    execute "cd " . curdir
    endfunction

call SetCscope()

Un'altra iterazione sulla funzione SetCscope () sopra. Ciò imposta il pre-percorso di cscope per ottenere le corrispondenze senza essere sulla directory dove "cscope.out" è:

function s:FindFile(file)
    let curdir = getcwd()
    let found = curdir
    while !filereadable(a:file) && found != "/"
        cd ..
        let found = getcwd()
    endwhile
    execute "cd " . curdir
    return found
endfunction

if has('cscope')    
    let $CSCOPE_DIR=s:FindFile("cscope.out")
    let $CSCOPE_DB=$CSCOPE_DIR."/cscope.out"
    if filereadable($CSCOPE_DB)
        cscope add $CSCOPE_DB $CSCOPE_DIR
    endif

    command -nargs=0 Cscope !cscope -ub -R &
endif