Come scrivere lo script prevede di installare mariadb?

Ambiente: centos7 + mariadb5.5.64.
Fammi mostrare le informazioni di installazione sullo schermo quando eseguirlo mysql_secure_installation.

# mysql_secure_installation

NOTE: RUNNING ALL PARTS OF THIS SCRIPT IS RECOMMENDED FOR ALL MariaDB
      SERVERS IN PRODUCTION USE!  PLEASE READ EACH STEP CAREFULLY!

In order to log into MariaDB to secure it, we'll need the current
password for the root user.  If you've just installed MariaDB, and
you haven't set the root password yet, the password will be blank,
so you should just press enter here.

Enter current password for root (enter for none): 
OK, successfully used password, moving on...

Setting the root password ensures that nobody can log into the MariaDB
root user without the proper authorisation.

Set root password? [Y/n] y
New password: 
Re-enter new password: 
Password updated successfully!
Reloading privilege tables..
 ... Success!


By default, a MariaDB installation has an anonymous user, allowing anyone
to log into MariaDB without having to have a user account created for
them.  This is intended only for testing, and to make the installation
go a bit smoother.  You should remove them before moving into a
production environment.

Remove anonymous users? [Y/n] y
 ... Success!

Normally, root should only be allowed to connect from 'localhost'.  This
ensures that someone cannot guess at the root password from the network.

Disallow root login remotely? [Y/n] y
 ... Success!

By default, MariaDB comes with a database named 'test' that anyone can
access.  This is also intended only for testing, and should be removed
before moving into a production environment.

Remove test database and access to it? [Y/n] y
 - Dropping test database...
 ... Success!
 - Removing privileges on test database...
 ... Success!

Reloading the privilege tables will ensure that all changes made so far
will take effect immediately.

Reload privilege tables now? [Y/n] y
 ... Success!

Cleaning up...

All done!  If you've completed all of the above steps, your MariaDB
installation should now be secure.

Thanks for using MariaDB!

Scrivo uno script di automazione per l'installazione di mariadb.

  vim secure.exp
  set timeout 60
  spawn mysql_secure_installation
  expect {
      "Enter current password for root (enter for none): " {send "\r";exp_continue}
      "Set root password? [Y/n] " {send "y\r";exp_continue}
      "New password:" {send "123456\r";exp_continue}
      "Re-enter new password:" {send "123456\r";exp_continue}
      "Remove anonymous users? [Y/n]" {send "y\r";exp_continue}
      "Disallow root login remotely? [Y/n]" {send "y\r";exp_continue}
      "Remove test database and access to it? [Y/n]" {send "y\r";exp_continue}
      "Reload privilege tables now? [Y/n]" {send "y\r";exp_continue}
  }

Per eseguire /usr/bin/expect secure.exp, trovo l'errore:

spawn mysql_secure_installation
invalid command name "Y/n"
    while executing
"Y/n"
    invoked from within
"expect {
          "Enter current password for root (enter for none): " {send "\r";exp_continue}
          "Set root password? [Y/n] " {send "y\r";exp..."
    (file "secure.exp" line 3)

Non serve scrivere come di seguito:

  set timeout 60
  spawn mysql_secure_installation
  expect {
      "Enter current password for root (enter for none): " {send "\r";exp_continue}
      "Set root password? \\[Y/n] " {send "y\r";exp_continue}
      "New password:" {send "123456\r";exp_continue}
      "Re-enter new password:" {send "123456\r";exp_continue}
      "Remove anonymous users? \\[Y/n]" {send "y\r";exp_continue}
      "Disallow root login remotely? \\[Y/n]" {send "y\r";exp_continue}
      "Remove test database and access to it? \\[Y/n]" {send "y\r";exp_continue}
      "Reload privilege tables now? \\[Y/n]" {send "y\r";exp_continue}
  }

Stesso errore:

invalid command name "Y/n"
    while executing
"Y/n"
    invoked from within
"expect {
      "Enter current password for root (enter for none): " {send "\r";exp_continue}
      "Set root password? \\[Y/n] " {send "y\r";exp_conti..."
    (file "secure.exp" line 3)

Come risolvere il mio script exp quindi?

Questi script attendono di ricevere output opzionale ( timeout -1significa "nessun timeout") e possono distinguere risposte diverse, come richiesto da yum installe mysql_secure_installation. Con #!/bin/expect -fcome shebang, gli script possono essere eseguiti quando sono stati impostati su chmod +x.

A) Per cominciare, mariadb_yum.exp(richiede suo sudo):

#!/bin/expect -f
set timeout 30
if {[llength $argv] == 0} {
    send_user "Usage: mariadb_yum.exp \[linux sudo password\]\n"
    exit 1
}
set USERNAME "[exec whoami]"
set PASSWORD [lindex $argv 0];

# optionally, redirect output to log file (silent install)
# log_user 0
# log_file -a "/home/$USERNAME/mariadb_install.log"

spawn sudo yum -y install MariaDB-server
set yum_spawn_id $spawn_id

# On GCE it will never ask for a sudo password:
expect -ex "\[sudo\] password for $USERNAME: " {
   exp_send "$PASSWORD\r"
}

expect {
    # when the package was already installed
    -ex "Nothing to do" {
        send_user "package was already installed\n"
    }
    # when the package had been installed
    -ex "Complete!" {
        send_user "package had been installed\n"
    }
}

expect eof
close $yum_spawn_id
exit 0

B) E poi mariadb_sec.exp(non richiede sudo):

#!/bin/expect -f
set timeout 1
if {[llength $argv] == 0} {
    send_user "Usage: mariadb_sec.exp \[mysql root password\]\n"
    exit 1
}
set PASSWORD [lindex $argv 0];

spawn mysql_secure_installation
set mysql_spawn_id $spawn_id

# optionally, redirect output to log file (silent install)
# log_user 0
# log_file -a "/home/[exec whoami]/mariadb_install.log"

# when there is no password set, this probably should be "\r"
expect -ex "Enter current password for root (enter for none): "
exp_send "$PASSWORD\r"

expect {
    # await an eventual error message
    -ex "ERROR 1045" {
        send_user "\nMariaDB > An invalid root password had been provided.\n"
        close $mysql_spawn_id
        exit 1
    }
    # when there is a root password set
    -ex "Change the root password? \[Y/n\] " {
        exp_send "n\r"
    }
    # when there is no root password set (could not test this branch).
    -ex "Set root password? \[Y/n\] " {
        exp_send "Y\r"
        expect -ex "New password: "
        exp_send "$PASSWORD\r"
        expect -ex "Re-enter new password: "
        exp_send "$PASSWORD\r"
    }
}
expect -ex "Remove anonymous users? \[Y/n\] "
exp_send "Y\r"
expect -ex "Disallow root login remotely? \[Y/n\] "
exp_send "Y\r"
expect -ex "Remove test database and access to it? \[Y/n\] "
exp_send "Y\r"
expect -ex "Reload privilege tables now? \[Y/n\] "
exp_send "Y\r"

expect eof
close $mysql_spawn_id
exit 0

Ai fini del debug - o per convalidare la risposta, è possibile eseguire expecta livello di registro strace 4. Questo è probabilmente affidabile quanto una fonte può ottenere, quando si tratta di scrivere expectscript, in quanto mostra bene ciò che sta accadendo e, soprattutto, in quale ordine accadono le cose:

expect -c "strace 4" ./mariadb_yum.exp [linux sudo password]
expect -c "strace 4" ./mariadb_sec.exp [mysql root password]

Le istruzioni set exp_internal 1possono essere utilizzate per ottenere l'output per il regex-matching.

Una possibile fonte di confusione potrebbe essere quella in cui si generano i processi, in quanto si possono generare diversi processi su vari host, ad es. sshlocalmente e quindi yume in mysql_secure_installationremoto. Aggiunto $spawn_idallo script; la prima closechiamata potrebbe essere ridondante, dal momento che è già EOF(solo per mostrare come spawn& closeprocessi):

Thanks for using MariaDB!
 1  close $mysql_spawn_id
 1  exit 0
 2  rename _close.pre_expect close

Conclusione: mariadb_sec.expprobabilmente la sceneggiatura potrebbe essere ulteriormente migliorata, ad es. quando inizialmente non inviava password e vedeva cosa succede - quindi inviava la password ERROR 1045(quando una password era già stata impostata in precedenza). Si può pensare che si debba impostare la password quando il server è stato appena installato (tranne che yum reinstallfornisce lo stesso risultato). Non avevo un contenitore CentOS vuoto per testare tutti i casi. A meno che non rootvengano eseguiti in una shell, sarebbe necessario passare entrambi i tipi di password in uno script per automatizzare questa operazione dall'installazione fino alla post-installazione.

Probabilmente degno di nota è che su GCE, sudonon chiederebbe una password; ci sono in effetti differenze minori in base all'ambiente, poiché queste immagini del contenitore CentOS si comportano diversamente. In tal caso (poiché non è presente alcun surilevamento di immagini contenitore o in atto), lo mariadb_yum.expscript potrebbe rimanere bloccato per alcuni 30secondi e quindi continuare.

Le fonti più affidabili che posso offrire sono il expectmanuale, scritto da Don Libes @ NIST e il manuale TCL / TK expect, insieme al suo progetto SourceForge chiamato per coincidenza expect.

Non solo le parentesi quadre vengono utilizzate per la sostituzione dei comandi, ma sono anche speciali per i modelli glob .

È possibile utilizzare l' -exactinterruttore durante l'escape tra parentesi quadre tra virgolette:

spawn mysql_secure_installation
expect {
    ...
    -exact "Set root password? \[Y/n\] " {send "y\r";exp_continue}
    ...
}

Oppure usa le parentesi graffe anziché le virgolette:

spawn mysql_secure_installation
expect {
    ...
    {Set root password? \[Y/n\] } {send "y\r";exp_continue}
    ...
}

Cordiali saluti, puoi avere lo script prevede generato per te usando autoexpect:

autoexpect ./mysql_secure_installation

Questo genererà uno script prevede chiamato script.expnella directory di lavoro attuale.