Come posso produrre UTF-8 da Perl?

Sto cercando di scrivere uno script Perl usando il pragma "utf8" e ottengo risultati inaspettati. Sto usando Mac OS X 10.5 (Leopard) e sto modificando con TextMate. Tutte le mie impostazioni sia per il mio editor che per il sistema operativo sono predefinite per scrivere file in formato utf-8.

Tuttavia, quando inserisco quanto segue in un file di testo, lo salvo come ".pl" e lo eseguo, ottengo il simpatico "rombo con un punto interrogativo" al posto dei caratteri non ASCII.

#!/usr/bin/env perl -w

use strict;
use utf8;

my $str = 'Çirçös';
print( "$str\n" );

Hai idea di cosa sto sbagliando? Mi aspetto di ottenere 'Çirçös' nell'output, ma invece ottengo ' ir s'.

use utf8;non abilita l' output Unicode - ti permette di digitare Unicode nel tuo programma. Aggiungi questo al programma, prima della tua print()dichiarazione:

binmode(STDOUT, ":utf8");

Vedi se questo aiuta. Questo dovrebbe produrre STDOUToutput in UTF-8 invece che in ASCII ordinario.

Puoi usare il pragma aperto .

Per es. sotto imposta STDOUT, STDIN e STDERR per usare UTF-8 ....

use open qw/:std :utf8/;

TMTOWTDI , ha scelto il metodo che meglio si adatta al tuo lavoro. Uso il metodo ambientale quindi non devo pensarci.

In ambiente :

export PERL_UNICODE=SDL

sulla riga di comando :

perl -CSDL -le 'print "\x{1815}"';

o con binmode :

binmode(STDOUT, ":utf8");          #treat as if it is UTF-8
binmode(STDIN, ":encoding(utf8)"); #actually check if it is UTF-8

o con PerlIO :

open my $fh, ">:utf8", $filename
    or die "could not open $filename: $!\n";

open my $fh, "<:encoding(utf-8)", $filename
    or die "could not open $filename: $!\n";

o con il pragma aperto :

use open ":encoding(utf8)";
use open IN => ":encoding(utf8)", OUT => ":utf8";

Vuoi anche dire che le stringhe nel tuo codice sono utf-8. Vedere Perché il Perl moderno evita UTF-8 per impostazione predefinita? . Quindi imposta non solo PERL_UNICODE=SDALma anche PERL5OPT=-Mutf8.

Grazie, finalmente ho una soluzione per non mettere utf8 :: encode in tutto il codice. Per sintetizzare e completare per altri casi, come scrivere e leggere file in utf8 e funziona anche con LoadFile di un file YAML in utf8

use utf8;
use open ':encoding(utf8)';
binmode(STDOUT, ":utf8");

open(FH, ">test.txt"); 
print FH "something éá";

use YAML qw(LoadFile Dump);
my $PUBS = LoadFile("cache.yaml");
my $f = "2917";
my $ref = $PUBS->{$f};
print "$f \"".$ref->{name}."\" ". $ref->{primary_uri}." ";

dove cache.yaml è:

---
2917:
  id: 2917
  name: Semanário
  primary_uri: 2917.xml

fai nella tua shell: $ env | grep LANG

Questo probabilmente mostrerà che la tua shell non sta usando una locale utf-8.