Controllare se esiste una tabella temporanea ed eliminare se esiste prima di creare una tabella temporanea

Sto usando il seguente codice per verificare se esiste la tabella temporanea e rilasciarla se esiste prima di crearla nuovamente. Funziona bene finché non cambio le colonne. Se aggiungo una colonna in seguito, verrà visualizzato un errore che dice "colonna non valida". Per favore fatemi sapere cosa sto facendo di sbagliato.

IF OBJECT_ID('tempdb..#Results') IS NOT NULL
    DROP TABLE #Results

CREATE TABLE #Results
(
    Company                CHAR(3),
    StepId                TINYINT,
    FieldId                TINYINT,
)

select company, stepid, fieldid from #Results

--Works fine to this point

IF OBJECT_ID('tempdb..#Results') IS NOT NULL
    DROP TABLE #Results

CREATE TABLE #Results
(
    Company                CHAR(3),
    StepId                TINYINT,
    FieldId                TINYINT,
    NewColumn            NVARCHAR(50)
)

select company, stepid, fieldid, NewColumn from #Results

--Does not work

Non riesco a riprodurre l'errore.

Forse non capisco il problema.

In SQL Server 2005 funziona correttamente per me, con la colonna "pippo" aggiuntiva che appare nel secondo risultato di selezione:

IF OBJECT_ID('tempdb..#Results') IS NOT NULL DROP TABLE #Results
GO
CREATE TABLE #Results ( Company CHAR(3), StepId TINYINT, FieldId TINYINT )
GO
select company, stepid, fieldid from #Results
GO
ALTER TABLE #Results ADD foo VARCHAR(50) NULL
GO
select company, stepid, fieldid, foo from #Results
GO
IF OBJECT_ID('tempdb..#Results') IS NOT NULL DROP TABLE #Results
GO

La dichiarazione dovrebbe essere dell'ordine

1. Modifica l'istruzione per la tabella
2. PARTIRE
3. Seleziona la dichiarazione.

Senza "GO" nel mezzo, l'intera cosa verrà considerata come un singolo script e quando l'istruzione select cerca la colonna, non verrà trovata.

Con "GO", considererà la parte dello script fino a "GO" come un singolo batch e verrà eseguita prima di accedere alla query dopo "GO".

Invece di droppinge ricreare la tabella temporanea è possibile truncatee riutilizzarla

IF OBJECT_ID('tempdb..#Results') IS NOT NULL
    Truncate TABLE #Results
else
    CREATE TABLE #Results
    (
        Company             CHAR(3),
        StepId              TINYINT,
        FieldId             TINYINT,
    )

Se si sta utilizzando Sql Server 2016o Azure Sql Databasequindi utilizzare la sintassi seguente per eliminare la tabella temporanea e ricrearla. Maggiori informazioni qui MSDN

Sintassi

DROP TABLE [IF EXISTS] [nome_database. [nome_ schema]. | nome_schema. ] table_name [, ... n]

Query:

DROP TABLE IF EXISTS tempdb.dbo.#Results
CREATE TABLE #Results
  (
   Company             CHAR(3),
   StepId              TINYINT,
   FieldId             TINYINT,
  )

Penso che il problema sia che devi aggiungere l'istruzione GO in mezzo per separare l'esecuzione in batch. Poiché il secondo script di eliminazione IF OBJECT_ID('tempdb..#Results') IS NOT NULL DROP TABLE #Results, ad esempio, non ha eliminato la tabella temporanea facente parte di un singolo batch. Puoi provare lo script qui sotto.

IF OBJECT_ID('tempdb..#Results') IS NOT NULL
    DROP TABLE #Results

CREATE TABLE #Results
(
    Company                CHAR(3),
    StepId                TINYINT,
    FieldId                TINYINT,
)

GO

select company, stepid, fieldid from #Results

IF OBJECT_ID('tempdb..#Results') IS NOT NULL
DROP TABLE #Results

CREATE TABLE #Results
(
    Company                CHAR(3),
    StepId                TINYINT,
    FieldId                TINYINT,
    NewColumn            NVARCHAR(50)
)

GO

select company, stepid, fieldid, NewColumn from #Results

Questo potrebbe essere realizzato con una singola riga di codice:

IF OBJECT_ID('tempdb..#tempTableName') IS NOT NULL DROP TABLE #tempTableName;   

Questo ha funzionato per me: social.msdn.microsoft.com/Forums/en/transactsql/thread/02c6da90-954d-487d-a823-e24b891ec1b0?prof=required

if exists (
    select  * from tempdb.dbo.sysobjects o
    where o.xtype in ('U') 

   and o.id = object_id(N'tempdb..#tempTable')
)
DROP TABLE #tempTable;

Solo un piccolo commento dalla mia parte poiché OBJECT_IDnon funziona per me. Lo restituisce sempre

`#tempTable non esiste

..anche se non esistono. Ho appena scoperto che è memorizzato con un nome diverso (postfisso da caratteri di _sottolineatura) in questo modo:

#tempTable________

Questo funziona bene per me:

IF EXISTS(SELECT [name] FROM tempdb.sys.tables WHERE [name] like '#tempTable%') BEGIN
   DROP TABLE #tempTable;
END;

Ora puoi utilizzare la sintassi seguente se stai utilizzando una delle nuove versioni di SQL Server (2016+).

DROP TABLE IF EXISTS schema.yourtable(even temporary tables #...)

pmac72 utilizza GO per suddividere la query in batch e utilizza ALTER.

Sembra che tu stia eseguendo lo stesso batch ma eseguendolo due volte dopo averlo modificato: DROP ... CREATE ... edit ... DROP ... CREATE ..

Forse pubblica il tuo codice esatto in modo che possiamo vedere cosa sta succedendo.

Di solito ho riscontrato questo errore quando ho già creato la tabella temporanea; il codice che controlla gli errori dell'istruzione SQL vede la "vecchia" tabella temporanea in atto e restituisce un conteggio errato sul numero di colonne nelle istruzioni successive, come se la tabella temporanea non fosse mai stata eliminata.

Dopo aver modificato il numero di colonne in una tabella temporanea dopo aver già creato una versione con meno colonne, rilasciare la tabella e POI eseguire la query.

Di recente ho visto un DBA fare qualcosa di simile a questo:

begin try
    drop table #temp
end try

begin catch 
    print 'table does not exist'
end catch 

create table #temp(a int, b int)

Il mio codice utilizza una Sourcetabella che cambia e una Destinationtabella che deve corrispondere a tali modifiche.

-- 
-- Sample SQL to update only rows in a "Destination" Table
--  based on only rows that have changed in a "Source" table
--


--
-- Drop and Create a Temp Table to use as the "Source" Table
--
IF OBJECT_ID('tempdb..#tSource') IS NOT NULL drop table #tSource
create table #tSource (Col1 int, Col2 int, Col3 int, Col4 int)

--
-- Insert some values into the source
--
Insert #tSource (Col1, Col2, Col3, Col4) Values(1,1,1,1)
Insert #tSource (Col1, Col2, Col3, Col4) Values(2,1,1,2)
Insert #tSource (Col1, Col2, Col3, Col4) Values(3,1,1,3)
Insert #tSource (Col1, Col2, Col3, Col4) Values(4,1,1,4)
Insert #tSource (Col1, Col2, Col3, Col4) Values(5,1,1,5)
Insert #tSource (Col1, Col2, Col3, Col4) Values(6,1,1,6)

--
-- Drop and Create a Temp Table to use as the "Destination" Table
--
IF OBJECT_ID('tempdb..#tDest') IS NOT NULL drop Table #tDest
create table #tDest (Col1 int, Col2 int, Col3 int, Col4 int)

--
-- Add all Rows from the Source to the Destination
--
Insert #tDest
Select Col1, Col2, Col3, Col4 from #tSource


--
-- Look at both tables to see that they are the same
--
select *
from #tSource
Select *
from #tDest

--
-- Make some changes to the Source
--
update #tSource
    Set Col3=19
    Where Col1=1
update #tSource
    Set Col3=29
    Where Col1=2
update #tSource
    Set Col2=38
    Where Col1=3
update #tSource
    Set Col2=48
    Where Col1=4

--
-- Look at the Differences
-- Note: Only 4 rows are different. 2 Rows have remained the same.
--
Select Col1, Col2, Col3, Col4
from #tSource
except
Select Col1, Col2, Col3, Col4
from #tDest

--
-- Update only the rows that have changed
-- Note: I am using Col1 like an ID column
--
Update #tDest
    Set Col2=S.Col2,
        Col3=S.Col3,
        Col4=S.Col4
From    (   Select Col1, Col2, Col3, Col4
            from #tSource
            except
            Select Col1, Col2, Col3, Col4
            from #tDest
        ) S
Where #tDest.Col1=S.Col1 

--
-- Look at the tables again to see that
--  the destination table has changed to match
--  the source table.

select *
from #tSource
Select *
from #tDest

--
-- Clean Up
--
drop table #tSource
drop table #tDest

Sì, "colonna non valida" questo errore generato dalla riga "seleziona azienda, stepid, fieldid, NewColumn da #Results".

Esistono due fasi di esecuzione di t-sql,

in primo luogo, analizzando, in questa fase il server sql verifica la correzione della stringa sql inviata, inclusa la colonna della tabella, e ha ottimizzato la query per un ripristino più rapido.

secondo, correre, recuperare i dati.

Se la tabella #Results esiste, il processo di analisi controllerà che le colonne specificate siano valide o meno, altrimenti l'analisi (la tabella non esiste) verrà superata passando le colonne di verifica come specificato.

Quando si modifica una colonna in una tabella temporanea, è necessario eliminare la tabella prima di eseguire nuovamente la query. (Sì, è fastidioso. Proprio quello che devi fare.)

Ho sempre pensato che ciò fosse dovuto al fatto che il controllo "colonna non valida" viene eseguito dal parser prima che venga eseguita la query, quindi si basa sulle colonne nella tabella prima che venga rilasciata ..... ed è quello che dicevano anche i pnbs.