Come faccio a rendere l'output di CMake in una directory 'bin'?

Attualmente sto costruendo un progetto con una struttura di plugin. Sto usando CMake per compilare il progetto. I plugin sono compilati in directory separate. Il mio problema è che CMake compila e salva i binari e i plugin, librerie dinamiche, nella struttura di directory del sorgente. Come posso fare in modo che CMake salvi i file in qualcosa come una directory ./bin ?

Come nella risposta di Oleg, credo che la variabile corretta da impostare sia CMAKE_RUNTIME_OUTPUT_DIRECTORY . Nella nostra radice CMakeLists.txt utilizziamo quanto segue:

set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)

È inoltre possibile specificare le directory di output in base al target:

set_target_properties( targets...
    PROPERTIES
    ARCHIVE_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/lib"
    LIBRARY_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/lib"
    RUNTIME_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/bin"
)

In entrambi i casi è possibile aggiungere _[CONFIG]al nome della variabile / proprietà per rendere la directory di output si applicano a una configurazione specifica (i valori standard per la configurazione sono DEBUG, RELEASE, MINSIZERELe RELWITHDEBINFO).

Uso set(CMAKE_RUNTIME_OUTPUT_DIRECTORY "/some/full/path/to/bin")

Utilizzare la EXECUTABLE_OUTPUT_PATHvariabile CMake per impostare il percorso necessario. Per i dettagli, consultare la documentazione online di CMake:

Documentazione CMake 2.8.8

Quanto a me sto usando cmake 3.5, il seguito ( set variable) non funziona:

set(
      ARCHIVE_OUTPUT_DIRECTORY "/home/xy/cmake_practice/lib/"
      LIBRARY_OUTPUT_DIRECTORY "/home/xy/cmake_practice/lib/"
      RUNTIME_OUTPUT_DIRECTORY "/home/xy/cmake_practice/bin/"
)

ma questo funziona ( set set_target_properties):

set_target_properties(demo5
    PROPERTIES
    ARCHIVE_OUTPUT_DIRECTORY "/home/xy/cmake_practice/lib/"
    LIBRARY_OUTPUT_DIRECTORY "/home/xy/cmake_practice/lib/"
    RUNTIME_OUTPUT_DIRECTORY "/home/xy/cmake_practice/bin/"
)

$ cat CMakeLists.txt
project (hello)
set(EXECUTABLE_OUTPUT_PATH "bin")
add_executable (hello hello.c)

L'inglese non è la mia lingua madre; scusa gli errori di battitura.

usa questa riga config:
set(EXECUTABLE_OUTPUT_PATH ${PROJECT_SOURCE_DIR}/build/)
posiziona qualsiasi tuo progetto CMakeLists.txt.
questo $ {PROJECT_SOURCE_DIR} è la directory di origine corrente in cui si trova il progetto.
e se vagare perché $ {EXECUTABLE_OUTPUT_PATH}
controlla questo file CMakeCache.txtquindi cerca la parola chiave output path,
tutte le variabili definite qui, darebbe una spiegazione completa del progetto setting·

cat CMakeLists.txt
project (hello)
set(CMAKE_BINARY_DIR "/bin")
set(EXECUTABLE_OUTPUT_PATH ${CMAKE_BINARY_DIR})
add_executable (hello hello.c)

Indipendentemente dal fatto che lo definisca nel CMakeLists.txt principale o in quelli individuali, si presume comunque che io voglia tutte le librerie e i bin fuori dal percorso principale, che è l'assunto meno utile di tutti.

Per aggiungere a questo:

Se stai usando CMAKE per generare una soluzione di Visual Studio e vuoi che Visual Studio produca i file compilati in / bin, la risposta di Peter deve essere leggermente modificata:

# set output directories for all builds (Debug, Release, etc.)
foreach( OUTPUTCONFIG ${CMAKE_CONFIGURATION_TYPES} )
    string( TOUPPER ${OUTPUTCONFIG} OUTPUTCONFIG )
    set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY_${OUTPUTCONFIG} ${CMAKE_SOURCE_DIR}/lib )
    set( CMAKE_LIBRARY_OUTPUT_DIRECTORY_${OUTPUTCONFIG} ${CMAKE_SOURCE_DIR}/lib )
    set( CMAKE_RUNTIME_OUTPUT_DIRECTORY_${OUTPUTCONFIG} ${CMAKE_SOURCE_DIR}/bin )
endforeach( OUTPUTCONFIG CMAKE_CONFIGURATION_TYPES )