File batch. Elimina tutti i file e le cartelle in una directory

Voglio avere un file batch che eliminerà tutte le cartelle e i file nella mia cartella cache per il mio toolkit wireless.

Attualmente ho il seguente:

cd "C:\Users\tbrollo\j2mewtk\2.5.2\appdb\RMS"
del *.db

Questo eliminerà tutti i file .db nella mia directory RMS , tuttavia voglio eliminare ogni singola cosa da questa directory. Come posso fare questo?

del *.*invece di del *.db. Ciò rimuoverà tutto.

Uso:

• Crea un file batch

• Copia il testo seguente nel file batch

  set folder="C:\test"
  cd /d %folder%
  for /F "delims=" %%i in ('dir /b') do (rmdir "%%i" /s/q || del "%%i" /s/q)
  

Elimina tutti i file e le cartelle.

IF EXIST "C:\Users\tbrollo\j2mewtk\2.5.2\appdb\RMS" (
    rmdir "C:\Users\tbrollo\j2mewtk\2.5.2\appdb\RMS" /s /q
)

Ciò eliminerà tutto dalla cartella (e dalla cartella stessa).

del *.*eliminerà solo i file, ma non le sottodirectory. Per cancellare il contenuto di una directory, puoi usare questo script:

@echo off
setlocal enableextensions
if {%1}=={} goto :HELP
if {%1}=={/?} goto :HELP
goto :START

:HELP
echo Usage: %~n0 directory-name
echo.
echo Empties the contents of the specified directory,
echo WITHOUT CONFIRMATION. USE EXTREME CAUTION!
goto :DONE

:START
pushd %1 || goto :DONE
rd /q /s . 2> NUL
popd

:DONE
endlocal

Le pushdmodifiche nella directory di cui si desidera eliminare i bambini. Quindi, quando viene rdrichiesto di eliminare la directory corrente e tutte le directory secondarie, la cancellazione delle directory secondarie ha esito positivo, ma la cancellazione della directory corrente non riesce, perché ci siamo dentro. Questo produce un errore che 2> NULingoia. (2 è il flusso di errori).

Ho appena messo insieme questo da ciò che ha pubblicato morty346:

set folder="C:\test"
IF EXIST "%folder%" (
    cd /d %folder%
    for /F "delims=" %%i in ('dir /b') do (rmdir "%%i" /s/q || del "%%i" /s/q)
)

Aggiunge un rapido controllo dell'esistenza della cartella definita nella variabile, modifica la directory nella cartella ed elimina il contenuto.

Puoi farlo usando dele il /Sflag (per dirgli di ricorrere a tutti i file da tutte le sottodirectory):

del /S C:\Path\to\directory\*

Il RD comando può anche essere usato. Elimina in modo ricorsivo silenziosamente senza un prompt:

@RD /S /Q %VAR_PATH%

Rmdir (rd)

set "DIR_TO_DELETE=your_path_to_the_folder"

IF EXIST %DIR_TO_DELETE% (
    FOR /D %%p IN ("%DIR_TO_DELETE%\*.*") DO rmdir "%%p" /S /Q
    del %DIR_TO_DELETE%\*.* /F /Q
)

Prova quanto segue; per me funziona.

Ho un'applicazione che scarica i dati nella mia cartella "C: \ tmp" e quanto segue funziona meglio per me. Non chiede nemmeno Sì o No per cancellare i dati. Ho fatto un programma per farlo funzionare ogni 5 minuti

cd "C:\tmp"

del *.* /Q

Meglio ancora, diciamo che voglio rimuovere tutto sotto la C:\windows\tempcartella.

@echo off
rd C:\windows\temp /s /q

È possibile utilizzare robocopy per eseguire il mirroring di una cartella vuota sulla cartella che si sta cancellando.

robocopy "C:\temp\empty" "C:\temp\target" /E /MIR

Funziona anche se non riesci a rimuovere o ricreare la cartella attuale.

Richiede una directory vuota esistente.

Uso

set dir="Your Folder Path Here"
rmdir /s %dir%
mkdir %dir%

Questa versione cancella senza chiedere:

set dir="Your Folder Here"
rmdir /s /q %dir%
mkdir %dir%

Esempio:

set dir="C:\foo1\foo\foo\foo3"
rmdir /s /q %dir%
mkdir %dir%

Questo chiarirà C:\foo1\foo\foo\foo3.

_{(Vorrei menzionare la risposta di Abdullah Sabouin . C'è stato un disordine nel copiare me. Non ho notato il suo post. Vorrei ringraziarvi per il melpomene per aver segnalato gli errori!)}

Non è possibile cancellare tutto con uno rmdiro delda soli:

• rmdir /s /qnon accetta i parametri jolly. Quindi rmdir /s /q *errore.
• del /s /f /q eliminerà tutti i file, ma rimarranno sottodirectory vuote.

La mia soluzione preferita (come ho usato in molti altri file batch) è:

rmdir /s /q . 2>NUL

Solo una versione modificata della risposta di GregM :

set folder="C:\test"
cd /D %folder%
if NOT %errorlevel% == 0 (exit /b 1)
echo Entire content of %cd% will be deleted. Press Ctrl-C to abort
pause

REM First the directories /ad option of dir
for /F "delims=" %%i in ('dir /b /ad') do (echo rmdir "%%i" /s/q)

REM Now the files /a-d option of dir
for /F "delims=" %%i in ('dir /b /a-d') do (echo del "%%i" /q)

REM To deactivate simulation mode remove the word 'echo' before 'rmdir' and 'del'.

@echo off
@color 0A

echo Deleting logs

rmdir /S/Q c:\log\

ping 1.1.1.1 -n 5 -w 1000 > nul

echo Adding log folder back

md c:\log\

Eri sulla strada giusta. Basta aggiungere il codice per aggiungere nuovamente la cartella che viene nuovamente eliminata.

È necessario eseguire questo comando per eliminare tutti i file:

del*.*