Oracle PL / SQL - Come creare una semplice variabile array?

Vorrei creare una variabile di array in memoria che può essere utilizzata nel mio codice PL / SQL. Non riesco a trovare alcuna raccolta in Oracle PL / SQL che utilizza memoria pura, sembrano tutti associati alle tabelle. Sto cercando di fare qualcosa del genere nel mio PL / SQL (sintassi C #):

string[] arrayvalues = new string[3] {"Matt", "Joanne", "Robert"};

Modifica: Oracle: 9i

È possibile utilizzare VARRAY per un array di dimensioni fisse:

declare
   type array_t is varray(3) of varchar2(10);
   array array_t := array_t('Matt', 'Joanne', 'Robert');
begin
   for i in 1..array.count loop
       dbms_output.put_line(array(i));
   end loop;
end;

O TABELLA per un array illimitato:

...
   type array_t is table of varchar2(10);
...

La parola "tabella" qui non ha nulla a che fare con le tabelle del database, in modo confuso. Entrambi i metodi creano array in memoria.

Con uno di questi è necessario inizializzare ed estendere la raccolta prima di aggiungere elementi:

declare
   type array_t is varray(3) of varchar2(10);
   array array_t := array_t(); -- Initialise it
begin
   for i in 1..3 loop
      array.extend(); -- Extend it
      array(i) := 'x';
   end loop;
end;

Il primo indice è 1 non 0.

Potresti semplicemente dichiarare un DBMS_SQL.VARCHAR2_TABLE per contenere un array di lunghezza variabile in memoria indicizzato da un BINARY_INTEGER:

DECLARE
   name_array dbms_sql.varchar2_table;
BEGIN
   name_array(1) := 'Tim';
   name_array(2) := 'Daisy';
   name_array(3) := 'Mike';
   name_array(4) := 'Marsha';
   --
   FOR i IN name_array.FIRST .. name_array.LAST
   LOOP
      -- Do something
   END LOOP;
END;

È possibile utilizzare un array associativo (in precedenza denominato tabelle PL / SQL) in quanto sono un array in memoria.

DECLARE
   TYPE employee_arraytype IS TABLE OF employee%ROWTYPE
        INDEX BY PLS_INTEGER;
   employee_array employee_arraytype;
BEGIN
   SELECT *
     BULK COLLECT INTO employee_array
     FROM employee
    WHERE department = 10;
   --
   FOR i IN employee_array.FIRST .. employee_array.LAST
   LOOP
      -- Do something
   END LOOP;
END;

L'array associativo può contenere qualsiasi tipo di record.

Spero che sia d'aiuto, Ollie.

Un'altra soluzione è utilizzare una raccolta Oracle come hashmap:

declare 
-- create a type for your "Array" - it can be of any kind, record might be useful
  type hash_map is table of varchar2(1000) index by varchar2(30);
  my_hmap hash_map ;
-- i will be your iterator: it must be of the index's type
  i varchar2(30);
begin
  my_hmap('a') := 'apple';
  my_hmap('b') := 'box';
  my_hmap('c') := 'crow';
-- then how you use it:

  dbms_output.put_line (my_hmap('c')) ;

-- or to loop on every element - it's a "collection"
  i := my_hmap.FIRST;

  while (i is not null)  loop     
    dbms_output.put_line(my_hmap(i));      
    i := my_hmap.NEXT(i);
  end loop;

end;

Puoi anche usare un oracle defined collection

DECLARE 
  arrayvalues sys.odcivarchar2list;
BEGIN
  arrayvalues := sys.odcivarchar2list('Matt','Joanne','Robert');
  FOR x IN ( SELECT m.column_value m_value
               FROM table(arrayvalues) m )
  LOOP
    dbms_output.put_line (x.m_value||' is a good pal');
  END LOOP;
END;

Vorrei usare l'array in memoria. Ma con il .COUNTmiglioramento suggerito dall'Uziberia:

DECLARE
  TYPE t_people IS TABLE OF varchar2(10) INDEX BY PLS_INTEGER;
  arrayvalues t_people;
BEGIN
  SELECT *
   BULK COLLECT INTO arrayvalues
   FROM (select 'Matt' m_value from dual union all
         select 'Joanne'       from dual union all
         select 'Robert'       from dual
    )
  ;
  --
  FOR i IN 1 .. arrayvalues.COUNT
  LOOP
    dbms_output.put_line(arrayvalues(i)||' is my friend');
  END LOOP;
END;

Un'altra soluzione sarebbe quella di utilizzare un Hashmap come ha fatto @Jchomel qui .

NB:

Con Oracle 12c puoi persino interrogare le matrici direttamente ora !

Programmi di esempio come segue e forniti sul link anche https://oracle-concepts-learning.blogspot.com/

tabella plsql o array associato.

        DECLARE 
            TYPE salary IS TABLE OF NUMBER INDEX BY VARCHAR2(20); 
            salary_list salary; 
            name VARCHAR2(20); 
        BEGIN 
           -- adding elements to the table 
           salary_list('Rajnish') := 62000; salary_list('Minakshi') := 75000; 
           salary_list('Martin') := 100000; salary_list('James') := 78000; 
           -- printing the table name := salary_list.FIRST; WHILE name IS NOT null 
            LOOP 
               dbms_output.put_line ('Salary of ' || name || ' is ' || 
               TO_CHAR(salary_list(name))); 
               name := salary_list.NEXT(name); 
            END LOOP; 
        END; 
        /