Commentare più righe nel file batch DOS

Ho scritto un enorme file batch MS DOS. Per testare questo file batch ho bisogno di eseguire solo alcune righe e voglio nascondere / commentare rimanenti.

Ho alcune righe di commento esistenti che iniziano con, ::quindi non posso ::più usarle in quanto codificheranno tutti i commenti.

Come posso risolvere questo problema?

Puoi usare a gotoper saltare il codice.

goto comment
...skip this...
:comment

Se vuoi aggiungere REM all'inizio di ogni riga invece di usare GOTO, puoi usare Notepad ++ per farlo facilmente seguendo questi passaggi:

1. Seleziona il blocco di linee
2. premi Ctrl-Q

Ripeti i passaggi per rimuovere il commento

break||(
 code that cannot contain non paired closing bracket
)

Sebbene la gotosoluzione sia una buona opzione, non funzionerà tra parentesi (inclusi i comandi FOR e IF), ma funzionerà. Anche se dovresti fare attenzione alla chiusura delle parentesi e alla sintassi non valida per i comandi FORe IFperché verranno analizzati.

Aggiornare

L'aggiornamento in risposta del dbenham mi ha dato alcune idee. Primo - ci sono due casi diversi in cui possiamo aver bisogno di commenti su più righe - nel contesto di una parentesi in cui GOTO non può essere utilizzato e al di fuori di esso. All'interno del contesto delle parentesi possiamo usare altre parentesi se c'è una condizione che impedisce l'esecuzione del codice Anche se il codice verrà comunque analizzato e verranno rilevati alcuni errori di sintassi ( FOR,IF , staffe in modo improprio chiusi, espansione di parametro sbagliato ..). Quindi, se è possibile è meglio usare GOTO.

Sebbene non sia possibile creare una macro / variabile utilizzata come etichetta, ma è possibile utilizzare macro per i commenti delle parentesi, tuttavia si possono utilizzare due trucchi per rendere i commenti GOTO più simmetrici e più piacevoli (almeno per me). Per questo userò due trucchi: 1) puoi mettere un singolo simbolo davanti a un'etichetta e goto sarà ancora in grado di trovarlo (non ho idea del perché sia ​​questo, secondo me sta cercando un'unità).2) puoi mettere un singolo : alla fine del nome di una variabile e una funzione di sostituzione / sottrazione non verrà attivata (anche con estensioni abilitate). Che combinato con le macro per i commenti tra parentesi può far sembrare entrambi i casi quasi uguali.

Quindi ecco gli esempi (nell'ordine che mi piacciono di più):

Con staffe rettangolari :

@echo off

::GOTO comment macro
set "[:=goto :]%%"
::brackets comment macros
set "[=rem/||(" & set "]=)"

::testing
echo not commented 1

%[:%
  multi 
  line
  comment outside of brackets
%:]%

echo not commented 2

%[:%
  second multi 
  line
  comment outside of brackets
%:]%

::GOTO macro cannot be used inside for
for %%a in (first second) do (
    echo first not commented line of the %%a execution
    %[%
        multi line
        comment
    %]%
    echo second not commented line of the %%a execution
)

Con parentesi graffe :

@echo off

::GOTO comment macro
set "{:=goto :}%%"
::brackets comment macros
set "{=rem/||(" & set "}=)"

::testing
echo not commented 1

%{:%
  multi 
  line
  comment outside of brackets
%:}%

echo not commented 2

%{:%
  second multi 
  line
  comment outside of brackets
%:}%

::GOTO macro cannot be used inside for loop
for %%a in (first second) do (
    echo first not commented line of the %%a execution
    %{%
        multi line
        comment
    %}%
    echo second not commented line of the %%a execution
)

Con parentesi :

@echo off

::GOTO comment macro
set "(:=goto :)%%"
::brackets comment macros
set "(=rem/||(" & set ")=)"

::testing
echo not commented 1

%(:%
  multi 
  line
  comment outside of brackets
%:)%

echo not commented 2

%(:%
  second multi 
  line
  comment outside of brackets
%:)%

::GOTO macro cannot be used inside for loop
for %%a in (first second) do (
    echo first not commented line of the %%a execution
    %(%
        multi line
        comment
    %)%
    echo second not commented line of the %%a execution
)

Miscela tra stili PowerShell e C ( <non può essere utilizzato perché il reindirizzamento è con prezzo più alto. *Non può essere utilizzato a causa di %*):

@echo off

::GOTO comment macro
set "/#:=goto :#/%%"
::brackets comment macros
set "/#=rem/||(" & set "#/=)"

::testing
echo not commented 1

%/#:%
  multi 
  line
  comment outside of brackets
%:#/%

echo not commented 2

%/#:%
  second multi 
  line
  comment outside of brackets
%:#/%

::GOTO macro cannot be used inside for loop
for %%a in (first second) do (
    echo first not commented line of the %%a execution
    %/#%
        multi line
        comment
    %#/%
    echo second not commented line of the %%a execution
)

Per sottolineare questo è un commento (anche se non è così breve):

@echo off

::GOTO comment macro
set "REM{:=goto :}REM%%"
::brackets comment macros
set "REM{=rem/||(" & set "}REM=)"

::testing
echo not commented 1

%REM{:%
  multi 
  line
  comment outside of brackets
%:}REM%

echo not commented 2

%REM{:%
  second multi 
  line
  comment outside of brackets
%:}REM%

::GOTO macro cannot be used inside for
for %%a in (first second) do (
    echo first not commented line of the %%a execution
    %REM{%
        multi line
        comment
    %}REM%
    echo second not commented line of the %%a execution
)

Un'altra opzione è racchiudere le righe indesiderate in un blocco IF che non può mai essere vero

if 1==0 (
...
)

Ovviamente non verrà eseguito nulla all'interno del blocco if, ma verrà analizzato. Quindi non puoi avere alcuna sintassi non valida all'interno di. Inoltre, il commento non può contenere) meno che non sia sottoposto a escape o citato. Per questi motivi la soluzione GOTO accettata è più affidabile. (La soluzione GOTO potrebbe anche essere più veloce)

Aggiornamento 2017-09-19

Ecco un miglioramento cosmetico alla soluzione GOTO di pdub . Definisco una semplice variabile di ambiente "macro" che rende la sintassi del commento GOTO un po 'più auto documentata. Sebbene sia generalmente consigliato che: le etichette siano univoche all'interno di uno script batch, è davvero OK incorporare più commenti come questo nello stesso script batch.

@echo off
setlocal

set "beginComment=goto :endComment"

%beginComment%
Multi-line comment 1
goes here
:endComment

echo This code executes

%beginComment%
Multi-line comment 2
goes here
:endComment

echo Done

Oppure potresti usare una di queste varianti della soluzione di npocmaka . L'uso di REM invece di BREAK rende l'intento un po 'più chiaro.

rem.||(
   remarks
   go here
)

rem^ ||(
   The space after the caret
   is critical
)

Voglio solo menzionare che la soluzione GOTO di pdub non è completamente corretta nel caso in cui: l'etichetta del commento appare più volte. Modifico il codice da questa domanda come esempio.

@ECHO OFF
SET FLAG=1
IF [%FLAG%]==[1] (
    ECHO IN THE FIRST IF...
    GOTO comment
    ECHO "COMMENT PART 1"
:comment
    ECHO HERE AT TD_NEXT IN THE FIRST BLOCK
)

IF [%FLAG%]==[1] (
    ECHO IN THE SECOND IF...
    GOTO comment
    ECHO "COMMENT PART"
:comment
    ECHO HERE AT TD_NEXT IN THE SECOND BLOCK
)

L'output sarà

IN THE FIRST IF...
HERE AT TD_NEXT IN THE SECOND BLOCK

Il comando ECHO QUI A TD_NEXT NEL PRIMO BLOCCO viene saltato.

@jeb

E dopo averlo usato, lo stderr sembra essere inaccessibile

No, prova questo:

@echo off 2>Nul 3>Nul 4>Nul

   ben ali  
   mubarak 2>&1
   gadeffi
   ..next ?

   echo hello Tunisia

  pause

Ma perché funziona?

scusa, rispondo alla domanda in frensh:

(la redirection par 3> est spécial car elle persiste, on va l'utiliser pour capturer le flux des erreurs 2> est on va le transformer en un flusso persistant à l'ade de 3> ceci va nous permettre d'avoir une gestion des erreur pour tout notre environement de script..par la suite si on veux recuperer le flux 'stderr' il faut faire une autre redirection du handle 2> au handle 1> here n'est autre que la console ..)

prova questo:

   @echo off 2>Nul 3>Nul 4>Nul

   ben ali
   mubarak
   gadeffi
   ..next ?

   echo hello Tunisia

  pause