Numero di righe interessate da un AGGIORNAMENTO in PL / SQL

Ho una funzione PL / SQL (in esecuzione su Oracle 10g) in cui aggiorno alcune righe. C'è un modo per scoprire quante righe sono state interessate dall'aggiornamento? Quando eseguo la query manualmente mi dice quante righe sono state interessate, voglio ottenere quel numero in PL / SQL.

Si utilizza la sql%rowcountvariabile.

Devi chiamarlo subito dopo l'istruzione per la quale devi trovare il conteggio delle righe interessate.

Per esempio:

set serveroutput ON; 
DECLARE 
    i NUMBER; 
BEGIN 
    UPDATE employees 
    SET    status = 'fired' 
    WHERE  name LIKE '%Bloggs'; 
    i := SQL%rowcount; 
    --note that assignment has to precede COMMIT
    COMMIT; 
    dbms_output.Put_line(i); 
END; 

Per coloro che desiderano i risultati da un semplice comando, la soluzione potrebbe essere:

begin
  DBMS_OUTPUT.PUT_LINE(TO_Char(SQL%ROWCOUNT)||' rows affected.');
end;

Il problema di base è che SQL% ROWCOUNT è una variabile (o funzione) PL / SQL e non è possibile accedervi direttamente da un comando SQL. Utilizzando un blocco PL / SQL noname, questo può essere ottenuto.

... Se qualcuno ha una soluzione per usarlo in un comando SELECT, sarei interessato.

in alternativa, SQL%ROWCOUNT è possibile utilizzarlo all'interno della procedura senza che sia necessario dichiarare una variabile

SQL%ROWCOUNTpuò anche essere usato senza essere assegnato (almeno da Oracle 11g ).

Finché non è stata eseguita alcuna operazione (aggiornamenti, eliminazioni o inserimenti) all'interno del blocco corrente, SQL%ROWCOUNTè impostato su null. Quindi rimane con il numero di riga interessato dall'ultima operazione DML:

diciamo che abbiamo un CLIENTE da tavolo

create table client (
  val_cli integer
 ,status varchar2(10)
)
/

Lo testeremmo in questo modo:

begin
  dbms_output.put_line('Value when entering the block:'||sql%rowcount);

  insert into client 
            select 1, 'void' from dual
  union all select 4, 'void' from dual
  union all select 1, 'void' from dual
  union all select 6, 'void' from dual
  union all select 10, 'void' from dual;  
  dbms_output.put_line('Number of lines affected by previous DML operation:'||sql%rowcount);

  for val in 1..10
    loop
      update client set status = 'updated' where val_cli = val;
      if sql%rowcount = 0 then
        dbms_output.put_line('no client with '||val||' val_cli.');
      elsif sql%rowcount = 1 then
        dbms_output.put_line(sql%rowcount||' client updated for '||val);
      else -- >1
        dbms_output.put_line(sql%rowcount||' clients updated for '||val);
      end if;
  end loop;  
end;

Con il risultato di:

Value when entering the block:
Number of lines affected by previous DML operation:5
2 clients updated for 1
no client with 2 val_cli.
no client with 3 val_cli.
1 client updated for 4
no client with 5 val_cli.
1 client updated for 6
no client with 7 val_cli.
no client with 8 val_cli.
no client with 9 val_cli.
1 client updated for 10

Provi questo, per favore..

create table client (
  val_cli integer
 ,status varchar2(10)
);

---------------------
begin
insert into client
select 1, 'void' from dual
union all
select 4, 'void' from dual
union all
select 1, 'void' from dual
union all
select 6, 'void' from dual
union all
select 10, 'void' from dual;
end;

---------------------
select * from client;

---------------------
declare
  counter integer := 0;
begin
  for val in 1..10
    loop
      update client set status = 'updated' where val_cli = val;
      if sql%rowcount = 0 then
        dbms_output.put_line('no client with '||val||' val_cli.');
      else
        dbms_output.put_line(sql%rowcount||' client updated for '||val);
        counter := counter + sql%rowcount;
      end if;
  end loop;
   dbms_output.put_line('Number of total lines affected update operation: '||counter);
end;

---------------------
select * from client;

--------------------------------------------------------

Il risultato sarà come di seguito:

2 client aggiornati per 1
nessun client con 2 val_cli.
nessun client con 3 val_cli.
1 client aggiornato per 4
nessun client con 5 val_cli.
1 client aggiornato per 6
nessun client con 7 val_cli.
nessun client con 8 val_cli.
nessun client con 9 val_cli.
1 client aggiornato per 10
Numero di righe totali interessate dall'operazione di aggiornamento: 5

Utilizzare la funzione analitica Count (*) OVER PARTITION BY NULL Questo conterà il numero totale di righe