Sono un principiante di CMAKE. Di seguito è riportato un semplice file cmake che funziona bene nelle finestre dell'ambiente mingw. Il problema è chiaramente con la target_link_libraries()funzione di CMAKE in cui sto collegando libwsock32.a. In Windows funziona e ottengo i risultati.

Tuttavia, come previsto, in Linux, la /usr/bin/ldricerca -lwsock32NON è presente sul sistema operativo Linux.

Il mio problema è: come posso istruire CMAKE per evitare di collegare la libreria wsock32 nel sistema operativo Linux ???

Qualsiasi aiuto sarà molto apprezzato.

Il mio file CMake semplice:

 PROJECT(biourl)
 set (${PROJECT_NAME}_headers ./BioSocketAddress.h  ./BioSocketBase.h ./BioSocketBuffer.h ./BioSocketCommon.h  ./BioSocketListener.h  ./BioSocketPrivate.h  ./BioSocketStream.h ./BioUrl.h BioDatabase.h )

set (${PROJECT_NAME}_sources BioSocketAddress.C  BioSocketBase.C  BioSocketCommon.C BioSocketStream.C  BioUrl.C BioDatabase.C )

add_library(${PROJECT_NAME} STATIC ${${PROJECT_NAME}_headers} ${${PROJECT_NAME}_sources} )

# linkers
#find_library(ws NAMES wsock32 PATHS ${PROJECT_SOURCE_DIR} NO_SYSTEM_ENVIRONMENT_PATH NO_DEFAULT_PATH)

target_link_libraries(${PROJECT_NAME} bioutils wsock32)

install (TARGETS ${PROJECT_NAME}
       RUNTIME DESTINATION bin
       LIBRARY DESTINATION lib
       ARCHIVE DESTINATION lib/archive )

Uso

if (WIN32)
    #do something
endif (WIN32)

o

if (UNIX)
    #do something
endif (UNIX)

o

if (MSVC)
    #do something
endif (MSVC)

o simili

vedere Variabili utili di CMake e Piattaforma di controllo CMake

Dato che questo è un problema così comune, geronto-posting:

    if(UNIX AND NOT APPLE)
        set(LINUX TRUE)
    endif()

    # if(NOT LINUX) should work, too, if you need that
    if(LINUX) 
        message(STATUS ">>> Linux")
        # linux stuff here
    else()
        message(STATUS ">>> Not Linux")
        # stuff that should happen not on Linux 
    endif()

CMake boolean logic docs

Nomi delle piattaforme CMake, ecc.

In generale

Puoi rilevare e specificare variabili per diversi sistemi operativi come questo:

Rileva Microsoft Windows

if(WIN32)
    # for Windows operating system in general
endif()

O:

if(MSVC OR MSYS OR MINGW)
    # for detecting Windows compilers
endif()

Rileva Apple MacOS

if(APPLE)
    # for MacOS X or iOS, watchOS, tvOS (since 3.10.3)
endif()

Rileva Unix e Linux

if(UNIX AND NOT APPLE)
    # for Linux, BSD, Solaris, Minix
endif()

Il tuo problema con il linker specifico

Per risolvere il tuo problema con la wsock32libreria specifica di Windows , rimuovila da altri sistemi, in questo modo:

if(WIN32)
    target_link_libraries(${PROJECT_NAME} bioutils wsock32)
else
    target_link_libraries(${PROJECT_NAME} bioutils)
endif()

Hai alcune parole speciali da CMAKE, dai un'occhiata:

if(${CMAKE_SYSTEM_NAME} STREQUAL "Linux")
    // do something for Linux
else
    // do something for other OS

Sono possibili anche espressioni del generatore:

target_link_libraries(
    target_name
    PUBLIC
        libA
        $<$<PLATFORM_ID:Windows>:wsock32>
    PRIVATE
        $<$<PLATFORM_ID:Linux>:libB>
        libC
)

Questo collegherà libA, wsock32 e libC su Windows e collegherà libA, libB e libC su Linux

CMake Generator Expressions

Prova questo:

if(WIN32)
    set(ADDITIONAL_LIBRARIES wsock32)
else()
    set(ADDITIONAL_LIBRARIES "")
endif()

target_link_libraries(${PROJECT_NAME} bioutils ${ADDITIONAL_LIBRARIES})

Puoi trovare altre variabili utili qui .

Voglio lasciarlo qui perché ho lottato con questo durante la compilazione per Android in Windows con Android SDK.

CMake distingue tra TARGET e piattaforma HOST.

Il mio TARGET era Android quindi le variabili come CMAKE_SYSTEM_NAME avevano il valore "Android" e la variabile WIN32 dall'altra risposta qui non era definita. Ma volevo sapere se il mio sistema HOST era Windows perché avevo bisogno di fare alcune cose in modo diverso durante la compilazione su Windows, Linux o IO. Per farlo ho usato CMAKE_HOST_SYSTEM_NAME che ho trovato a malapena conosciuto o menzionato da nessuna parte perché per la maggior parte delle persone TARGEt e HOST sono uguali o non si preoccupano.

Spero che questo aiuti qualcuno da qualche parte ...

Usa qualche macro del preprocessore per verificare se è in Windows o Linux. Per esempio

#ifdef WIN32
LIB= 
#elif __GNUC__
LIB=wsock32
#endif

include -l $ (LIB) nel comando di compilazione.

È inoltre possibile specificare alcuni argomenti della riga di comando per differenziarli entrambi.