Attivazione silenziosa di Office 2010 dopo l'installazione automatica

Ho creato un'installazione automatica di Office 2010 utilizzando lo Strumento di personalizzazione di Office. Stiamo usando un MAK piuttosto che un KMS (non una mia decisione). C'è un modo per attivare Office 2010 dopo l'installazione? Anche se la chiave è impostata durante l'installazione, non si attiva.

Non voglio che agli utenti venga richiesto di attivarsi poiché questo si troverà in un ambiente di laboratorio.

Nel caso qualcuno si chiedesse: Office installa OSPP.VBS nella directory office14 e può gestire l'attivazione di Office, tra le altre cose.

In PTOM l'ho impostato per l'esecuzione c:\windows\system32\cscript C:\"Program Files (x86)\Microsoft Office\Office14\OSPP.VBS" /actdurante la post-installazione.

Successivamente vengono attivati ​​tutti i prodotti per ufficio. Ho installato silenziosamente Visio, Project e quindi Office e Office ha avviato l'attivazione dopo che tutti e tre i prodotti sono stati attivati ​​contemporaneamente.

Non confondere le acque in questo post, ma ho impostato questo usando questo comando in Strumento di personalizzazione di Office:
[WindowsFolder] \ system32 \ cscript [INSTALLLOCATION] \ OSPP.VBS
Con il parametro di / act

Nel caso in cui qualcun altro abbia bisogno di tali informazioni. Ross

Basta lanciare questo batch nel tuo script post sysprep, dovrebbe fare il trucco per te. Testato su sistemi a 32 e 64 bit e su diversi sistemi operativi.

Forse qualcuno può vbs questo o altro.

activateproper.cmd

REM CUSTOMER NAME HERE
REM DATE LAST MODIFIED

set _win7vlk=XXXXX-8FFQX-YYYYY-33XHT-ZZZZZ
set _2010vlk=YYYYY-YYYYY-WQGB6-KW8P8-XXXXX

REM Use current working dir
cd /d "%~dp0"

if not defined _win7vlk if not defined _2010vlk goto :nokey

echo Checking for internet connectivity needed to activate
echo This screen will not progress until internet is established
echo If you are using firewall please disable the firewall temporarily

:LOOP
PING -n 3 google.com|find "TTL" >NUL
IF NOT ERRORLEVEL 1 goto :ENDLOOP
IF     ERRORLEVEL 1 goto :LOOP
:ENDLOOP
echo Internet Detected

echo Change the time
net time \\LANMACHINEWITHCORRECTTIME /set /y

echo Prompt to activate Windows 7 if needed
if exist "%windir%\system32\slmgr.vbs" FOR /F "tokens=5" %%a in ('cscript "%windir%\system32\slmgr.vbs" -xpr') do (set _act=%%a)
if "%_act%" neq "activated." if defined _win7vlk (
    cscript "%windir%\system32\slmgr.vbs" -ipk %_win7vlk%
    cscript "%windir%\system32\slmgr.vbs" -ato
    )

echo Prompt to activate Office 2010 if needed
if exist "%PROGRAMFILES%\Microsoft Office\Office14\WINWORD.exe" set _offver=%PROGRAMFILES%
if exist "%PROGRAMFILES% (x86)\Microsoft Office\Office14\WINWORD.exe" set _offver=%PROGRAMFILES% (x86)

if defined _offver if defined _2010vlk (FOR /F "tokens=3* delims=: " %%a in ('cscript "%_offver%\Microsoft Office\Office14\OSPP.VBS" /dstatus') do (
    if "%%a" == "---OOB_GRACE---" (cscript "%_offver%\Microsoft Office\Office14\OSPP.VBS" /inpkey:%_2010vlk%
                    cscript "%_offver%\Microsoft Office\Office14\OSPP.VBS" /act)
    if "%%a" == "---OOT_GRACE---" (cscript "%_offver%\Microsoft Office\Office14\OSPP.VBS" /inpkey:%_2010vlk%
                    cscript "%_offver%\Microsoft Office\Office14\OSPP.VBS" /act)
    if "%%a" == "---NOTIFICATIONS---" (cscript "%_offver%\Microsoft Office\Office14\OSPP.VBS" /inpkey:%_2010vlk%
                    cscript "%_offver%\Microsoft Office\Office14\OSPP.VBS" /act)
    ))



:nokey

È inoltre possibile attivare Office 2010 al momento dell'installazione di una chiave MAK impostando il valore della proprietà AUTO_ACTIVATE. Per fare ciò, attenersi alla seguente procedura :

1. Nello Strumento di personalizzazione di Office, selezionare Modifica proprietà di installazione nel riquadro a sinistra, quindi fare clic su Aggiungi nel riquadro a destra.

2. Nella finestra di dialogo Aggiungi valore proprietà , nella casella Nome , digitare AUTO_ACTIVATE . Si noti che i nomi delle proprietà devono essere maiuscoli.

3. Nella casella valore digitare 1 e quindi fare clic su OK .