Uso git come backup per il mio sistema Windows ed è stato incredibilmente utile. In fondo al post, mostro gli script che utilizzo per configurare su un sistema Windows. L'uso di git come backup per qualsiasi sistema offre 2 grandi vantaggi:
- A differenza delle soluzioni commerciali spesso utilizzano il proprio formato proprietario, il backup è in un formato open source ampiamente supportato e ben documentato. Questo ti dà il pieno controllo dei tuoi dati. È molto facile vedere quali file sono cambiati e quando. Se vuoi troncare la tua storia, puoi farlo anche tu. Vuoi cancellare qualcosa dalla tua storia? Nessun problema. Ottenere una versione del tuo file è semplice come qualsiasi comando git.
- Quanti o quanti mirror vuoi e tutti possono avere tempi di backup personalizzati. Otterrai il tuo mirror locale, che è esaltato dal lento traffico Internet e ti dà quindi (1) la possibilità di eseguire backup più frequenti durante il giorno e (2) un tempo di ripristino rapido. (I backup frequenti sono un grande vantaggio, perché trovo che la maggior parte del tempo che perdo un documento sia dovuto a un errore dell'utente. Ad esempio, tuo figlio sovrascrive accidentalmente un documento su cui ha lavorato nelle ultime 5 ore.) Ma otterrai il tuo mirror remoto, che offre il vantaggio della protezione dei dati in caso di disastro locale o furto. E supponi di voler eseguire il backup del mirroring remoto in un momento personalizzato per risparmiare larghezza di banda Internet? Nessun problema.
In conclusione: un backup git ti dà un'incredibile quantità di energia nel controllare come avvengono i tuoi backup.
L'ho configurato sul mio sistema Windows. Il primo passo è creare il repository git locale in cui impegnerai tutti i tuoi dati locali. Consiglio di utilizzare un secondo disco rigido locale, ma utilizzando lo stesso disco rigido funzionerà (ma si prevede che spingerai questo da qualche parte in remoto, o altrimenti sarai fregato se il disco rigido si spegne.)
Dovrai prima installare cygwin (con rsync) e anche installare git per Windows: http://git-scm.com/download/win
Quindi, crea il tuo repository git locale (eseguilo una sola volta):
init-repo.bat:
@echo off
REM SCRIPT PURPOSE: CREATE YOUR LOCAL GIT-REPO (RUN ONLY ONCE)
REM Set where the git repository will be stored
SET GBKUP_LOCAL_MIRROR_HOME=E:\backup\mirror
REM Create the backup git repo.
SET GIT_PARAMS=--git-dir=%GBKUP_LOCAL_MIRROR_HOME%\.git --work-tree=%GBKUP_LOCAL_MIRROR_HOME%
mkdir %GBKUP_LOCAL_MIRROR_HOME%
git %GIT_PARAMS% init
git %GIT_PARAMS% config core.autocrlf false
git %GIT_PARAMS% config core.ignorecase false
git %GIT_PARAMS% config core.fileMode false
git %GIT_PARAMS% config user.email backup@yourComputerName
git %GIT_PARAMS% config user.name backup
REM add a remote to the git repo. Make sure you have set myRemoteServer in ~/.ssh/config
REM The path on the remote server will vary. Our remote server is a Windows machine running cygwin+ssh.
REM For better security, you could install gitolite on the remote server, and forbid any non-fast-forward merges, and thus stop a malicious user from overwriting your backups.
git %GIT_PARAMS% remote add origin myRemoteServer:/cygdrive/c/backup/yourComputerName.git
REM treat all files as binary; so you don't have to worry about autocrlf changing your line endings
SET ATTRIBUTES_FILE=%GBKUP_LOCAL_MIRROR_HOME%\.git\info\attributes
echo.>> %ATTRIBUTES_FILE%
echo *.gbkuptest text>> %ATTRIBUTES_FILE%
echo * binary>> %ATTRIBUTES_FILE%
REM compression is often a waste of time with binary files
echo * -delta>> %ATTRIBUTES_FILE%
REM You may need to get rid of windows new lines. We use cygwin's tool
C:\cygwin64\bin\dos2unix %ATTRIBUTES_FILE%
Successivamente, abbiamo il nostro wrapper di script di backup, che verrà chiamato regolarmente dall'utilità di pianificazione di Windows:
gbackup.vbs:
' A simple vbs wrapper to run your bat file in the background
Set oShell = CreateObject ("Wscript.Shell")
Dim strArgs
strArgs = "cmd /c C:\opt\gbackup\gbackup.bat"
oShell.Run strArgs, 0, false
Successivamente, abbiamo lo script di backup stesso che il wrapper chiama:
gbackup.bat:
@echo off
REM Set where the git repository will be stored
SET GBKUP_LOCAL_MIRROR_HOME=E:\backup\mirror
REM the user which runs the scheduler
SET GBKUP_RUN_AS_USER=yourWindowsUserName
REM exclude file
SET GBKUP_EXCLUDE_FILE=/cygdrive/c/opt/gbackup/exclude-from.txt
SET GBKUP_TMP_GIT_DIR_NAME=git-renamed
for /f "delims=" %%i in ('C:\cygwin64\bin\cygpath %GBKUP_LOCAL_MIRROR_HOME%') do set GBKUP_LOCAL_MIRROR_CYGWIN=%%i
REM rename any .git directories as they were (see below command)
for /r %GBKUP_LOCAL_MIRROR_HOME% %%i in (%GBKUP_TMP_GIT_DIR_NAME%) do ren "%%i" ".git" 2> nul
SET RSYNC_CMD_BASE=C:\cygwin64\bin\rsync -ahv --progress --delete --exclude-from %GBKUP_EXCLUDE_FILE%
REM rsync all needed directories to local mirror
%RSYNC_CMD_BASE% /cygdrive/c/dev %GBKUP_LOCAL_MIRROR_CYGWIN%
%RSYNC_CMD_BASE% /cygdrive/c/Users/asmith %GBKUP_LOCAL_MIRROR_CYGWIN%
%RSYNC_CMD_BASE% /cygdrive/c/Users/bsmith %GBKUP_LOCAL_MIRROR_CYGWIN%
cacls %GBKUP_LOCAL_MIRROR_HOME% /t /e /p %GBKUP_RUN_AS_USER%:f
REM rename any .git directories as git will ignore the entire directory, except the main one
for /r %GBKUP_LOCAL_MIRROR_HOME% %%i in (.git) do ren "%%i" "%GBKUP_TMP_GIT_DIR_NAME%" 2> nul
ren %GBKUP_LOCAL_MIRROR_HOME%\%GBKUP_TMP_GIT_DIR_NAME% .git
REM finally commit to git
SET GIT_PARAMS=--git-dir=%GBKUP_LOCAL_MIRROR_HOME%\.git --work-tree=%GBKUP_LOCAL_MIRROR_HOME%
SET BKUP_LOG_FILE=%TMP%\git-backup.log
SET TO_LOG=1^>^> %BKUP_LOG_FILE% 2^>^&1
echo ===========================BACKUP START=========================== %TO_LOG%
For /f "tokens=2-4 delims=/ " %%a in ('date /t') do (set mydate=%%c-%%a-%%b)
For /f "tokens=1-2 delims=/:" %%a in ('time /t') do (set mytime=%%a%%b)
echo %mydate%_%mytime% %TO_LOG%
echo updating git index, committing, and then pushing to remote %TO_LOG%
REM Caution: The --ignore-errors directive tells git to continue even if it can't access a file.
git %GIT_PARAMS% add -Av --ignore-errors %TO_LOG%
git %GIT_PARAMS% commit -m "backup" %TO_LOG%
git %GIT_PARAMS% push -vv --progress origin master %TO_LOG%
echo ===========================BACKUP END=========================== %TO_LOG%
Abbiamo il file exclude-from.txt, dove mettiamo tutti i file da ignorare:
escludere-from.txt:
target/
logs/
AppData/
Downloads/
trash/
temp/
.idea/
.m2/
.IntelliJIdea14/
OLD/
Searches/
Videos/
NTUSER.DAT*
ntuser.dat*
Dovrai andare su qualsiasi repository remoto e fare un 'git init --bare' su di essi. È possibile testare lo script eseguendo lo script di backup. Supponendo che tutto funzioni, vai a Utilità di pianificazione di Windows e punta un backup orario verso il file vbs. Successivamente, avrai una cronologia git del tuo computer per ogni ora. È estremamente conveniente: ogni cancella accidentalmente una sezione di testo e la manca? Controlla il tuo repository git.