MSIZAP è ancora utile o è obsoleto?

Aggiornamento flash utilizzando file MSI installati in base ai criteri di gruppo. Tuttavia, con ogni aggiornamento, circa un terzo delle workstation non si aggiorna (edizioni Windows Vista e Windows 7 a 32/64 bit). Nei registri eventi, viene visualizzato questo messaggio:

"Adobe Flash Player 11 ActiveX - Errore 1714. Impossibile rimuovere la versione precedente di Adobe Flash Player 11 ActiveX. Contattare il gruppo di supporto tecnico. Errore di sistema 1612."

L'unico modo in cui sono stato in grado di risolvere il problema è utilizzare lo strumento Microsoft Fit It . Tuttavia, è un processo che richiede molto tempo, che richiede circa 15 minuti per eseguire manualmente per ogni workstation, quindi uccide efficacemente un giorno intero ogni volta che viene rilasciato un aggiornamento flash.

Mi sono imbattuto in questo script che include MSIZAP per rimuovere le disinstallazioni non riuscite di Flash. Quindi, la mia domanda è : l'utility MSIZAP è l'approccio migliore per la rimozione programmatica del flash o è obsoleta a questo punto? Il motivo per cui chiedo è che la maggior parte dei materiali scritti che ho trovato sull'argomento provengono dal 2009 o dal 2010.

@echo off
SET MSIZAP=\\my.domain.com\netlogon\bin\msizap.exe
SET DFSPATH=\\my.domain.com\dfsroot\Packages\Adobe

SET UNINSTALL=%DFSPATH%\uninstall_flash_player_x86.exe
SET INSTALL=%DFSPATH%\install_flash_player_11.4.402.278_active_x.exe 

rem Detect 64-bit Windows
IF NOT "%ProgramFiles(x86)%"=="" SET WOW6432NODE=WOW6432NODE\

SET VER_FLAG_KEY=HKEY_LOCAL_MACHINE\SOFTWARE\%WOW6432NODE%Macromedia\FlashPlayer
SET VER_FLAG_VALUE=11,4,402,278

REG QUERY "%VER_FLAG_KEY%" /v CurrentVersion | find /i "%VER_FLAG_VALUE%" > NUL 2>NUL
if errorlevel 1 goto do_install
goto :EOF

:do_install
rem Uninstall all old versions of Flash.
start /wait /min "" "%UNINSTALL%" -uninstall activex

rem MSIZAP all old versions
start /wait /min "" "%MSIZAP%" TW! {2BD2FA21-B51D-4F01-94A7-AC16737B2163}
start /wait /min "" "%MSIZAP%" TW! {B7B3E9B3-FB14-4927-894B-E9124509AF5A}
start /wait /min "" "%MSIZAP%" TW! {FA1D6742-0515-4A94-AD5D-F0484026E4A2}

rem Run new installer
start /wait /min "" "%INSTALL%" -install activex

rem Block future automatic updates
SET DEST="%windir%\system32\Macromed\Flash\mms.cfg"

rem Detect 64-bit Windows
IF NOT "%ProgramFiles(x86)%"=="" SET DEST="%windir%\SysWOW64\Macromed\Flash\mms.cfg"

rem I'm using "sort" here because the redirect is being interpreted as "1>" and
rem doing "1 >" causes a space to be stored in the file, which "breaks" the file.
echo AutoUpdateDisable=1|sort>%DEST%

Fonte: ho distribuito Flash Player tramite una politica di installazione del software. Come aggiornare?

— Force Flow
fonte

Se si dispone di un elenco di GUID, perché non semplicemente percorrerli e disinstallarli? Qualcosa del tipo: msiexec /x {the-product-guid} /qn- Quello dovrebbe disinstallare il prodotto [s]. Non credo che MsiZap sia supportato .

— jscott,

Tieni presente che questi programmi non possono essere disinstallati completamente tramite i criteri di gruppo e non possono essere reinstallati o aggiornati finché non vengono ripuliti con lo strumento Correggi. Per quanto ne sapevo, msiexec funziona solo quando le cose funzionano davvero correttamente.

— Force Flow,

Stai reimballando il programma di installazione di Flash con un MSI o utilizzandone uno fornito? L'MSI non è cambiato in modo significativo da diversi anni, quindi i meccanismi sottostanti non sono realmente cambiati. Detto questo, lo zapping in primo luogo è un meccanico a forza bruta che potrebbe aver portato a futuri fallimenti. La correzione È fondamentalmente automatizzabile se sei facile con PowerShell, anche se non lo consiglierei ufficialmente. (Lavoro per Microsoft, quindi non lo consiglio - sto solo dicendo che il fegato è PowerShell e teoricamente potrebbe essere fatto.)

— Matthew Wetmore

Stai cercando di installare la nuova versione su quella precedente e fare affidamento sul suo programma di installazione per la rimozione? Oppure dici al programma di installazione di Windows di disinstallare prima il vecchio, prima di installare il nuovo?

Se fai il primo, ti consiglio di passare al successivo, perché ho avuto quasi solo una buona esperienza con questo. L'unica eccezione è stata quando una volta Adobe ha inserito un numero di versione errato nel comando di disinstallazione all'interno di msi (ma era riproducibile al 100% e quindi immediatamente visibile su un computer di prova prima della distribuzione).

Vedi /server//a/441131/144344 e /server//a/564881/144344

— Klaus Hartnegg
fonte