Come posso creare automaticamente un elenco di cartelle con nome in Windows?

Quindi, sto studiando un corso online che ha centinaia di lezioni secondarie. Devo scaricare il codice sorgente per ogni lezione in una sottocartella corrispondente. Con oltre 120 lezioni, la creazione di una sottocartella una alla volta è un processo scrupoloso.

Ecco la mia attuale struttura di cartelle:

C'è un modo in cui posso creare tutte queste sottocartelle contemporaneamente, insieme al nome proprio, attraverso un file batch o qualcosa di simile.

Come posso creare tutte queste sottocartelle contemporaneamente, usando il mio schema di denominazione?

Se dovessi creare le sottocartelle in una directory specifica, come C: \ Dropbox \ Development, dovrei prima effettuare il cd in quella directory? Supponendo che sto usando la shell cmd?

Per creare le sottocartelle (sottodirectory) in una directory specifica (che non è la directory corrente), è possibile effettuare una delle seguenti operazioni:

• cd C:\Dropbox\Development prima o
• Cambia il md Lec-%%icomando in md C:\Dropbox\Development\Lec-%%i.

Nota:

• mkdirè sinonimo di mde può essere utilizzato al suo posto.

Di seguito mostro entrambe le alternative, prima da una cmdshell (riga di comando) e seconda usando un file batch.

Come bonus (anche se non richiesto nella domanda originale) c'è anche bashun'alternativa alla shell.

Da una cmdshell:

cd C:\Dropbox\Development
for /l %i in (9,1,120) do md Lec-%i

o

for /l %i in (9,1,120) do md C:\Dropbox\Development\Lec-%i

Da un file batch:

@echo off
cd C:\Dropbox\Development
for /l %%i in (9,1,120) do md Lec-%%i

O

@echo off
for /l %%i in (9,1,120) do md C:\Dropbox\Development\Lec-%%i

Appunti:

• 9è il numero iniziale. Cambia se necessario.
• 1è il passo. Non cambiare questo.
• 120il numero finale. Modificare, se necessario, il numero dell'ultima directory richiesta.

• Per creare file in un'altra directory, puoi farlo

  • cd C:\Dropbox\Development\Lec-%%i prima o
  • cambia il mdcomando in md C:\Dropbox\Development\Lec-%%i.

C'è un modo per fare una cosa simile per Mac OSX dal terminale Mac?

Da una bashshell:

for i in {9..120}; do mkdir Lec-$i; done; 

Oppure (per una versione più portatile)

for i in `seq 9 120`; do mkdir Lec-$i; done;

Ulteriori letture

• Un indice AZ della riga di comando CMD di Windows - Un riferimento eccellente per tutte le cose relative alla riga cmd di Windows.
• per - Esegui condizionalmente un comando più volte.
• md - Crea directory - Crea una nuova cartella.

C'è un altro modo semplice, per un numero limitato di cartelle. Può essere utile qui o per qualcun altro.

In Windows possiamo creare nomi di cartelle numerati creando una cartella "lec (1)" e copiandola incollandola quante volte vogliamo, se incolliamo 10 volte ci saranno 11 cartelle con nomi "lect (1)" in "lec ( 10) - Copia "

L'unico trucco qui è che la prima cartella deve contenere parentesi (n), dove n è il numero da cui inizia la numerazione.

Windows include "- copia" in corrispondenza del nome della cartella incollata "lec (1) - Copia" :(

Se non ti piace, seleziona tutto e rinomina prima lec (1) -> lec- (1) o altro.

Tutti i nomi delle cartelle verranno adattati e "- copia" verrà rimosso;)

• Ctrl + C - Copia
• Ctrl + V - Incolla
• F2 - rinomina
• Invio - per terminare la ridenominazione.
• ESC- per annullare la ridenominazione.
• Ctrl + A o Ctrl + SU per selezionare le cartelle.

Questo non sarà meglio di uno script per il tuo particolare scenario, ma è abbastanza bello saperlo quando i nomi delle tue cartelle non sono correlati: puoi creare più directory dalla riga di comando separandole con uno spazio:

C:\temp\animals>dir
 Volume in drive C is Windows
 Volume Serial Number is 82CB-BB0F

 Directory of C:\temp\animals

11/16/2015  03:55 PM    <DIR>          .
11/16/2015  03:55 PM    <DIR>          ..
               0 File(s)              0 bytes
               2 Dir(s)  1,636,846,243,840 bytes free

C:\temp\animals>mkdir cats dogs penguins

C:\temp\animals>dir
 Volume in drive C is Windows
 Volume Serial Number is 82CB-BB0F

 Directory of C:\temp\animals

11/16/2015  03:55 PM    <DIR>          .
11/16/2015  03:55 PM    <DIR>          ..
11/16/2015  03:55 PM    <DIR>          cats
11/16/2015  03:55 PM    <DIR>          dogs
11/16/2015  03:55 PM    <DIR>          penguins
               0 File(s)              0 bytes
               5 Dir(s)  1,636,846,178,304 bytes free

Se si creano cartelle numerate denominate in questo modo, è possibile che non vengano visualizzate nell'ordinamento corretto (previsto):

C:\Dropbox\Development> dir /b
Lec-10
Lec-100
Lec-101
Lec-102
Lec-103
Lec-104
Lec-105
Lec-106
Lec-107
Lec-108
Lec-109
Lec-11
Lec-110
Lec-111
Lec-112
Lec-113
Lec-114
Lec-115
Lec-116
Lec-117
Lec-118
Lec-119
Lec-12
Lec-120
Lec-13
Lec-14
Lec-15
Lec-16
Lec-17
Lec-18
Lec-19
Lec-20
Lec-21
...
Lec-89
Lec-9
Lec-90
Lec-91
...

Il problema è che la parte numerica dei nomi di cartelle è a larghezza variabile, il che influenza il modo in cui le cartelle sono ordinate.

Se per te è importante che le cartelle siano ordinate correttamente, usa il file batch di seguito per creare cartelle con la parte numerata dei nomi delle cartelle riempita con "0" (zero) in modo che tutti i numeri abbiano la stessa lunghezza, in questo modo:

C:\Dropbox\Development> dir /b
Lec-009
Lec-010
Lec-011
Lec-012
Lec-013
Lec-014
Lec-015
Lec-016
Lec-017
Lec-018
Lec-019
Lec-020
Lec-021
...

Ecco il file batch:

@echo off

for /L %%f in (9,1,120) do call :work 000%%f
goto :EOF


:work

set "dx=%~1"
set "dx=%dx:~-3%"

md "C:\Dropbox\Development\Lec-%dx%" >nul 2>&1

set "dx="
goto :EOF

È possibile eseguire questo file batch nella stessa cartella dei file. Ogni file verrà spostato in una cartella con lo stesso nome.

for /f "delims=" %%a in ('dir /b') do (
if not "%%~fa"=="%~f0" (
md "%%~na" 2>nul
if exist "%%a" move "%%~na.*" "%%~na"
)
)

Lo uso con un avviso di seguito per evitare un uso accidentale.

@echo off
echo.
set sure=
set /p sure=you want to put each file in this folder into their own folders? 
if /i "%sure%"=="" exit
if /i "%sure:~0,1%"=="n" exit
if /i not "%sure:~0,1%"=="y" (exit) else (echo.&echo are you sure? Close window to cancel or..)
echo.&pause 
for /f "delims=" %%a in ('dir /b') do (
if not "%%~fa"=="%~f0" (
md "%%~na" 2>nul
if exist "%%a" move "%%~na.*" "%%~na"
)
)

Prima di tutto non ho letto tutto il tuo problema ... ma per quanto ne so ... vuoi rinominare le cartelle in base all'elenco ... beh, ci sono due metodi

Metodo-1 -Se non hai un elenco di cartelle ... c'è una soluzione alternativa ... devi andare su macOS con questo albero delle cartelle ... e semplicemente copiare l'intero albero delle cartelle ... Quello che macOS farà sarà copiare il contenuto così come l'elenco di tutte le cartelle in termini di elenco e ... ora incolla in TextEdit o qualsiasi software simile a Blocco note.

-Ora suppongo che tu abbia quell'elenco di cartelle con te ... hai solo bisogno di un software di terze parti per fare il lavoro (ora tutti i passaggi sono per Windows) https://www.rename-expert.com -In termini per usare questo software dovevi creare una nuova cartella, una nuova cartella-2, una nuova cartella-4 quanto volevi.

-Ora in Rinomina esperto esiste un'opzione per rinominare le cartelle dalla base dell'elenco.

- Boom hai finito.

Metodo-2 -Se si desidera creare una copia speculare dell'intero albero delle cartelle senza file al suo interno.

-Beyond Compare è il software che ti serve. https://www.scootersoftware.com/support.php?zz=kb_copyfolderstructure